arch/powerpc/kernel/exceptions-64e.S

   1 /*
   2  *  Boot code and exception vectors for Book3E processors
   3  *
   4  *  Copyright (C) 2007 Ben. Herrenschmidt (benh@kernel.crashing.org), IBM Corp.
   5  *
   6  *  This program is free software; you can redistribute it and/or
   7  *  modify it under the terms of the GNU General Public License
   8  *  as published by the Free Software Foundation; either version
   9  *  2 of the License, or (at your option) any later version.
  10  */
  11
  12 #include <linux/threads.h>
  13 #include <asm/reg.h>
  14 #include <asm/page.h>
  15 #include <asm/ppc_asm.h>
  16 #include <asm/asm-offsets.h>
  17 #include <asm/cputable.h>
  18 #include <asm/setup.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/reg_a2.h>
  21 #include <asm/exception-64e.h>
  22 #include <asm/bug.h>
  23 #include <asm/irqflags.h>
  24 #include <asm/ptrace.h>
  25 #include <asm/ppc-opcode.h>
  26 #include <asm/mmu.h>
  27 #include <asm/hw_irq.h>
  28 #include <asm/kvm_asm.h>
  29 #include <asm/kvm_booke_hv_asm.h>
  30
  31 /* XXX This will ultimately add space for a special exception save
  32  *     structure used to save things like SRR0/SRR1, SPRGs, MAS, etc...
  33  *     when taking special interrupts. For now we don't support that,
  34  *     special interrupts from within a non-standard level will probably
  35  *     blow you up
  36  */
  37 #define SPECIAL_EXC_FRAME_SIZE  INT_FRAME_SIZE
  38
  39 /* Exception prolog code for all exceptions */
  40 #define EXCEPTION_PROLOG(n, intnum, type, addition)                         \
  41         mtspr   SPRN_SPRG_##type##_SCRATCH,r13; /* get spare registers */   \
  42         mfspr   r13,SPRN_SPRG_PACA;     /* get PACA */                      \
  43         std     r10,PACA_EX##type+EX_R10(r13);                              \
  44         std     r11,PACA_EX##type+EX_R11(r13);                              \
  45         PROLOG_STORE_RESTORE_SCRATCH_##type;                                \
  46         mfcr    r10;                    /* save CR */                       \
  47         mfspr   r11,SPRN_##type##_SRR1;/* what are we coming from */        \
  48         DO_KVM  intnum,SPRN_##type##_SRR1;    /* KVM hook */                \
  49         stw     r10,PACA_EX##type+EX_CR(r13); /* save old CR in the PACA */ \
  50         addition;                       /* additional code for that exc. */ \
  51         std     r1,PACA_EX##type+EX_R1(r13); /* save old r1 in the PACA */  \
  52         type##_SET_KSTACK;              /* get special stack if necessary */\
  53         andi.   r10,r11,MSR_PR;         /* save stack pointer */            \
  54         beq     1f;                     /* branch around if supervisor */   \
  55         ld      r1,PACAKSAVE(r13);      /* get kernel stack coming from usr */\
  56 1:      cmpdi   cr1,r1,0;               /* check if SP makes sense */       \
  57         bge-    cr1,exc_##n##_bad_stack;/* bad stack (TODO: out of line) */ \
  58         mfspr   r10,SPRN_##type##_SRR0; /* read SRR0 before touching stack */
  59
  60 /* Exception type-specific macros */
  61 #define GEN_SET_KSTACK                                                      \
  62         subi    r1,r1,INT_FRAME_SIZE;   /* alloc frame on kernel stack */
  63 #define SPRN_GEN_SRR0   SPRN_SRR0
  64 #define SPRN_GEN_SRR1   SPRN_SRR1
  65
  66 #define GDBELL_SET_KSTACK       GEN_SET_KSTACK
  67 #define SPRN_GDBELL_SRR0        SPRN_GSRR0
  68 #define SPRN_GDBELL_SRR1        SPRN_GSRR1
  69
  70 #define CRIT_SET_KSTACK                                                     \
  71         ld      r1,PACA_CRIT_STACK(r13);                                    \
  72         subi    r1,r1,SPECIAL_EXC_FRAME_SIZE;
  73 #define SPRN_CRIT_SRR0  SPRN_CSRR0
  74 #define SPRN_CRIT_SRR1  SPRN_CSRR1
  75
  76 #define DBG_SET_KSTACK                                                      \
  77         ld      r1,PACA_DBG_STACK(r13);                                     \
  78         subi    r1,r1,SPECIAL_EXC_FRAME_SIZE;
  79 #define SPRN_DBG_SRR0   SPRN_DSRR0
  80 #define SPRN_DBG_SRR1   SPRN_DSRR1
  81
  82 #define MC_SET_KSTACK                                                       \
  83         ld      r1,PACA_MC_STACK(r13);                                      \
  84         subi    r1,r1,SPECIAL_EXC_FRAME_SIZE;
  85 #define SPRN_MC_SRR0    SPRN_MCSRR0
  86 #define SPRN_MC_SRR1    SPRN_MCSRR1
  87
  88 #define NORMAL_EXCEPTION_PROLOG(n, intnum, addition)                        \
  89         EXCEPTION_PROLOG(n, intnum, GEN, addition##_GEN(n))
  90
  91 #define CRIT_EXCEPTION_PROLOG(n, intnum, addition)                          \
  92         EXCEPTION_PROLOG(n, intnum, CRIT, addition##_CRIT(n))
  93
  94 #define DBG_EXCEPTION_PROLOG(n, intnum, addition)                           \
  95         EXCEPTION_PROLOG(n, intnum, DBG, addition##_DBG(n))
  96
  97 #define MC_EXCEPTION_PROLOG(n, intnum, addition)                            \
  98         EXCEPTION_PROLOG(n, intnum, MC, addition##_MC(n))
  99
 100 #define GDBELL_EXCEPTION_PROLOG(n, intnum, addition)                        \
 101         EXCEPTION_PROLOG(n, intnum, GDBELL, addition##_GDBELL(n))
 102
 103 /*
 104  * Store user-visible scratch in PACA exception slots and restore proper value
 105  */
 106 #define PROLOG_STORE_RESTORE_SCRATCH_GEN
 107 #define PROLOG_STORE_RESTORE_SCRATCH_GDBELL
 108 #define PROLOG_STORE_RESTORE_SCRATCH_DBG
 109 #define PROLOG_STORE_RESTORE_SCRATCH_MC
 110
 111 #define PROLOG_STORE_RESTORE_SCRATCH_CRIT                                   \
 112         mfspr   r10,SPRN_SPRG_CRIT_SCRATCH;     /* get r13 */               \
 113         std     r10,PACA_EXCRIT+EX_R13(r13);                                \
 114         ld      r11,PACA_SPRG3(r13);                                        \
 115         mtspr   SPRN_SPRG_CRIT_SCRATCH,r11;
 116
 117 /* Variants of the "addition" argument for the prolog
 118  */
 119 #define PROLOG_ADDITION_NONE_GEN(n)
 120 #define PROLOG_ADDITION_NONE_GDBELL(n)
 121 #define PROLOG_ADDITION_NONE_CRIT(n)
 122 #define PROLOG_ADDITION_NONE_DBG(n)
 123 #define PROLOG_ADDITION_NONE_MC(n)
 124
 125 #define PROLOG_ADDITION_MASKABLE_GEN(n)                                     \
 126         lbz     r10,PACASOFTIRQEN(r13); /* are irqs soft-disabled ? */      \
 127         cmpwi   cr0,r10,0;              /* yes -> go out of line */         \
 128         beq     masked_interrupt_book3e_##n
 129
 130 #define PROLOG_ADDITION_2REGS_GEN(n)                                        \
 131         std     r14,PACA_EXGEN+EX_R14(r13);                                 \
 132         std     r15,PACA_EXGEN+EX_R15(r13)
 133
 134 #define PROLOG_ADDITION_1REG_GEN(n)                                         \
 135         std     r14,PACA_EXGEN+EX_R14(r13);
 136
 137 #define PROLOG_ADDITION_2REGS_CRIT(n)                                       \
 138         std     r14,PACA_EXCRIT+EX_R14(r13);                                \
 139         std     r15,PACA_EXCRIT+EX_R15(r13)
 140
 141 #define PROLOG_ADDITION_2REGS_DBG(n)                                        \
 142         std     r14,PACA_EXDBG+EX_R14(r13);                                 \
 143         std     r15,PACA_EXDBG+EX_R15(r13)
 144
 145 #define PROLOG_ADDITION_2REGS_MC(n)                                         \
 146         std     r14,PACA_EXMC+EX_R14(r13);                                  \
 147         std     r15,PACA_EXMC+EX_R15(r13)
 148
 149
 150 /* Core exception code for all exceptions except TLB misses.
 151  * XXX: Needs to make SPRN_SPRG_GEN depend on exception type
 152  */
 153 #define EXCEPTION_COMMON(n, excf, ints)                                     \
 154 exc_##n##_common:                                                           \
 155         std     r0,GPR0(r1);            /* save r0 in stackframe */         \
 156         std     r2,GPR2(r1);            /* save r2 in stackframe */         \
 157         SAVE_4GPRS(3, r1);              /* save r3 - r6 in stackframe */    \
 158         SAVE_2GPRS(7, r1);              /* save r7, r8 in stackframe */     \
 159         std     r9,GPR9(r1);            /* save r9 in stackframe */         \
 160         std     r10,_NIP(r1);           /* save SRR0 to stackframe */       \
 161         std     r11,_MSR(r1);           /* save SRR1 to stackframe */       \
 162         beq     2f;                     /* if from kernel mode */           \
 163         ACCOUNT_CPU_USER_ENTRY(r10,r11);/* accounting (uses cr0+eq) */      \
 164 2:      ld      r3,excf+EX_R10(r13);    /* get back r10 */                  \
 165         ld      r4,excf+EX_R11(r13);    /* get back r11 */                  \
 166         mfspr   r5,SPRN_SPRG_GEN_SCRATCH;/* get back r13 */                 \
 167         std     r12,GPR12(r1);          /* save r12 in stackframe */        \
 168         ld      r2,PACATOC(r13);        /* get kernel TOC into r2 */        \
 169         mflr    r6;                     /* save LR in stackframe */         \
 170         mfctr   r7;                     /* save CTR in stackframe */        \
 171         mfspr   r8,SPRN_XER;            /* save XER in stackframe */        \
 172         ld      r9,excf+EX_R1(r13);     /* load orig r1 back from PACA */   \
 173         lwz     r10,excf+EX_CR(r13);    /* load orig CR back from PACA  */  \
 174         lbz     r11,PACASOFTIRQEN(r13); /* get current IRQ softe */         \
 175         ld      r12,exception_marker@toc(r2);                               \
 176         li      r0,0;                                                       \
 177         std     r3,GPR10(r1);           /* save r10 to stackframe */        \
 178         std     r4,GPR11(r1);           /* save r11 to stackframe */        \
 179         std     r5,GPR13(r1);           /* save it to stackframe */         \
 180         std     r6,_LINK(r1);                                               \
 181         std     r7,_CTR(r1);                                                \
 182         std     r8,_XER(r1);                                                \
 183         li      r3,(n)+1;               /* indicate partial regs in trap */ \
 184         std     r9,0(r1);               /* store stack frame back link */   \
 185         std     r10,_CCR(r1);           /* store orig CR in stackframe */   \
 186         std     r9,GPR1(r1);            /* store stack frame back link */   \
 187         std     r11,SOFTE(r1);          /* and save it to stackframe */     \
 188         std     r12,STACK_FRAME_OVERHEAD-16(r1); /* mark the frame */       \
 189         std     r3,_TRAP(r1);           /* set trap number              */  \
 190         std     r0,RESULT(r1);          /* clear regs->result */            \
 191         ints;
 192
 193 /* Variants for the "ints" argument. This one does nothing when we want
 194  * to keep interrupts in their original state
 195  */
 196 #define INTS_KEEP
 197
 198 /* This second version is meant for exceptions that don't immediately
 199  * hard-enable. We set a bit in paca->irq_happened to ensure that
 200  * a subsequent call to arch_local_irq_restore() will properly
 201  * hard-enable and avoid the fast-path, and then reconcile irq state.
 202  */
 203 #define INTS_DISABLE    RECONCILE_IRQ_STATE(r3,r4)
 204
 205 /* This is called by exceptions that used INTS_KEEP (that did not touch
 206  * irq indicators in the PACA). This will restore MSR:EE to it's previous
 207  * value
 208  *
 209  * XXX In the long run, we may want to open-code it in order to separate the
 210  *     load from the wrtee, thus limiting the latency caused by the dependency
 211  *     but at this point, I'll favor code clarity until we have a near to final
 212  *     implementation
 213  */
 214 #define INTS_RESTORE_HARD                                                   \
 215         ld      r11,_MSR(r1);                                               \
 216         wrtee   r11;
 217
 218 /* XXX FIXME: Restore r14/r15 when necessary */
 219 #define BAD_STACK_TRAMPOLINE(n)                                             \
 220 exc_##n##_bad_stack:                                                        \
 221         li      r1,(n);                 /* get exception number */          \
 222         sth     r1,PACA_TRAP_SAVE(r13); /* store trap */                    \
 223         b       bad_stack_book3e;       /* bad stack error */
 224
 225 /* WARNING: If you change the layout of this stub, make sure you chcek
 226         *   the debug exception handler which handles single stepping
 227         *   into exceptions from userspace, and the MM code in
 228         *   arch/powerpc/mm/tlb_nohash.c which patches the branch here
 229         *   and would need to be updated if that branch is moved
 230         */
 231 #define EXCEPTION_STUB(loc, label)                                      \
 232         . = interrupt_base_book3e + loc;                                \
 233         nop;    /* To make debug interrupts happy */                    \
 234         b       exc_##label##_book3e;
 235
 236 #define ACK_NONE(r)
 237 #define ACK_DEC(r)                                                      \
 238         lis     r,TSR_DIS@h;                                            \
 239         mtspr   SPRN_TSR,r
 240 #define ACK_FIT(r)                                                      \
 241         lis     r,TSR_FIS@h;                                            \
 242         mtspr   SPRN_TSR,r
 243
 244 /* Used by asynchronous interrupt that may happen in the idle loop.
 245  *
 246  * This check if the thread was in the idle loop, and if yes, returns
 247  * to the caller rather than the PC. This is to avoid a race if
 248  * interrupts happen before the wait instruction.
 249  */
 250 #define CHECK_NAPPING()                                                 \
 251         CURRENT_THREAD_INFO(r11, r1);                                   \
 252         ld      r10,TI_LOCAL_FLAGS(r11);                                \
 253         andi.   r9,r10,_TLF_NAPPING;                                    \
 254         beq+    1f;                                                     \
 255         ld      r8,_LINK(r1);                                           \
 256         rlwinm  r7,r10,0,~_TLF_NAPPING;                                 \
 257         std     r8,_NIP(r1);                                            \
 258         std     r7,TI_LOCAL_FLAGS(r11);                                 \
 259 1:
 260
 261
 262 #define MASKABLE_EXCEPTION(trapnum, intnum, label, hdlr, ack)           \
 263         START_EXCEPTION(label);                                         \
 264         NORMAL_EXCEPTION_PROLOG(trapnum, intnum, PROLOG_ADDITION_MASKABLE)\
 265         EXCEPTION_COMMON(trapnum, PACA_EXGEN, INTS_DISABLE)             \
 266         ack(r8);                                                        \
 267         CHECK_NAPPING();                                                \
 268         addi    r3,r1,STACK_FRAME_OVERHEAD;                             \
 269         bl      hdlr;                                                   \
 270         b       .ret_from_except_lite;
 271
 272 /* This value is used to mark exception frames on the stack. */
 273         .section        ".toc","aw"
 274 exception_marker:
 275         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
 276
 277
 278 /*
 279  * And here we have the exception vectors !
 280  */
 281
 282         .text
 283         .balign 0x1000
 284         .globl interrupt_base_book3e
 285 interrupt_base_book3e:                                  /* fake trap */
 286         EXCEPTION_STUB(0x000, machine_check)            /* 0x0200 */
 287         EXCEPTION_STUB(0x020, critical_input)           /* 0x0580 */
 288         EXCEPTION_STUB(0x040, debug_crit)               /* 0x0d00 */
 289         EXCEPTION_STUB(0x060, data_storage)             /* 0x0300 */
 290         EXCEPTION_STUB(0x080, instruction_storage)      /* 0x0400 */
 291         EXCEPTION_STUB(0x0a0, external_input)           /* 0x0500 */
 292         EXCEPTION_STUB(0x0c0, alignment)                /* 0x0600 */
 293         EXCEPTION_STUB(0x0e0, program)                  /* 0x0700 */
 294         EXCEPTION_STUB(0x100, fp_unavailable)           /* 0x0800 */
 295         EXCEPTION_STUB(0x120, system_call)              /* 0x0c00 */
 296         EXCEPTION_STUB(0x140, ap_unavailable)           /* 0x0f20 */
 297         EXCEPTION_STUB(0x160, decrementer)              /* 0x0900 */
 298         EXCEPTION_STUB(0x180, fixed_interval)           /* 0x0980 */
 299         EXCEPTION_STUB(0x1a0, watchdog)                 /* 0x09f0 */
 300         EXCEPTION_STUB(0x1c0, data_tlb_miss)
 301         EXCEPTION_STUB(0x1e0, instruction_tlb_miss)
 302         EXCEPTION_STUB(0x200, altivec_unavailable)      /* 0x0f20 */
 303         EXCEPTION_STUB(0x220, altivec_assist)           /* 0x1700 */
 304         EXCEPTION_STUB(0x260, perfmon)
 305         EXCEPTION_STUB(0x280, doorbell)
 306         EXCEPTION_STUB(0x2a0, doorbell_crit)
 307         EXCEPTION_STUB(0x2c0, guest_doorbell)
 308         EXCEPTION_STUB(0x2e0, guest_doorbell_crit)
 309         EXCEPTION_STUB(0x300, hypercall)
 310         EXCEPTION_STUB(0x320, ehpriv)
 311
 312         .globl interrupt_end_book3e
 313 interrupt_end_book3e:
 314
 315 /* Critical Input Interrupt */
 316         START_EXCEPTION(critical_input);
 317         CRIT_EXCEPTION_PROLOG(0x100, BOOKE_INTERRUPT_CRITICAL,
 318                               PROLOG_ADDITION_NONE)
 319 //      EXCEPTION_COMMON(0x100, PACA_EXCRIT, INTS_DISABLE)
 320 //      bl      special_reg_save_crit
 321 //      CHECK_NAPPING();
 322 //      addi    r3,r1,STACK_FRAME_OVERHEAD
 323 //      bl      .critical_exception
 324 //      b       ret_from_crit_except
 325         b       .
 326
 327 /* Machine Check Interrupt */
 328         START_EXCEPTION(machine_check);
 329         MC_EXCEPTION_PROLOG(0x200, BOOKE_INTERRUPT_MACHINE_CHECK,
 330                             PROLOG_ADDITION_NONE)
 331 //      EXCEPTION_COMMON(0x200, PACA_EXMC, INTS_DISABLE)
 332 //      bl      special_reg_save_mc
 333 //      addi    r3,r1,STACK_FRAME_OVERHEAD
 334 //      CHECK_NAPPING();
 335 //      bl      .machine_check_exception
 336 //      b       ret_from_mc_except
 337         b       .
 338
 339 /* Data Storage Interrupt */
 340         START_EXCEPTION(data_storage)
 341         NORMAL_EXCEPTION_PROLOG(0x300, BOOKE_INTERRUPT_DATA_STORAGE,
 342                                 PROLOG_ADDITION_2REGS)
 343         mfspr   r14,SPRN_DEAR
 344         mfspr   r15,SPRN_ESR
 345         EXCEPTION_COMMON(0x300, PACA_EXGEN, INTS_DISABLE)
 346         b       storage_fault_common
 347
 348 /* Instruction Storage Interrupt */
 349         START_EXCEPTION(instruction_storage);
 350         NORMAL_EXCEPTION_PROLOG(0x400, BOOKE_INTERRUPT_INST_STORAGE,
 351                                 PROLOG_ADDITION_2REGS)
 352         li      r15,0
 353         mr      r14,r10
 354         EXCEPTION_COMMON(0x400, PACA_EXGEN, INTS_DISABLE)
 355         b       storage_fault_common
 356
 357 /* External Input Interrupt */
 358         MASKABLE_EXCEPTION(0x500, BOOKE_INTERRUPT_EXTERNAL,
 359                            external_input, .do_IRQ, ACK_NONE)
 360
 361 /* Alignment */
 362         START_EXCEPTION(alignment);
 363         NORMAL_EXCEPTION_PROLOG(0x600, BOOKE_INTERRUPT_ALIGNMENT,
 364                                 PROLOG_ADDITION_2REGS)
 365         mfspr   r14,SPRN_DEAR
 366         mfspr   r15,SPRN_ESR
 367         EXCEPTION_COMMON(0x600, PACA_EXGEN, INTS_KEEP)
 368         b       alignment_more  /* no room, go out of line */
 369
 370 /* Program Interrupt */
 371         START_EXCEPTION(program);
 372         NORMAL_EXCEPTION_PROLOG(0x700, BOOKE_INTERRUPT_PROGRAM,
 373                                 PROLOG_ADDITION_1REG)
 374         mfspr   r14,SPRN_ESR
 375         EXCEPTION_COMMON(0x700, PACA_EXGEN, INTS_DISABLE)
 376         std     r14,_DSISR(r1)
 377         addi    r3,r1,STACK_FRAME_OVERHEAD
 378         ld      r14,PACA_EXGEN+EX_R14(r13)
 379         bl      .save_nvgprs
 380         bl      .program_check_exception
 381         b       .ret_from_except
 382
 383 /* Floating Point Unavailable Interrupt */
 384         START_EXCEPTION(fp_unavailable);
 385         NORMAL_EXCEPTION_PROLOG(0x800, BOOKE_INTERRUPT_FP_UNAVAIL,
 386                                 PROLOG_ADDITION_NONE)
 387         /* we can probably do a shorter exception entry for that one... */
 388         EXCEPTION_COMMON(0x800, PACA_EXGEN, INTS_KEEP)
 389         ld      r12,_MSR(r1)
 390         andi.   r0,r12,MSR_PR;
 391         beq-    1f
 392         bl      .load_up_fpu
 393         b       fast_exception_return
 394 1:      INTS_DISABLE
 395         bl      .save_nvgprs
 396         addi    r3,r1,STACK_FRAME_OVERHEAD
 397         bl      .kernel_fp_unavailable_exception
 398         b       .ret_from_except
 399
 400 /* Altivec Unavailable Interrupt */
 401         START_EXCEPTION(altivec_unavailable);
 402         NORMAL_EXCEPTION_PROLOG(0x200, BOOKE_INTERRUPT_ALTIVEC_UNAVAIL,
 403                                 PROLOG_ADDITION_NONE)
 404         /* we can probably do a shorter exception entry for that one... */
 405         EXCEPTION_COMMON(0x200, PACA_EXGEN, INTS_KEEP)
 406 #ifdef CONFIG_ALTIVEC
 407 BEGIN_FTR_SECTION
 408         ld      r12,_MSR(r1)
 409         andi.   r0,r12,MSR_PR;
 410         beq-    1f
 411         bl      .load_up_altivec
 412         b       fast_exception_return
 413 1:
 414 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 415 #endif
 416         INTS_DISABLE
 417         bl      .save_nvgprs
 418         addi    r3,r1,STACK_FRAME_OVERHEAD
 419         bl      .altivec_unavailable_exception
 420         b       .ret_from_except
 421
 422 /* AltiVec Assist */
 423         START_EXCEPTION(altivec_assist);
 424         NORMAL_EXCEPTION_PROLOG(0x220, BOOKE_INTERRUPT_ALTIVEC_ASSIST,
 425                                 PROLOG_ADDITION_NONE)
 426         EXCEPTION_COMMON(0x220, PACA_EXGEN, INTS_DISABLE)
 427         bl      .save_nvgprs
 428         addi    r3,r1,STACK_FRAME_OVERHEAD
 429 #ifdef CONFIG_ALTIVEC
 430 BEGIN_FTR_SECTION
 431         bl      .altivec_assist_exception
 432 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 433 #else
 434         bl      .unknown_exception
 435 #endif
 436         b       .ret_from_except
 437
 438
 439 /* Decrementer Interrupt */
 440         MASKABLE_EXCEPTION(0x900, BOOKE_INTERRUPT_DECREMENTER,
 441                            decrementer, .timer_interrupt, ACK_DEC)
 442
 443 /* Fixed Interval Timer Interrupt */
 444         MASKABLE_EXCEPTION(0x980, BOOKE_INTERRUPT_FIT,
 445                            fixed_interval, .unknown_exception, ACK_FIT)
 446
 447 /* Watchdog Timer Interrupt */
 448         START_EXCEPTION(watchdog);
 449         CRIT_EXCEPTION_PROLOG(0x9f0, BOOKE_INTERRUPT_WATCHDOG,
 450                               PROLOG_ADDITION_NONE)
 451 //      EXCEPTION_COMMON(0x9f0, PACA_EXCRIT, INTS_DISABLE)
 452 //      bl      special_reg_save_crit
 453 //      CHECK_NAPPING();
 454 //      addi    r3,r1,STACK_FRAME_OVERHEAD
 455 //      bl      .unknown_exception
 456 //      b       ret_from_crit_except
 457         b       .
 458
 459 /* System Call Interrupt */
 460         START_EXCEPTION(system_call)
 461         mr      r9,r13                  /* keep a copy of userland r13 */
 462         mfspr   r11,SPRN_SRR0           /* get return address */
 463         mfspr   r12,SPRN_SRR1           /* get previous MSR */
 464         mfspr   r13,SPRN_SPRG_PACA      /* get our PACA */
 465         b       system_call_common
 466
 467 /* Auxiliary Processor Unavailable Interrupt */
 468         START_EXCEPTION(ap_unavailable);
 469         NORMAL_EXCEPTION_PROLOG(0xf20, BOOKE_INTERRUPT_AP_UNAVAIL,
 470                                 PROLOG_ADDITION_NONE)
 471         EXCEPTION_COMMON(0xf20, PACA_EXGEN, INTS_DISABLE)
 472         bl      .save_nvgprs
 473         addi    r3,r1,STACK_FRAME_OVERHEAD
 474         bl      .unknown_exception
 475         b       .ret_from_except
 476
 477 /* Debug exception as a critical interrupt*/
 478         START_EXCEPTION(debug_crit);
 479         CRIT_EXCEPTION_PROLOG(0xd00, BOOKE_INTERRUPT_DEBUG,
 480                               PROLOG_ADDITION_2REGS)
 481
 482         /*
 483          * If there is a single step or branch-taken exception in an
 484          * exception entry sequence, it was probably meant to apply to
 485          * the code where the exception occurred (since exception entry
 486          * doesn't turn off DE automatically).  We simulate the effect
 487          * of turning off DE on entry to an exception handler by turning
 488          * off DE in the CSRR1 value and clearing the debug status.
 489          */
 490
 491         mfspr   r14,SPRN_DBSR           /* check single-step/branch taken */
 492         andis.  r15,r14,(DBSR_IC|DBSR_BT)@h
 493         beq+    1f
 494
 495         LOAD_REG_IMMEDIATE(r14,interrupt_base_book3e)
 496         LOAD_REG_IMMEDIATE(r15,interrupt_end_book3e)
 497         cmpld   cr0,r10,r14
 498         cmpld   cr1,r10,r15
 499         blt+    cr0,1f
 500         bge+    cr1,1f
 501
 502         /* here it looks like we got an inappropriate debug exception. */
 503         lis     r14,(DBSR_IC|DBSR_BT)@h         /* clear the event */
 504         rlwinm  r11,r11,0,~MSR_DE       /* clear DE in the CSRR1 value */
 505         mtspr   SPRN_DBSR,r14
 506         mtspr   SPRN_CSRR1,r11
 507         lwz     r10,PACA_EXCRIT+EX_CR(r13)      /* restore registers */
 508         ld      r1,PACA_EXCRIT+EX_R1(r13)
 509         ld      r14,PACA_EXCRIT+EX_R14(r13)
 510         ld      r15,PACA_EXCRIT+EX_R15(r13)
 511         mtcr    r10
 512         ld      r10,PACA_EXCRIT+EX_R10(r13)     /* restore registers */
 513         ld      r11,PACA_EXCRIT+EX_R11(r13)
 514         ld      r13,PACA_EXCRIT+EX_R13(r13)
 515         rfci
 516
 517         /* Normal debug exception */
 518         /* XXX We only handle coming from userspace for now since we can't
 519          *     quite save properly an interrupted kernel state yet
 520          */
 521 1:      andi.   r14,r11,MSR_PR;         /* check for userspace again */
 522         beq     kernel_dbg_exc;         /* if from kernel mode */
 523
 524         /* Now we mash up things to make it look like we are coming on a
 525          * normal exception
 526          */
 527         ld      r15,PACA_EXCRIT+EX_R13(r13)
 528         mtspr   SPRN_SPRG_GEN_SCRATCH,r15
 529         mfspr   r14,SPRN_DBSR
 530         EXCEPTION_COMMON(0xd00, PACA_EXCRIT, INTS_DISABLE)
 531         std     r14,_DSISR(r1)
 532         addi    r3,r1,STACK_FRAME_OVERHEAD
 533         mr      r4,r14
 534         ld      r14,PACA_EXCRIT+EX_R14(r13)
 535         ld      r15,PACA_EXCRIT+EX_R15(r13)
 536         bl      .save_nvgprs
 537         bl      .DebugException
 538         b       .ret_from_except
 539
 540 kernel_dbg_exc:
 541         b       .       /* NYI */
 542
 543 /* Debug exception as a debug interrupt*/
 544         START_EXCEPTION(debug_debug);
 545         DBG_EXCEPTION_PROLOG(0xd00, BOOKE_INTERRUPT_DEBUG,
 546                                                  PROLOG_ADDITION_2REGS)
 547
 548         /*
 549          * If there is a single step or branch-taken exception in an
 550          * exception entry sequence, it was probably meant to apply to
 551          * the code where the exception occurred (since exception entry
 552          * doesn't turn off DE automatically).  We simulate the effect
 553          * of turning off DE on entry to an exception handler by turning
 554          * off DE in the DSRR1 value and clearing the debug status.
 555          */
 556
 557         mfspr   r14,SPRN_DBSR           /* check single-step/branch taken */
 558         andis.  r15,r14,(DBSR_IC|DBSR_BT)@h
 559         beq+    1f
 560
 561         LOAD_REG_IMMEDIATE(r14,interrupt_base_book3e)
 562         LOAD_REG_IMMEDIATE(r15,interrupt_end_book3e)
 563         cmpld   cr0,r10,r14
 564         cmpld   cr1,r10,r15
 565         blt+    cr0,1f
 566         bge+    cr1,1f
 567
 568         /* here it looks like we got an inappropriate debug exception. */
 569         lis     r14,(DBSR_IC|DBSR_BT)@h         /* clear the event */
 570         rlwinm  r11,r11,0,~MSR_DE       /* clear DE in the DSRR1 value */
 571         mtspr   SPRN_DBSR,r14
 572         mtspr   SPRN_DSRR1,r11
 573         lwz     r10,PACA_EXDBG+EX_CR(r13)       /* restore registers */
 574         ld      r1,PACA_EXDBG+EX_R1(r13)
 575         ld      r14,PACA_EXDBG+EX_R14(r13)
 576         ld      r15,PACA_EXDBG+EX_R15(r13)
 577         mtcr    r10
 578         ld      r10,PACA_EXDBG+EX_R10(r13)      /* restore registers */
 579         ld      r11,PACA_EXDBG+EX_R11(r13)
 580         mfspr   r13,SPRN_SPRG_DBG_SCRATCH
 581         rfdi
 582
 583         /* Normal debug exception */
 584         /* XXX We only handle coming from userspace for now since we can't
 585          *     quite save properly an interrupted kernel state yet
 586          */
 587 1:      andi.   r14,r11,MSR_PR;         /* check for userspace again */
 588         beq     kernel_dbg_exc;         /* if from kernel mode */
 589
 590         /* Now we mash up things to make it look like we are coming on a
 591          * normal exception
 592          */
 593         mfspr   r15,SPRN_SPRG_DBG_SCRATCH
 594         mtspr   SPRN_SPRG_GEN_SCRATCH,r15
 595         mfspr   r14,SPRN_DBSR
 596         EXCEPTION_COMMON(0xd08, PACA_EXDBG, INTS_DISABLE)
 597         std     r14,_DSISR(r1)
 598         addi    r3,r1,STACK_FRAME_OVERHEAD
 599         mr      r4,r14
 600         ld      r14,PACA_EXDBG+EX_R14(r13)
 601         ld      r15,PACA_EXDBG+EX_R15(r13)
 602         bl      .save_nvgprs
 603         bl      .DebugException
 604         b       .ret_from_except
 605
 606         START_EXCEPTION(perfmon);
 607         NORMAL_EXCEPTION_PROLOG(0x260, BOOKE_INTERRUPT_PERFORMANCE_MONITOR,
 608                                 PROLOG_ADDITION_NONE)
 609         EXCEPTION_COMMON(0x260, PACA_EXGEN, INTS_DISABLE)
 610         CHECK_NAPPING()
 611         addi    r3,r1,STACK_FRAME_OVERHEAD
 612         bl      .performance_monitor_exception
 613         b       .ret_from_except_lite
 614
 615 /* Doorbell interrupt */
 616         MASKABLE_EXCEPTION(0x280, BOOKE_INTERRUPT_DOORBELL,
 617                            doorbell, .doorbell_exception, ACK_NONE)
 618
 619 /* Doorbell critical Interrupt */
 620         START_EXCEPTION(doorbell_crit);
 621         CRIT_EXCEPTION_PROLOG(0x2a0, BOOKE_INTERRUPT_DOORBELL_CRITICAL,
 622                               PROLOG_ADDITION_NONE)
 623 //      EXCEPTION_COMMON(0x2a0, PACA_EXCRIT, INTS_DISABLE)
 624 //      bl      special_reg_save_crit
 625 //      CHECK_NAPPING();
 626 //      addi    r3,r1,STACK_FRAME_OVERHEAD
 627 //      bl      .doorbell_critical_exception
 628 //      b       ret_from_crit_except
 629         b       .
 630
 631 /*
 632  *      Guest doorbell interrupt
 633  *      This general exception use GSRRx save/restore registers
 634  */
 635         START_EXCEPTION(guest_doorbell);
 636         GDBELL_EXCEPTION_PROLOG(0x2c0, BOOKE_INTERRUPT_GUEST_DBELL,
 637                                 PROLOG_ADDITION_NONE)
 638         EXCEPTION_COMMON(0x2c0, PACA_EXGEN, INTS_KEEP)
 639         addi    r3,r1,STACK_FRAME_OVERHEAD
 640         bl      .save_nvgprs
 641         INTS_RESTORE_HARD
 642         bl      .unknown_exception
 643         b       .ret_from_except
 644
 645 /* Guest Doorbell critical Interrupt */
 646         START_EXCEPTION(guest_doorbell_crit);
 647         CRIT_EXCEPTION_PROLOG(0x2e0, BOOKE_INTERRUPT_GUEST_DBELL_CRIT,
 648                               PROLOG_ADDITION_NONE)
 649 //      EXCEPTION_COMMON(0x2e0, PACA_EXCRIT, INTS_DISABLE)
 650 //      bl      special_reg_save_crit
 651 //      CHECK_NAPPING();
 652 //      addi    r3,r1,STACK_FRAME_OVERHEAD
 653 //      bl      .guest_doorbell_critical_exception
 654 //      b       ret_from_crit_except
 655         b       .
 656
 657 /* Hypervisor call */
 658         START_EXCEPTION(hypercall);
 659         NORMAL_EXCEPTION_PROLOG(0x310, BOOKE_INTERRUPT_HV_SYSCALL,
 660                                 PROLOG_ADDITION_NONE)
 661         EXCEPTION_COMMON(0x310, PACA_EXGEN, INTS_KEEP)
 662         addi    r3,r1,STACK_FRAME_OVERHEAD
 663         bl      .save_nvgprs
 664         INTS_RESTORE_HARD
 665         bl      .unknown_exception
 666         b       .ret_from_except
 667
 668 /* Embedded Hypervisor priviledged  */
 669         START_EXCEPTION(ehpriv);
 670         NORMAL_EXCEPTION_PROLOG(0x320, BOOKE_INTERRUPT_HV_PRIV,
 671                                 PROLOG_ADDITION_NONE)
 672         EXCEPTION_COMMON(0x320, PACA_EXGEN, INTS_KEEP)
 673         addi    r3,r1,STACK_FRAME_OVERHEAD
 674         bl      .save_nvgprs
 675         INTS_RESTORE_HARD
 676         bl      .unknown_exception
 677         b       .ret_from_except
 678
 679 /*
 680  * An interrupt came in while soft-disabled; We mark paca->irq_happened
 681  * accordingly and if the interrupt is level sensitive, we hard disable
 682  */
 683
 684 .macro masked_interrupt_book3e paca_irq full_mask
 685         lbz     r10,PACAIRQHAPPENED(r13)
 686         ori     r10,r10,\paca_irq
 687         stb     r10,PACAIRQHAPPENED(r13)
 688
 689         .if \full_mask == 1
 690         rldicl  r10,r11,48,1            /* clear MSR_EE */
 691         rotldi  r11,r10,16
 692         mtspr   SPRN_SRR1,r11
 693         .endif
 694
 695         lwz     r11,PACA_EXGEN+EX_CR(r13)
 696         mtcr    r11
 697         ld      r10,PACA_EXGEN+EX_R10(r13)
 698         ld      r11,PACA_EXGEN+EX_R11(r13)
 699         mfspr   r13,SPRN_SPRG_GEN_SCRATCH
 700         rfi
 701         b       .
 702 .endm
 703
 704 masked_interrupt_book3e_0x500:
 705         // XXX When adding support for EPR, use PACA_IRQ_EE_EDGE
 706         masked_interrupt_book3e PACA_IRQ_EE 1
 707
 708 masked_interrupt_book3e_0x900:
 709         ACK_DEC(r10);
 710         masked_interrupt_book3e PACA_IRQ_DEC 0
 711
 712 masked_interrupt_book3e_0x980:
 713         ACK_FIT(r10);
 714         masked_interrupt_book3e PACA_IRQ_DEC 0
 715
 716 masked_interrupt_book3e_0x280:
 717 masked_interrupt_book3e_0x2c0:
 718         masked_interrupt_book3e PACA_IRQ_DBELL 0
 719
 720 /*
 721  * Called from arch_local_irq_enable when an interrupt needs
 722  * to be resent. r3 contains either 0x500,0x900,0x260 or 0x280
 723  * to indicate the kind of interrupt. MSR:EE is already off.
 724  * We generate a stackframe like if a real interrupt had happened.
 725  *
 726  * Note: While MSR:EE is off, we need to make sure that _MSR
 727  * in the generated frame has EE set to 1 or the exception
 728  * handler will not properly re-enable them.
 729  */
 730 _GLOBAL(__replay_interrupt)
 731         /* We are going to jump to the exception common code which
 732          * will retrieve various register values from the PACA which
 733          * we don't give a damn about.
 734          */
 735         mflr    r10
 736         mfmsr   r11
 737         mfcr    r4
 738         mtspr   SPRN_SPRG_GEN_SCRATCH,r13;
 739         std     r1,PACA_EXGEN+EX_R1(r13);
 740         stw     r4,PACA_EXGEN+EX_CR(r13);
 741         ori     r11,r11,MSR_EE
 742         subi    r1,r1,INT_FRAME_SIZE;
 743         cmpwi   cr0,r3,0x500
 744         beq     exc_0x500_common
 745         cmpwi   cr0,r3,0x900
 746         beq     exc_0x900_common
 747         cmpwi   cr0,r3,0x280
 748         beq     exc_0x280_common
 749         blr
 750
 751
 752 /*
 753  * This is called from 0x300 and 0x400 handlers after the prologs with
 754  * r14 and r15 containing the fault address and error code, with the
 755  * original values stashed away in the PACA
 756  */
 757 storage_fault_common:
 758         std     r14,_DAR(r1)
 759         std     r15,_DSISR(r1)
 760         addi    r3,r1,STACK_FRAME_OVERHEAD
 761         mr      r4,r14
 762         mr      r5,r15
 763         ld      r14,PACA_EXGEN+EX_R14(r13)
 764         ld      r15,PACA_EXGEN+EX_R15(r13)
 765         bl      .do_page_fault
 766         cmpdi   r3,0
 767         bne-    1f
 768         b       .ret_from_except_lite
 769 1:      bl      .save_nvgprs
 770         mr      r5,r3
 771         addi    r3,r1,STACK_FRAME_OVERHEAD
 772         ld      r4,_DAR(r1)
 773         bl      .bad_page_fault
 774         b       .ret_from_except
 775
 776 /*
 777  * Alignment exception doesn't fit entirely in the 0x100 bytes so it
 778  * continues here.
 779  */
 780 alignment_more:
 781         std     r14,_DAR(r1)
 782         std     r15,_DSISR(r1)
 783         addi    r3,r1,STACK_FRAME_OVERHEAD
 784         ld      r14,PACA_EXGEN+EX_R14(r13)
 785         ld      r15,PACA_EXGEN+EX_R15(r13)
 786         bl      .save_nvgprs
 787         INTS_RESTORE_HARD
 788         bl      .alignment_exception
 789         b       .ret_from_except
 790
 791 /*
 792  * We branch here from entry_64.S for the last stage of the exception
 793  * return code path. MSR:EE is expected to be off at that point
 794  */
 795 _GLOBAL(exception_return_book3e)
 796         b       1f
 797
 798 /* This is the return from load_up_fpu fast path which could do with
 799  * less GPR restores in fact, but for now we have a single return path
 800  */
 801         .globl fast_exception_return
 802 fast_exception_return:
 803         wrteei  0
 804 1:      mr      r0,r13
 805         ld      r10,_MSR(r1)
 806         REST_4GPRS(2, r1)
 807         andi.   r6,r10,MSR_PR
 808         REST_2GPRS(6, r1)
 809         beq     1f
 810         ACCOUNT_CPU_USER_EXIT(r10, r11)
 811         ld      r0,GPR13(r1)
 812
 813 1:      stdcx.  r0,0,r1         /* to clear the reservation */
 814
 815         ld      r8,_CCR(r1)
 816         ld      r9,_LINK(r1)
 817         ld      r10,_CTR(r1)
 818         ld      r11,_XER(r1)
 819         mtcr    r8
 820         mtlr    r9
 821         mtctr   r10
 822         mtxer   r11
 823         REST_2GPRS(8, r1)
 824         ld      r10,GPR10(r1)
 825         ld      r11,GPR11(r1)
 826         ld      r12,GPR12(r1)
 827         mtspr   SPRN_SPRG_GEN_SCRATCH,r0
 828
 829         std     r10,PACA_EXGEN+EX_R10(r13);
 830         std     r11,PACA_EXGEN+EX_R11(r13);
 831         ld      r10,_NIP(r1)
 832         ld      r11,_MSR(r1)
 833         ld      r0,GPR0(r1)
 834         ld      r1,GPR1(r1)
 835         mtspr   SPRN_SRR0,r10
 836         mtspr   SPRN_SRR1,r11
 837         ld      r10,PACA_EXGEN+EX_R10(r13)
 838         ld      r11,PACA_EXGEN+EX_R11(r13)
 839         mfspr   r13,SPRN_SPRG_GEN_SCRATCH
 840         rfi
 841
 842 /*
 843  * Trampolines used when spotting a bad kernel stack pointer in
 844  * the exception entry code.
 845  *
 846  * TODO: move some bits like SRR0 read to trampoline, pass PACA
 847  * index around, etc... to handle crit & mcheck
 848  */
 849 BAD_STACK_TRAMPOLINE(0x000)
 850 BAD_STACK_TRAMPOLINE(0x100)
 851 BAD_STACK_TRAMPOLINE(0x200)
 852 BAD_STACK_TRAMPOLINE(0x220)
 853 BAD_STACK_TRAMPOLINE(0x260)
 854 BAD_STACK_TRAMPOLINE(0x280)
 855 BAD_STACK_TRAMPOLINE(0x2a0)
 856 BAD_STACK_TRAMPOLINE(0x2c0)
 857 BAD_STACK_TRAMPOLINE(0x2e0)
 858 BAD_STACK_TRAMPOLINE(0x300)
 859 BAD_STACK_TRAMPOLINE(0x310)
 860 BAD_STACK_TRAMPOLINE(0x320)
 861 BAD_STACK_TRAMPOLINE(0x400)
 862 BAD_STACK_TRAMPOLINE(0x500)
 863 BAD_STACK_TRAMPOLINE(0x600)
 864 BAD_STACK_TRAMPOLINE(0x700)
 865 BAD_STACK_TRAMPOLINE(0x800)
 866 BAD_STACK_TRAMPOLINE(0x900)
 867 BAD_STACK_TRAMPOLINE(0x980)
 868 BAD_STACK_TRAMPOLINE(0x9f0)
 869 BAD_STACK_TRAMPOLINE(0xa00)
 870 BAD_STACK_TRAMPOLINE(0xb00)
 871 BAD_STACK_TRAMPOLINE(0xc00)
 872 BAD_STACK_TRAMPOLINE(0xd00)
 873 BAD_STACK_TRAMPOLINE(0xd08)
 874 BAD_STACK_TRAMPOLINE(0xe00)
 875 BAD_STACK_TRAMPOLINE(0xf00)
 876 BAD_STACK_TRAMPOLINE(0xf20)
 877
 878         .globl  bad_stack_book3e
 879 bad_stack_book3e:
 880         /* XXX: Needs to make SPRN_SPRG_GEN depend on exception type */
 881         mfspr   r10,SPRN_SRR0;            /* read SRR0 before touching stack */
 882         ld      r1,PACAEMERGSP(r13)
 883         subi    r1,r1,64+INT_FRAME_SIZE
 884         std     r10,_NIP(r1)
 885         std     r11,_MSR(r1)
 886         ld      r10,PACA_EXGEN+EX_R1(r13) /* FIXME for crit & mcheck */
 887         lwz     r11,PACA_EXGEN+EX_CR(r13) /* FIXME for crit & mcheck */
 888         std     r10,GPR1(r1)
 889         std     r11,_CCR(r1)
 890         mfspr   r10,SPRN_DEAR
 891         mfspr   r11,SPRN_ESR
 892         std     r10,_DAR(r1)
 893         std     r11,_DSISR(r1)
 894         std     r0,GPR0(r1);            /* save r0 in stackframe */         \
 895         std     r2,GPR2(r1);            /* save r2 in stackframe */         \
 896         SAVE_4GPRS(3, r1);              /* save r3 - r6 in stackframe */    \
 897         SAVE_2GPRS(7, r1);              /* save r7, r8 in stackframe */     \
 898         std     r9,GPR9(r1);            /* save r9 in stackframe */         \
 899         ld      r3,PACA_EXGEN+EX_R10(r13);/* get back r10 */                \
 900         ld      r4,PACA_EXGEN+EX_R11(r13);/* get back r11 */                \
 901         mfspr   r5,SPRN_SPRG_GEN_SCRATCH;/* get back r13 XXX can be wrong */ \
 902         std     r3,GPR10(r1);           /* save r10 to stackframe */        \
 903         std     r4,GPR11(r1);           /* save r11 to stackframe */        \
 904         std     r12,GPR12(r1);          /* save r12 in stackframe */        \
 905         std     r5,GPR13(r1);           /* save it to stackframe */         \
 906         mflr    r10
 907         mfctr   r11
 908         mfxer   r12
 909         std     r10,_LINK(r1)
 910         std     r11,_CTR(r1)
 911         std     r12,_XER(r1)
 912         SAVE_10GPRS(14,r1)
 913         SAVE_8GPRS(24,r1)
 914         lhz     r12,PACA_TRAP_SAVE(r13)
 915         std     r12,_TRAP(r1)
 916         addi    r11,r1,INT_FRAME_SIZE
 917         std     r11,0(r1)
 918         li      r12,0
 919         std     r12,0(r11)
 920         ld      r2,PACATOC(r13)
 921 1:      addi    r3,r1,STACK_FRAME_OVERHEAD
 922         bl      .kernel_bad_stack
 923         b       1b
 924
 925 /*
 926  * Setup the initial TLB for a core. This current implementation
 927  * assume that whatever we are running off will not conflict with
 928  * the new mapping at PAGE_OFFSET.
 929  */
 930 _GLOBAL(initial_tlb_book3e)
 931
 932         /* Look for the first TLB with IPROT set */
 933         mfspr   r4,SPRN_TLB0CFG
 934         andi.   r3,r4,TLBnCFG_IPROT
 935         lis     r3,MAS0_TLBSEL(0)@h
 936         bne     found_iprot
 937
 938         mfspr   r4,SPRN_TLB1CFG
 939         andi.   r3,r4,TLBnCFG_IPROT
 940         lis     r3,MAS0_TLBSEL(1)@h
 941         bne     found_iprot
 942
 943         mfspr   r4,SPRN_TLB2CFG
 944         andi.   r3,r4,TLBnCFG_IPROT
 945         lis     r3,MAS0_TLBSEL(2)@h
 946         bne     found_iprot
 947
 948         lis     r3,MAS0_TLBSEL(3)@h
 949         mfspr   r4,SPRN_TLB3CFG
 950         /* fall through */
 951
 952 found_iprot:
 953         andi.   r5,r4,TLBnCFG_HES
 954         bne     have_hes
 955
 956         mflr    r8                              /* save LR */
 957 /* 1. Find the index of the entry we're executing in
 958  *
 959  * r3 = MAS0_TLBSEL (for the iprot array)
 960  * r4 = SPRN_TLBnCFG
 961  */
 962         bl      invstr                          /* Find our address */
 963 invstr: mflr    r6                              /* Make it accessible */
 964         mfmsr   r7
 965         rlwinm  r5,r7,27,31,31                  /* extract MSR[IS] */
 966         mfspr   r7,SPRN_PID
 967         slwi    r7,r7,16
 968         or      r7,r7,r5
 969         mtspr   SPRN_MAS6,r7
 970         tlbsx   0,r6                            /* search MSR[IS], SPID=PID */
 971
 972         mfspr   r3,SPRN_MAS0
 973         rlwinm  r5,r3,16,20,31                  /* Extract MAS0(Entry) */
 974
 975         mfspr   r7,SPRN_MAS1                    /* Insure IPROT set */
 976         oris    r7,r7,MAS1_IPROT@h
 977         mtspr   SPRN_MAS1,r7
 978         tlbwe
 979
 980 /* 2. Invalidate all entries except the entry we're executing in
 981  *
 982  * r3 = MAS0 w/TLBSEL & ESEL for the entry we are running in
 983  * r4 = SPRN_TLBnCFG
 984  * r5 = ESEL of entry we are running in
 985  */
 986         andi.   r4,r4,TLBnCFG_N_ENTRY           /* Extract # entries */
 987         li      r6,0                            /* Set Entry counter to 0 */
 988 1:      mr      r7,r3                           /* Set MAS0(TLBSEL) */
 989         rlwimi  r7,r6,16,4,15                   /* Setup MAS0 = TLBSEL | ESEL(r6) */
 990         mtspr   SPRN_MAS0,r7
 991         tlbre
 992         mfspr   r7,SPRN_MAS1
 993         rlwinm  r7,r7,0,2,31                    /* Clear MAS1 Valid and IPROT */
 994         cmpw    r5,r6
 995         beq     skpinv                          /* Dont update the current execution TLB */
 996         mtspr   SPRN_MAS1,r7
 997         tlbwe
 998         isync
 999 skpinv: addi    r6,r6,1                         /* Increment */
1000         cmpw    r6,r4                           /* Are we done? */
1001         bne     1b                              /* If not, repeat */
1002
1003         /* Invalidate all TLBs */
1004         PPC_TLBILX_ALL(0,R0)
1005         sync
1006         isync
1007
1008 /* 3. Setup a temp mapping and jump to it
1009  *
1010  * r3 = MAS0 w/TLBSEL & ESEL for the entry we are running in
1011  * r5 = ESEL of entry we are running in
1012  */
1013         andi.   r7,r5,0x1       /* Find an entry not used and is non-zero */
1014         addi    r7,r7,0x1
1015         mr      r4,r3           /* Set MAS0(TLBSEL) = 1 */
1016         mtspr   SPRN_MAS0,r4
1017         tlbre
1018
1019         rlwimi  r4,r7,16,4,15   /* Setup MAS0 = TLBSEL | ESEL(r7) */
1020         mtspr   SPRN_MAS0,r4
1021
1022         mfspr   r7,SPRN_MAS1
1023         xori    r6,r7,MAS1_TS           /* Setup TMP mapping in the other Address space */
1024         mtspr   SPRN_MAS1,r6
1025
1026         tlbwe
1027
1028         mfmsr   r6
1029         xori    r6,r6,MSR_IS
1030         mtspr   SPRN_SRR1,r6
1031         bl      1f              /* Find our address */
1032 1:      mflr    r6
1033         addi    r6,r6,(2f - 1b)
1034         mtspr   SPRN_SRR0,r6
1035         rfi
1036 2:
1037
1038 /* 4. Clear out PIDs & Search info
1039  *
1040  * r3 = MAS0 w/TLBSEL & ESEL for the entry we started in
1041  * r4 = MAS0 w/TLBSEL & ESEL for the temp mapping
1042  * r5 = MAS3
1043  */
1044         li      r6,0
1045         mtspr   SPRN_MAS6,r6
1046         mtspr   SPRN_PID,r6
1047
1048 /* 5. Invalidate mapping we started in
1049  *
1050  * r3 = MAS0 w/TLBSEL & ESEL for the entry we started in
1051  * r4 = MAS0 w/TLBSEL & ESEL for the temp mapping
1052  * r5 = MAS3
1053  */
1054         mtspr   SPRN_MAS0,r3
1055         tlbre
1056         mfspr   r6,SPRN_MAS1
1057         rlwinm  r6,r6,0,2,0     /* clear IPROT */
1058         mtspr   SPRN_MAS1,r6
1059         tlbwe
1060
1061         /* Invalidate TLB1 */
1062         PPC_TLBILX_ALL(0,R0)
1063         sync
1064         isync
1065
1066 /* The mapping only needs to be cache-coherent on SMP */
1067 #ifdef CONFIG_SMP
1068 #define M_IF_SMP        MAS2_M
1069 #else
1070 #define M_IF_SMP        0
1071 #endif
1072
1073 /* 6. Setup KERNELBASE mapping in TLB[0]
1074  *
1075  * r3 = MAS0 w/TLBSEL & ESEL for the entry we started in
1076  * r4 = MAS0 w/TLBSEL & ESEL for the temp mapping
1077  * r5 = MAS3
1078  */
1079         rlwinm  r3,r3,0,16,3    /* clear ESEL */
1080         mtspr   SPRN_MAS0,r3
1081         lis     r6,(MAS1_VALID|MAS1_IPROT)@h
1082         ori     r6,r6,(MAS1_TSIZE(BOOK3E_PAGESZ_1GB))@l
1083         mtspr   SPRN_MAS1,r6
1084
1085         LOAD_REG_IMMEDIATE(r6, PAGE_OFFSET | M_IF_SMP)
1086         mtspr   SPRN_MAS2,r6
1087
1088         rlwinm  r5,r5,0,0,25
1089         ori     r5,r5,MAS3_SR | MAS3_SW | MAS3_SX
1090         mtspr   SPRN_MAS3,r5
1091         li      r5,-1
1092         rlwinm  r5,r5,0,0,25
1093
1094         tlbwe
1095
1096 /* 7. Jump to KERNELBASE mapping
1097  *
1098  * r4 = MAS0 w/TLBSEL & ESEL for the temp mapping
1099  */
1100         /* Now we branch the new virtual address mapped by this entry */
1101         LOAD_REG_IMMEDIATE(r6,2f)
1102         lis     r7,MSR_KERNEL@h
1103         ori     r7,r7,MSR_KERNEL@l
1104         mtspr   SPRN_SRR0,r6
1105         mtspr   SPRN_SRR1,r7
1106         rfi                             /* start execution out of TLB1[0] entry */
1107 2:
1108
1109 /* 8. Clear out the temp mapping
1110  *
1111  * r4 = MAS0 w/TLBSEL & ESEL for the entry we are running in
1112  */
1113         mtspr   SPRN_MAS0,r4
1114         tlbre
1115         mfspr   r5,SPRN_MAS1
1116         rlwinm  r5,r5,0,2,0     /* clear IPROT */
1117         mtspr   SPRN_MAS1,r5
1118         tlbwe
1119
1120         /* Invalidate TLB1 */
1121         PPC_TLBILX_ALL(0,R0)
1122         sync
1123         isync
1124
1125         /* We translate LR and return */
1126         tovirt(r8,r8)
1127         mtlr    r8
1128         blr
1129
1130 have_hes:
1131         /* Setup MAS 0,1,2,3 and 7 for tlbwe of a 1G entry that maps the
1132          * kernel linear mapping. We also set MAS8 once for all here though
1133          * that will have to be made dependent on whether we are running under
1134          * a hypervisor I suppose.
1135          */
1136
1137         /* BEWARE, MAGIC
1138          * This code is called as an ordinary function on the boot CPU. But to
1139          * avoid duplication, this code is also used in SCOM bringup of
1140          * secondary CPUs. We read the code between the initial_tlb_code_start
1141          * and initial_tlb_code_end labels one instruction at a time and RAM it
1142          * into the new core via SCOM. That doesn't process branches, so there
1143          * must be none between those two labels. It also means if this code
1144          * ever takes any parameters, the SCOM code must also be updated to
1145          * provide them.
1146          */
1147         .globl a2_tlbinit_code_start
1148 a2_tlbinit_code_start:
1149
1150         ori     r11,r3,MAS0_WQ_ALLWAYS
1151         oris    r11,r11,MAS0_ESEL(3)@h /* Use way 3: workaround A2 erratum 376 */
1152         mtspr   SPRN_MAS0,r11
1153         lis     r3,(MAS1_VALID | MAS1_IPROT)@h
1154         ori     r3,r3,BOOK3E_PAGESZ_1GB << MAS1_TSIZE_SHIFT
1155         mtspr   SPRN_MAS1,r3
1156         LOAD_REG_IMMEDIATE(r3, PAGE_OFFSET | MAS2_M)
1157         mtspr   SPRN_MAS2,r3
1158         li      r3,MAS3_SR | MAS3_SW | MAS3_SX
1159         mtspr   SPRN_MAS7_MAS3,r3
1160         li      r3,0
1161         mtspr   SPRN_MAS8,r3
1162
1163         /* Write the TLB entry */
1164         tlbwe
1165
1166         .globl a2_tlbinit_after_linear_map
1167 a2_tlbinit_after_linear_map:
1168
1169         /* Now we branch the new virtual address mapped by this entry */
1170         LOAD_REG_IMMEDIATE(r3,1f)
1171         mtctr   r3
1172         bctr
1173
1174 1:      /* We are now running at PAGE_OFFSET, clean the TLB of everything
1175          * else (including IPROTed things left by firmware)
1176          * r4 = TLBnCFG
1177          * r3 = current address (more or less)
1178          */
1179
1180         li      r5,0
1181         mtspr   SPRN_MAS6,r5
1182         tlbsx   0,r3
1183
1184         rlwinm  r9,r4,0,TLBnCFG_N_ENTRY
1185         rlwinm  r10,r4,8,0xff
1186         addi    r10,r10,-1      /* Get inner loop mask */
1187
1188         li      r3,1
1189
1190         mfspr   r5,SPRN_MAS1
1191         rlwinm  r5,r5,0,(~(MAS1_VALID|MAS1_IPROT))
1192
1193         mfspr   r6,SPRN_MAS2
1194         rldicr  r6,r6,0,51              /* Extract EPN */
1195
1196         mfspr   r7,SPRN_MAS0
1197         rlwinm  r7,r7,0,0xffff0fff      /* Clear HES and WQ */
1198
1199         rlwinm  r8,r7,16,0xfff          /* Extract ESEL */
1200
1201 2:      add     r4,r3,r8
1202         and     r4,r4,r10
1203
1204         rlwimi  r7,r4,16,MAS0_ESEL_MASK
1205
1206         mtspr   SPRN_MAS0,r7
1207         mtspr   SPRN_MAS1,r5
1208         mtspr   SPRN_MAS2,r6
1209         tlbwe
1210
1211         addi    r3,r3,1
1212         and.    r4,r3,r10
1213
1214         bne     3f
1215         addis   r6,r6,(1<<30)@h
1216 3:
1217         cmpw    r3,r9
1218         blt     2b
1219
1220         .globl  a2_tlbinit_after_iprot_flush
1221 a2_tlbinit_after_iprot_flush:
1222
1223 #ifdef CONFIG_PPC_EARLY_DEBUG_WSP
1224         /* Now establish early debug mappings if applicable */
1225         /* Restore the MAS0 we used for linear mapping load */
1226         mtspr   SPRN_MAS0,r11
1227
1228         lis     r3,(MAS1_VALID | MAS1_IPROT)@h
1229         ori     r3,r3,(BOOK3E_PAGESZ_4K << MAS1_TSIZE_SHIFT)
1230         mtspr   SPRN_MAS1,r3
1231         LOAD_REG_IMMEDIATE(r3, WSP_UART_VIRT | MAS2_I | MAS2_G)
1232         mtspr   SPRN_MAS2,r3
1233         LOAD_REG_IMMEDIATE(r3, WSP_UART_PHYS | MAS3_SR | MAS3_SW)
1234         mtspr   SPRN_MAS7_MAS3,r3
1235         /* re-use the MAS8 value from the linear mapping */
1236         tlbwe
1237 #endif /* CONFIG_PPC_EARLY_DEBUG_WSP */
1238
1239         PPC_TLBILX(0,0,R0)
1240         sync
1241         isync
1242
1243         .globl a2_tlbinit_code_end
1244 a2_tlbinit_code_end:
1245
1246         /* We translate LR and return */
1247         mflr    r3
1248         tovirt(r3,r3)
1249         mtlr    r3
1250         blr
1251
1252 /*
1253  * Main entry (boot CPU, thread 0)
1254  *
1255  * We enter here from head_64.S, possibly after the prom_init trampoline
1256  * with r3 and r4 already saved to r31 and 30 respectively and in 64 bits
1257  * mode. Anything else is as it was left by the bootloader
1258  *
1259  * Initial requirements of this port:
1260  *
1261  * - Kernel loaded at 0 physical
1262  * - A good lump of memory mapped 0:0 by UTLB entry 0
1263  * - MSR:IS & MSR:DS set to 0
1264  *
1265  * Note that some of the above requirements will be relaxed in the future
1266  * as the kernel becomes smarter at dealing with different initial conditions
1267  * but for now you have to be careful
1268  */
1269 _GLOBAL(start_initialization_book3e)
1270         mflr    r28
1271
1272         /* First, we need to setup some initial TLBs to map the kernel
1273          * text, data and bss at PAGE_OFFSET. We don't have a real mode
1274          * and always use AS 0, so we just set it up to match our link
1275          * address and never use 0 based addresses.
1276          */
1277         bl      .initial_tlb_book3e
1278
1279         /* Init global core bits */
1280         bl      .init_core_book3e
1281
1282         /* Init per-thread bits */
1283         bl      .init_thread_book3e
1284
1285         /* Return to common init code */
1286         tovirt(r28,r28)
1287         mtlr    r28
1288         blr
1289
1290
1291 /*
1292  * Secondary core/processor entry
1293  *
1294  * This is entered for thread 0 of a secondary core, all other threads
1295  * are expected to be stopped. It's similar to start_initialization_book3e
1296  * except that it's generally entered from the holding loop in head_64.S
1297  * after CPUs have been gathered by Open Firmware.
1298  *
1299  * We assume we are in 32 bits mode running with whatever TLB entry was
1300  * set for us by the firmware or POR engine.
1301  */
1302 _GLOBAL(book3e_secondary_core_init_tlb_set)
1303         li      r4,1
1304         b       .generic_secondary_smp_init
1305
1306 _GLOBAL(book3e_secondary_core_init)
1307         mflr    r28
1308
1309         /* Do we need to setup initial TLB entry ? */
1310         cmplwi  r4,0
1311         bne     2f
1312
1313         /* Setup TLB for this core */
1314         bl      .initial_tlb_book3e
1315
1316         /* We can return from the above running at a different
1317          * address, so recalculate r2 (TOC)
1318          */
1319         bl      .relative_toc
1320
1321         /* Init global core bits */
1322 2:      bl      .init_core_book3e
1323
1324         /* Init per-thread bits */
1325 3:      bl      .init_thread_book3e
1326
1327         /* Return to common init code at proper virtual address.
1328          *
1329          * Due to various previous assumptions, we know we entered this
1330          * function at either the final PAGE_OFFSET mapping or using a
1331          * 1:1 mapping at 0, so we don't bother doing a complicated check
1332          * here, we just ensure the return address has the right top bits.
1333          *
1334          * Note that if we ever want to be smarter about where we can be
1335          * started from, we have to be careful that by the time we reach
1336          * the code below we may already be running at a different location
1337          * than the one we were called from since initial_tlb_book3e can
1338          * have moved us already.
1339          */
1340         cmpdi   cr0,r28,0
1341         blt     1f
1342         lis     r3,PAGE_OFFSET@highest
1343         sldi    r3,r3,32
1344         or      r28,r28,r3
1345 1:      mtlr    r28
1346         blr
1347
1348 _GLOBAL(book3e_secondary_thread_init)
1349         mflr    r28
1350         b       3b
1351
1352 _STATIC(init_core_book3e)
1353         /* Establish the interrupt vector base */
1354         LOAD_REG_IMMEDIATE(r3, interrupt_base_book3e)
1355         mtspr   SPRN_IVPR,r3
1356         sync
1357         blr
1358
1359 _STATIC(init_thread_book3e)
1360         lis     r3,(SPRN_EPCR_ICM | SPRN_EPCR_GICM)@h
1361         mtspr   SPRN_EPCR,r3
1362
1363         /* Make sure interrupts are off */
1364         wrteei  0
1365
1366         /* disable all timers and clear out status */
1367         li      r3,0
1368         mtspr   SPRN_TCR,r3
1369         mfspr   r3,SPRN_TSR
1370         mtspr   SPRN_TSR,r3
1371
1372         blr
1373
1374 _GLOBAL(__setup_base_ivors)
1375         SET_IVOR(0, 0x020) /* Critical Input */
1376         SET_IVOR(1, 0x000) /* Machine Check */
1377         SET_IVOR(2, 0x060) /* Data Storage */
1378         SET_IVOR(3, 0x080) /* Instruction Storage */
1379         SET_IVOR(4, 0x0a0) /* External Input */
1380         SET_IVOR(5, 0x0c0) /* Alignment */
1381         SET_IVOR(6, 0x0e0) /* Program */
1382         SET_IVOR(7, 0x100) /* FP Unavailable */
1383         SET_IVOR(8, 0x120) /* System Call */
1384         SET_IVOR(9, 0x140) /* Auxiliary Processor Unavailable */
1385         SET_IVOR(10, 0x160) /* Decrementer */
1386         SET_IVOR(11, 0x180) /* Fixed Interval Timer */
1387         SET_IVOR(12, 0x1a0) /* Watchdog Timer */
1388         SET_IVOR(13, 0x1c0) /* Data TLB Error */
1389         SET_IVOR(14, 0x1e0) /* Instruction TLB Error */
1390         SET_IVOR(15, 0x040) /* Debug */
1391
1392         sync
1393
1394         blr
1395
1396 _GLOBAL(setup_altivec_ivors)
1397         SET_IVOR(32, 0x200) /* AltiVec Unavailable */
1398         SET_IVOR(33, 0x220) /* AltiVec Assist */
1399         blr
1400
1401 _GLOBAL(setup_perfmon_ivor)
1402         SET_IVOR(35, 0x260) /* Performance Monitor */
1403         blr
1404
1405 _GLOBAL(setup_doorbell_ivors)
1406         SET_IVOR(36, 0x280) /* Processor Doorbell */
1407         SET_IVOR(37, 0x2a0) /* Processor Doorbell Crit */
1408         blr
1409
1410 _GLOBAL(setup_ehv_ivors)
1411         SET_IVOR(40, 0x300) /* Embedded Hypervisor System Call */
1412         SET_IVOR(41, 0x320) /* Embedded Hypervisor Privilege */
1413         SET_IVOR(38, 0x2c0) /* Guest Processor Doorbell */
1414         SET_IVOR(39, 0x2e0) /* Guest Processor Doorbell Crit/MC */
1415         blr