board/svm_sc8xx/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  35     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  36     lib/libgeneric.o                    (.text*)
  37     net/libnet.o                        (.text*)
  38     arch/powerpc/cpu/mpc8xx/libmpc8xx.o (.text*)
  39     arch/powerpc/lib/libpowerpc.o       (.text*)
  40     board/svm_sc8xx/libsvm_sc8xx.o      (.text*)
  41     *(.text.*printf)
  42     *(.text.do_mem_*)
  43     *(.text.flash*)
  44     *(.text.run_command)
  45     *(.text.main_loop)
  46     *(.text.srec_decode)
  47
  48     . = env_offset;
  49     common/env_embedded.o               (.ppcenv*)
  50
  51     *(.text*)
  52   }
  53   _etext = .;
  54   PROVIDE (etext = .);
  55   .rodata    :
  56   {
  57     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  58   }
  59
  60   /* Read-write section, merged into data segment: */
  61   . = (. + 0x00FF) & 0xFFFFFF00;
  62   _erotext = .;
  63   PROVIDE (erotext = .);
  64   .reloc   :
  65   {
  66     _GOT2_TABLE_ = .;
  67     KEEP(*(.got2))
  68     KEEP(*(.got))
  69     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  70     _FIXUP_TABLE_ = .;
  71     KEEP(*(.fixup))
  72   }
  73   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  74   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  75
  76   .data    :
  77   {
  78     *(.data*)
  79     *(.sdata*)
  80   }
  81   _edata  =  .;
  82   PROVIDE (edata = .);
  83
  84
  85   . = .;
  86
  87   . = ALIGN(4);
  88   .u_boot_list : {
  89         KEEP(*(SORT(.u_boot_list*)));
  90   }
  91
  92
  93   . = .;
  94   __start___ex_table = .;
  95   __ex_table : { *(__ex_table) }
  96   __stop___ex_table = .;
  97
  98   . = ALIGN(256);
  99   __init_begin = .;
 100   .text.init : { *(.text.init) }
 101   .data.init : { *(.data.init) }
 102   . = ALIGN(256);
 103   __init_end = .;
 104
 105   __bss_start = .;
 106   .bss (NOLOAD)       :
 107   {
 108    *(.bss*)
 109    *(.sbss*)
 110    *(COMMON)
 111    . = ALIGN(4);
 112   }
 113   __bss_end = . ;
 114   PROVIDE (end = .);
 115 }