board/mvblue/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2007
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   .text      :
  31   {
  32     arch/powerpc/cpu/mpc824x/start.o            (.text*)
  33     lib/libgeneric.o                            (.text*)
  34     net/libnet.o                                (.text*)
  35     drivers/pci/libpci.o                        (.text*)
  36     arch/powerpc/cpu/mpc824x/libmpc824x.o       (.text*)
  37     board/mvblue/libmvblue.o                    (.text*)
  38     arch/powerpc/lib/libpowerpc.o               (.text*)
  39
  40     . = DEFINED(env_offset) ? env_offset : .;
  41     common/env_embedded.o       (.ppcenv*)
  42
  43     *(.text*)
  44     . = ALIGN(16);
  45     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  46   }
  47
  48   /* Read-write section, merged into data segment: */
  49   . = (. + 0x0FFF) & 0xFFFFF000;
  50   _erotext = .;
  51   PROVIDE (erotext = .);
  52   .reloc   :
  53   {
  54     KEEP(*(.got))
  55     _GOT2_TABLE_ = .;
  56     KEEP(*(.got2))
  57     _FIXUP_TABLE_ = .;
  58     KEEP(*(.fixup))
  59   }
  60   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  61   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  62
  63   .data    :
  64   {
  65     *(.data*)
  66     *(.sdata*)
  67   }
  68   _edata  =  .;
  69   PROVIDE (edata = .);
  70
  71   . = .;
  72   __u_boot_cmd_start = .;
  73   .u_boot_cmd : { *(.u_boot_cmd) }
  74   __u_boot_cmd_end = .;
  75
  76
  77   . = .;
  78   __start___ex_table = .;
  79   __ex_table : { *(__ex_table) }
  80   __stop___ex_table = .;
  81
  82   . = ALIGN(4096);
  83   __init_begin = .;
  84   .text.init : { *(.text.init) }
  85   .data.init : { *(.data.init) }
  86   . = ALIGN(4096);
  87   __init_end = .;
  88
  89   __bss_start = .;
  90   .bss (NOLOAD)       :
  91   {
  92    *(.bss*)
  93    *(.sbss*)
  94    *(COMMON)
  95    . = ALIGN(4);
  96   }
  97   _end = . ;
  98   PROVIDE (end = .);
  99 }