board/vpac270/u-boot-spl.lds

   1 /*
   2  * Copyright (C) 2011 Marek Vasut <marek.vasut@gmail.com>
   3  * on behalf of DENX Software Engineering GmbH
   4  *
   5  * January 2004 - Changed to support H4 device
   6  * Copyright (c) 2004-2008 Texas Instruments
   7  *
   8  * (C) Copyright 2002
   9  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
  10  *
  11  * SPDX-License-Identifier:     GPL-2.0+
  12  */
  13
  14 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  15 OUTPUT_ARCH(arm)
  16 ENTRY(_start)
  17 SECTIONS
  18 {
  19         . = CONFIG_SPL_TEXT_BASE;
  20         .text.0 :
  21         {
  22                 arch/arm/cpu/pxa/start.o                (.text*)
  23                 arch/arm/lib/built-in.o                 (.text*)
  24                 board/vpac270/built-in.o                (.text*)
  25                 drivers/mtd/onenand/built-in.o          (.text*)
  26         }
  27
  28
  29         /* Start of the rest of the SPL */
  30         . = CONFIG_SPL_TEXT_BASE + 0x800;
  31
  32         .text.1 :
  33         {
  34                 *(.text*)
  35         }
  36
  37         . = ALIGN(4);
  38         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  39
  40         . = ALIGN(4);
  41         .data : {
  42                 *(.data*)
  43         }
  44
  45         . = ALIGN(4);
  46
  47         __image_copy_end = .;
  48
  49         .rel.dyn : {
  50                 __rel_dyn_start = .;
  51                 *(.rel*)
  52                 __rel_dyn_end = .;
  53         }
  54
  55         . = ALIGN(0x800);
  56
  57         _end = .;
  58
  59         .bss __rel_dyn_start (OVERLAY) : {
  60                 __bss_start = .;
  61                 *(.bss*)
  62                  . = ALIGN(4);
  63                 __bss_end = .;
  64         }
  65
  66         .dynsym _end : { *(.dynsym) }
  67         .dynbss : { *(.dynbss) }
  68         .dynstr : { *(.dynstr*) }
  69         .dynamic : { *(.dynamic*) }
  70         .hash : { *(.hash*) }
  71         .plt : { *(.plt*) }
  72         .interp : { *(.interp*) }
  73         .gnu : { *(.gnu*) }
  74         .ARM.exidx : { *(.ARM.exidx*) }
  75 }