board/manroland/uc100/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34
  35     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  36     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  37
  38     *(.text*)
  39   }
  40   _etext = .;
  41   PROVIDE (etext = .);
  42   .rodata    :
  43   {
  44     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  45   }
  46
  47   /* Read-write section, merged into data segment: */
  48   . = (. + 0x00FF) & 0xFFFFFF00;
  49   _erotext = .;
  50   PROVIDE (erotext = .);
  51   .reloc   :
  52   {
  53     _GOT2_TABLE_ = .;
  54     KEEP(*(.got2))
  55     KEEP(*(.got))
  56     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  57     _FIXUP_TABLE_ = .;
  58     KEEP(*(.fixup))
  59   }
  60   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  61   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  62
  63   .data    :
  64   {
  65     *(.data*)
  66     *(.sdata*)
  67   }
  68   _edata  =  .;
  69   PROVIDE (edata = .);
  70
  71   . = .;
  72
  73   . = ALIGN(4);
  74   .u_boot_list : {
  75         #include <u-boot.lst>
  76   }
  77
  78
  79   . = .;
  80   __start___ex_table = .;
  81   __ex_table : { *(__ex_table) }
  82   __stop___ex_table = .;
  83
  84   . = ALIGN(256);
  85   __init_begin = .;
  86   .text.init : { *(.text.init) }
  87   .data.init : { *(.data.init) }
  88   . = ALIGN(256);
  89   __init_end = .;
  90
  91   __bss_start = .;
  92   .bss (NOLOAD)       :
  93   {
  94    *(.bss*)
  95    *(.sbss*)
  96    *(COMMON)
  97    . = ALIGN(4);
  98   }
  99   __bss_end__ = . ;
 100   PROVIDE (end = .);
 101 }