board/mvblue/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2007
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9 /* Do we need any of these for elf?
  10    __DYNAMIC = 0;    */
  11 SECTIONS
  12 {
  13   /* Read-only sections, merged into text segment: */
  14   .text      :
  15   {
  16     arch/powerpc/cpu/mpc824x/start.o            (.text*)
  17     lib/built-in.o                              (.text*)
  18     net/built-in.o                              (.text*)
  19     drivers/pci/built-in.o                      (.text*)
  20     arch/powerpc/cpu/mpc824x/built-in.o         (.text*)
  21     board/mvblue/built-in.o                     (.text*)
  22     arch/powerpc/lib/built-in.o                 (.text*)
  23
  24     . = DEFINED(env_offset) ? env_offset : .;
  25     common/env_embedded.o       (.ppcenv*)
  26
  27     *(.text*)
  28     . = ALIGN(16);
  29     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  30   }
  31
  32   /* Read-write section, merged into data segment: */
  33   . = (. + 0x0FFF) & 0xFFFFF000;
  34   _erotext = .;
  35   PROVIDE (erotext = .);
  36   .reloc   :
  37   {
  38     _GOT2_TABLE_ = .;
  39     KEEP(*(.got2))
  40     KEEP(*(.got))
  41     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  42     _FIXUP_TABLE_ = .;
  43     KEEP(*(.fixup))
  44   }
  45   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  46   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  47
  48   .data    :
  49   {
  50     *(.data*)
  51     *(.sdata*)
  52   }
  53   _edata  =  .;
  54   PROVIDE (edata = .);
  55
  56   . = .;
  57
  58   . = ALIGN(4);
  59   .u_boot_list : {
  60         KEEP(*(SORT(.u_boot_list*)));
  61   }
  62
  63
  64   . = .;
  65   __start___ex_table = .;
  66   __ex_table : { *(__ex_table) }
  67   __stop___ex_table = .;
  68
  69   . = ALIGN(4096);
  70   __init_begin = .;
  71   .text.init : { *(.text.init) }
  72   .data.init : { *(.data.init) }
  73   . = ALIGN(4096);
  74   __init_end = .;
  75
  76   __bss_start = .;
  77   .bss (NOLOAD)       :
  78   {
  79    *(.bss*)
  80    *(.sbss*)
  81    *(COMMON)
  82    . = ALIGN(4);
  83   }
  84   __bss_end = . ;
  85   PROVIDE (end = .);
  86 }