board/sandpoint/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2007
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34
  35     arch/powerpc/cpu/mpc824x/start.o    (.text*)
  36     *(.text.v*printf)
  37
  38     . = DEFINED(env_offset) ? env_offset : .;
  39     common/env_embedded.o       (.ppcenv*)
  40
  41     *(.text*)
  42     . = ALIGN(16);
  43     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  44   }
  45
  46   /* Read-write section, merged into data segment: */
  47   . = (. + 0x0FFF) & 0xFFFFF000;
  48   _erotext = .;
  49   PROVIDE (erotext = .);
  50   .reloc   :
  51   {
  52     KEEP(*(.got))
  53     _GOT2_TABLE_ = .;
  54     KEEP(*(.got2))
  55     _FIXUP_TABLE_ = .;
  56     KEEP(*(.fixup))
  57   }
  58   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  59   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  60
  61   .data    :
  62   {
  63     *(.data*)
  64     *(.sdata*)
  65   }
  66   _edata  =  .;
  67   PROVIDE (edata = .);
  68
  69   . = .;
  70   __u_boot_cmd_start = .;
  71   .u_boot_cmd : { *(.u_boot_cmd) }
  72   __u_boot_cmd_end = .;
  73
  74
  75   . = .;
  76   __start___ex_table = .;
  77   __ex_table : { *(__ex_table) }
  78   __stop___ex_table = .;
  79
  80   . = ALIGN(4096);
  81   __init_begin = .;
  82   .text.init : { *(.text.init) }
  83   .data.init : { *(.data.init) }
  84   . = ALIGN(4096);
  85   __init_end = .;
  86
  87   __bss_start = .;
  88   .bss (NOLOAD)       :
  89   {
  90    *(.bss*)
  91    *(.sbss*)
  92    *(COMMON)
  93    . = ALIGN(4);
  94   }
  95   _end = . ;
  96   PROVIDE (end = .);
  97 }