arch/s390/kernel/entry64.S

   1 /*
   2  *    S390 low-level entry points.
   3  *
   4  *    Copyright IBM Corp. 1999, 2012
   5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   6  *               Hartmut Penner (hp@de.ibm.com),
   7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
   9  */
  10
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/processor.h>
  14 #include <asm/cache.h>
  15 #include <asm/errno.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20 #include <asm/page.h>
  21 #include <asm/sigp.h>
  22 #include <asm/irq.h>
  23
  24 __PT_R0      =  __PT_GPRS
  25 __PT_R1      =  __PT_GPRS + 8
  26 __PT_R2      =  __PT_GPRS + 16
  27 __PT_R3      =  __PT_GPRS + 24
  28 __PT_R4      =  __PT_GPRS + 32
  29 __PT_R5      =  __PT_GPRS + 40
  30 __PT_R6      =  __PT_GPRS + 48
  31 __PT_R7      =  __PT_GPRS + 56
  32 __PT_R8      =  __PT_GPRS + 64
  33 __PT_R9      =  __PT_GPRS + 72
  34 __PT_R10     =  __PT_GPRS + 80
  35 __PT_R11     =  __PT_GPRS + 88
  36 __PT_R12     =  __PT_GPRS + 96
  37 __PT_R13     =  __PT_GPRS + 104
  38 __PT_R14     =  __PT_GPRS + 112
  39 __PT_R15     =  __PT_GPRS + 120
  40
  41 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  42 STACK_SIZE  = 1 << STACK_SHIFT
  43 STACK_INIT = STACK_SIZE - STACK_FRAME_OVERHEAD - __PT_SIZE
  44
  45 _TIF_WORK       = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED)
  46 _TIF_TRACE      = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
  47                    _TIF_SYSCALL_TRACEPOINT)
  48 _CIF_WORK       = (_CIF_MCCK_PENDING | _CIF_ASCE)
  49 _PIF_WORK       = (_PIF_PER_TRAP)
  50
  51 #define BASED(name) name-system_call(%r13)
  52
  53         .macro  TRACE_IRQS_ON
  54 #ifdef CONFIG_TRACE_IRQFLAGS
  55         basr    %r2,%r0
  56         brasl   %r14,trace_hardirqs_on_caller
  57 #endif
  58         .endm
  59
  60         .macro  TRACE_IRQS_OFF
  61 #ifdef CONFIG_TRACE_IRQFLAGS
  62         basr    %r2,%r0
  63         brasl   %r14,trace_hardirqs_off_caller
  64 #endif
  65         .endm
  66
  67         .macro  LOCKDEP_SYS_EXIT
  68 #ifdef CONFIG_LOCKDEP
  69         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
  70         jz      .+10
  71         brasl   %r14,lockdep_sys_exit
  72 #endif
  73         .endm
  74
  75         .macro LPP newpp
  76 #if IS_ENABLED(CONFIG_KVM)
  77         tm      __LC_MACHINE_FLAGS+6,0x20       # MACHINE_FLAG_LPP
  78         jz      .+8
  79         .insn   s,0xb2800000,\newpp
  80 #endif
  81         .endm
  82
  83         .macro  HANDLE_SIE_INTERCEPT scratch,reason
  84 #if IS_ENABLED(CONFIG_KVM)
  85         tmhh    %r8,0x0001              # interrupting from user ?
  86         jnz     .+62
  87         lgr     \scratch,%r9
  88         slg     \scratch,BASED(.Lsie_critical)
  89         clg     \scratch,BASED(.Lsie_critical_length)
  90         .if     \reason==1
  91         # Some program interrupts are suppressing (e.g. protection).
  92         # We must also check the instruction after SIE in that case.
  93         # do_protection_exception will rewind to rewind_pad
  94         jh      .+42
  95         .else
  96         jhe     .+42
  97         .endif
  98         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
  99         LPP     __SF_EMPTY+16(%r15)             # set host id
 100         ni      __SIE_PROG0C+3(%r14),0xfe       # no longer in SIE
 101         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 102         larl    %r9,sie_exit                    # skip forward to sie_exit
 103         mvi     __SF_EMPTY+31(%r15),\reason     # set exit reason
 104 #endif
 105         .endm
 106
 107         .macro  CHECK_STACK stacksize,savearea
 108 #ifdef CONFIG_CHECK_STACK
 109         tml     %r15,\stacksize - CONFIG_STACK_GUARD
 110         lghi    %r14,\savearea
 111         jz      stack_overflow
 112 #endif
 113         .endm
 114
 115         .macro  SWITCH_ASYNC savearea,stack,shift
 116         tmhh    %r8,0x0001              # interrupting from user ?
 117         jnz     1f
 118         lgr     %r14,%r9
 119         slg     %r14,BASED(.Lcritical_start)
 120         clg     %r14,BASED(.Lcritical_length)
 121         jhe     0f
 122         lghi    %r11,\savearea          # inside critical section, do cleanup
 123         brasl   %r14,cleanup_critical
 124         tmhh    %r8,0x0001              # retest problem state after cleanup
 125         jnz     1f
 126 0:      lg      %r14,\stack             # are we already on the target stack?
 127         slgr    %r14,%r15
 128         srag    %r14,%r14,\shift
 129         jnz     1f
 130         CHECK_STACK 1<<\shift,\savearea
 131         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 132         j       2f
 133 1:      lg      %r15,\stack             # load target stack
 134 2:      la      %r11,STACK_FRAME_OVERHEAD(%r15)
 135         .endm
 136
 137         .macro UPDATE_VTIME scratch,enter_timer
 138         lg      \scratch,__LC_EXIT_TIMER
 139         slg     \scratch,\enter_timer
 140         alg     \scratch,__LC_USER_TIMER
 141         stg     \scratch,__LC_USER_TIMER
 142         lg      \scratch,__LC_LAST_UPDATE_TIMER
 143         slg     \scratch,__LC_EXIT_TIMER
 144         alg     \scratch,__LC_SYSTEM_TIMER
 145         stg     \scratch,__LC_SYSTEM_TIMER
 146         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
 147         .endm
 148
 149         .macro  LAST_BREAK scratch
 150         srag    \scratch,%r10,23
 151         jz      .+10
 152         stg     %r10,__TI_last_break(%r12)
 153         .endm
 154
 155         .macro REENABLE_IRQS
 156         stg     %r8,__LC_RETURN_PSW
 157         ni      __LC_RETURN_PSW,0xbf
 158         ssm     __LC_RETURN_PSW
 159         .endm
 160
 161         .macro STCK savearea
 162 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
 163         .insn   s,0xb27c0000,\savearea          # store clock fast
 164 #else
 165         .insn   s,0xb2050000,\savearea          # store clock
 166 #endif
 167         .endm
 168
 169         .section .kprobes.text, "ax"
 170
 171 /*
 172  * Scheduler resume function, called by switch_to
 173  *  gpr2 = (task_struct *) prev
 174  *  gpr3 = (task_struct *) next
 175  * Returns:
 176  *  gpr2 = prev
 177  */
 178 ENTRY(__switch_to)
 179         stmg    %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 180         stg     %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
 181         lg      %r4,__THREAD_info(%r2)          # get thread_info of prev
 182         lg      %r5,__THREAD_info(%r3)          # get thread_info of next
 183         lgr     %r15,%r5
 184         aghi    %r15,STACK_INIT                 # end of kernel stack of next
 185         stg     %r3,__LC_CURRENT                # store task struct of next
 186         stg     %r5,__LC_THREAD_INFO            # store thread info of next
 187         stg     %r15,__LC_KERNEL_STACK          # store end of kernel stack
 188         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 189         mvc     __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
 190         lg      %r15,__THREAD_ksp(%r3)          # load kernel stack of next
 191         lmg     %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 192         br      %r14
 193
 194 __critical_start:
 195 /*
 196  * SVC interrupt handler routine. System calls are synchronous events and
 197  * are executed with interrupts enabled.
 198  */
 199
 200 ENTRY(system_call)
 201         stpt    __LC_SYNC_ENTER_TIMER
 202 sysc_stmg:
 203         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 204         lg      %r10,__LC_LAST_BREAK
 205         lg      %r12,__LC_THREAD_INFO
 206         lghi    %r14,_PIF_SYSCALL
 207 sysc_per:
 208         lg      %r15,__LC_KERNEL_STACK
 209         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
 210 sysc_vtime:
 211         UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
 212         LAST_BREAK %r13
 213         stmg    %r0,%r7,__PT_R0(%r11)
 214         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 215         mvc     __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
 216         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
 217         stg     %r14,__PT_FLAGS(%r11)
 218 sysc_do_svc:
 219         lg      %r10,__TI_sysc_table(%r12)      # address of system call table
 220         llgh    %r8,__PT_INT_CODE+2(%r11)
 221         slag    %r8,%r8,2                       # shift and test for svc 0
 222         jnz     sysc_nr_ok
 223         # svc 0: system call number in %r1
 224         llgfr   %r1,%r1                         # clear high word in r1
 225         cghi    %r1,NR_syscalls
 226         jnl     sysc_nr_ok
 227         sth     %r1,__PT_INT_CODE+2(%r11)
 228         slag    %r8,%r1,2
 229 sysc_nr_ok:
 230         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 231         stg     %r2,__PT_ORIG_GPR2(%r11)
 232         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 233         lgf     %r9,0(%r8,%r10)                 # get system call add.
 234         tm      __TI_flags+7(%r12),_TIF_TRACE
 235         jnz     sysc_tracesys
 236         basr    %r14,%r9                        # call sys_xxxx
 237         stg     %r2,__PT_R2(%r11)               # store return value
 238
 239 sysc_return:
 240         LOCKDEP_SYS_EXIT
 241 sysc_tif:
 242         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
 243         jno     sysc_restore
 244         tm      __PT_FLAGS+7(%r11),_PIF_WORK
 245         jnz     sysc_work
 246         tm      __TI_flags+7(%r12),_TIF_WORK
 247         jnz     sysc_work                       # check for work
 248         tm      __LC_CPU_FLAGS+7,_CIF_WORK
 249         jnz     sysc_work
 250 sysc_restore:
 251         lg      %r14,__LC_VDSO_PER_CPU
 252         lmg     %r0,%r10,__PT_R0(%r11)
 253         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 254         stpt    __LC_EXIT_TIMER
 255         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 256         lmg     %r11,%r15,__PT_R11(%r11)
 257         lpswe   __LC_RETURN_PSW
 258 sysc_done:
 259
 260 #
 261 # One of the work bits is on. Find out which one.
 262 #
 263 sysc_work:
 264         tm      __LC_CPU_FLAGS+7,_CIF_MCCK_PENDING
 265         jo      sysc_mcck_pending
 266         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 267         jo      sysc_reschedule
 268         tm      __PT_FLAGS+7(%r11),_PIF_PER_TRAP
 269         jo      sysc_singlestep
 270         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 271         jo      sysc_sigpending
 272         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 273         jo      sysc_notify_resume
 274         tm      __LC_CPU_FLAGS+7,_CIF_ASCE
 275         jo      sysc_uaccess
 276         j       sysc_return             # beware of critical section cleanup
 277
 278 #
 279 # _TIF_NEED_RESCHED is set, call schedule
 280 #
 281 sysc_reschedule:
 282         larl    %r14,sysc_return
 283         jg      schedule
 284
 285 #
 286 # _CIF_MCCK_PENDING is set, call handler
 287 #
 288 sysc_mcck_pending:
 289         larl    %r14,sysc_return
 290         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 291
 292 #
 293 # _CIF_ASCE is set, load user space asce
 294 #
 295 sysc_uaccess:
 296         ni      __LC_CPU_FLAGS+7,255-_CIF_ASCE
 297         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 298         j       sysc_return
 299
 300 #
 301 # _TIF_SIGPENDING is set, call do_signal
 302 #
 303 sysc_sigpending:
 304         lgr     %r2,%r11                # pass pointer to pt_regs
 305         brasl   %r14,do_signal
 306         tm      __PT_FLAGS+7(%r11),_PIF_SYSCALL
 307         jno     sysc_return
 308         lmg     %r2,%r7,__PT_R2(%r11)   # load svc arguments
 309         lg      %r10,__TI_sysc_table(%r12)      # address of system call table
 310         lghi    %r8,0                   # svc 0 returns -ENOSYS
 311         llgh    %r1,__PT_INT_CODE+2(%r11)       # load new svc number
 312         cghi    %r1,NR_syscalls
 313         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
 314         slag    %r8,%r1,2
 315         j       sysc_nr_ok              # restart svc
 316
 317 #
 318 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 319 #
 320 sysc_notify_resume:
 321         lgr     %r2,%r11                # pass pointer to pt_regs
 322         larl    %r14,sysc_return
 323         jg      do_notify_resume
 324
 325 #
 326 # _PIF_PER_TRAP is set, call do_per_trap
 327 #
 328 sysc_singlestep:
 329         ni      __PT_FLAGS+7(%r11),255-_PIF_PER_TRAP
 330         lgr     %r2,%r11                # pass pointer to pt_regs
 331         larl    %r14,sysc_return
 332         jg      do_per_trap
 333
 334 #
 335 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 336 # and after the system call
 337 #
 338 sysc_tracesys:
 339         lgr     %r2,%r11                # pass pointer to pt_regs
 340         la      %r3,0
 341         llgh    %r0,__PT_INT_CODE+2(%r11)
 342         stg     %r0,__PT_R2(%r11)
 343         brasl   %r14,do_syscall_trace_enter
 344         lghi    %r0,NR_syscalls
 345         clgr    %r0,%r2
 346         jnh     sysc_tracenogo
 347         sllg    %r8,%r2,2
 348         lgf     %r9,0(%r8,%r10)
 349 sysc_tracego:
 350         lmg     %r3,%r7,__PT_R3(%r11)
 351         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 352         lg      %r2,__PT_ORIG_GPR2(%r11)
 353         basr    %r14,%r9                # call sys_xxx
 354         stg     %r2,__PT_R2(%r11)       # store return value
 355 sysc_tracenogo:
 356         tm      __TI_flags+7(%r12),_TIF_TRACE
 357         jz      sysc_return
 358         lgr     %r2,%r11                # pass pointer to pt_regs
 359         larl    %r14,sysc_return
 360         jg      do_syscall_trace_exit
 361
 362 #
 363 # a new process exits the kernel with ret_from_fork
 364 #
 365 ENTRY(ret_from_fork)
 366         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 367         lg      %r12,__LC_THREAD_INFO
 368         brasl   %r14,schedule_tail
 369         TRACE_IRQS_ON
 370         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 371         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
 372         jne     sysc_tracenogo
 373         # it's a kernel thread
 374         lmg     %r9,%r10,__PT_R9(%r11)  # load gprs
 375 ENTRY(kernel_thread_starter)
 376         la      %r2,0(%r10)
 377         basr    %r14,%r9
 378         j       sysc_tracenogo
 379
 380 /*
 381  * Program check handler routine
 382  */
 383
 384 ENTRY(pgm_check_handler)
 385         stpt    __LC_SYNC_ENTER_TIMER
 386         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 387         lg      %r10,__LC_LAST_BREAK
 388         lg      %r12,__LC_THREAD_INFO
 389         larl    %r13,system_call
 390         lmg     %r8,%r9,__LC_PGM_OLD_PSW
 391         HANDLE_SIE_INTERCEPT %r14,1
 392         tmhh    %r8,0x0001              # test problem state bit
 393         jnz     1f                      # -> fault in user space
 394         tmhh    %r8,0x4000              # PER bit set in old PSW ?
 395         jnz     0f                      # -> enabled, can't be a double fault
 396         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 397         jnz     pgm_svcper              # -> single stepped svc
 398 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
 399         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 400         j       2f
 401 1:      UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
 402         LAST_BREAK %r14
 403         lg      %r15,__LC_KERNEL_STACK
 404         lg      %r14,__TI_task(%r12)
 405         lghi    %r13,__LC_PGM_TDB
 406         tm      __LC_PGM_ILC+2,0x02     # check for transaction abort
 407         jz      2f
 408         mvc     __THREAD_trap_tdb(256,%r14),0(%r13)
 409 2:      la      %r11,STACK_FRAME_OVERHEAD(%r15)
 410         stmg    %r0,%r7,__PT_R0(%r11)
 411         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 412         stmg    %r8,%r9,__PT_PSW(%r11)
 413         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
 414         mvc     __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
 415         xc      __PT_FLAGS(8,%r11),__PT_FLAGS(%r11)
 416         stg     %r10,__PT_ARGS(%r11)
 417         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 418         jz      0f
 419         tmhh    %r8,0x0001              # kernel per event ?
 420         jz      pgm_kprobe
 421         oi      __PT_FLAGS+7(%r11),_PIF_PER_TRAP
 422         mvc     __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
 423         mvc     __THREAD_per_cause(2,%r14),__LC_PER_CODE
 424         mvc     __THREAD_per_paid(1,%r14),__LC_PER_ACCESS_ID
 425 0:      REENABLE_IRQS
 426         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 427         larl    %r1,pgm_check_table
 428         llgh    %r10,__PT_INT_CODE+2(%r11)
 429         nill    %r10,0x007f
 430         sll     %r10,2
 431         je      sysc_return
 432         lgf     %r1,0(%r10,%r1)         # load address of handler routine
 433         lgr     %r2,%r11                # pass pointer to pt_regs
 434         basr    %r14,%r1                # branch to interrupt-handler
 435         j       sysc_return
 436
 437 #
 438 # PER event in supervisor state, must be kprobes
 439 #
 440 pgm_kprobe:
 441         REENABLE_IRQS
 442         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 443         lgr     %r2,%r11                # pass pointer to pt_regs
 444         brasl   %r14,do_per_trap
 445         j       sysc_return
 446
 447 #
 448 # single stepped system call
 449 #
 450 pgm_svcper:
 451         mvc     __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
 452         larl    %r14,sysc_per
 453         stg     %r14,__LC_RETURN_PSW+8
 454         lghi    %r14,_PIF_SYSCALL | _PIF_PER_TRAP
 455         lpswe   __LC_RETURN_PSW         # branch to sysc_per and enable irqs
 456
 457 /*
 458  * IO interrupt handler routine
 459  */
 460 ENTRY(io_int_handler)
 461         STCK    __LC_INT_CLOCK
 462         stpt    __LC_ASYNC_ENTER_TIMER
 463         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 464         lg      %r10,__LC_LAST_BREAK
 465         lg      %r12,__LC_THREAD_INFO
 466         larl    %r13,system_call
 467         lmg     %r8,%r9,__LC_IO_OLD_PSW
 468         HANDLE_SIE_INTERCEPT %r14,2
 469         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 470         tmhh    %r8,0x0001              # interrupting from user?
 471         jz      io_skip
 472         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
 473         LAST_BREAK %r14
 474 io_skip:
 475         stmg    %r0,%r7,__PT_R0(%r11)
 476         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 477         stmg    %r8,%r9,__PT_PSW(%r11)
 478         mvc     __PT_INT_CODE(12,%r11),__LC_SUBCHANNEL_ID
 479         xc      __PT_FLAGS(8,%r11),__PT_FLAGS(%r11)
 480         TRACE_IRQS_OFF
 481         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 482 io_loop:
 483         lgr     %r2,%r11                # pass pointer to pt_regs
 484         lghi    %r3,IO_INTERRUPT
 485         tm      __PT_INT_CODE+8(%r11),0x80      # adapter interrupt ?
 486         jz      io_call
 487         lghi    %r3,THIN_INTERRUPT
 488 io_call:
 489         brasl   %r14,do_IRQ
 490         tm      __LC_MACHINE_FLAGS+6,0x10       # MACHINE_FLAG_LPAR
 491         jz      io_return
 492         tpi     0
 493         jz      io_return
 494         mvc     __PT_INT_CODE(12,%r11),__LC_SUBCHANNEL_ID
 495         j       io_loop
 496 io_return:
 497         LOCKDEP_SYS_EXIT
 498         TRACE_IRQS_ON
 499 io_tif:
 500         tm      __TI_flags+7(%r12),_TIF_WORK
 501         jnz     io_work                 # there is work to do (signals etc.)
 502         tm      __LC_CPU_FLAGS+7,_CIF_WORK
 503         jnz     io_work
 504 io_restore:
 505         lg      %r14,__LC_VDSO_PER_CPU
 506         lmg     %r0,%r10,__PT_R0(%r11)
 507         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 508         stpt    __LC_EXIT_TIMER
 509         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 510         lmg     %r11,%r15,__PT_R11(%r11)
 511         lpswe   __LC_RETURN_PSW
 512 io_done:
 513
 514 #
 515 # There is work todo, find out in which context we have been interrupted:
 516 # 1) if we return to user space we can do all _TIF_WORK work
 517 # 2) if we return to kernel code and kvm is enabled check if we need to
 518 #    modify the psw to leave SIE
 519 # 3) if we return to kernel code and preemptive scheduling is enabled check
 520 #    the preemption counter and if it is zero call preempt_schedule_irq
 521 # Before any work can be done, a switch to the kernel stack is required.
 522 #
 523 io_work:
 524         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 525         jo      io_work_user            # yes -> do resched & signal
 526 #ifdef CONFIG_PREEMPT
 527         # check for preemptive scheduling
 528         icm     %r0,15,__TI_precount(%r12)
 529         jnz     io_restore              # preemption is disabled
 530         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 531         jno     io_restore
 532         # switch to kernel stack
 533         lg      %r1,__PT_R15(%r11)
 534         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 535         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 536         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 537         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 538         lgr     %r15,%r1
 539         # TRACE_IRQS_ON already done at io_return, call
 540         # TRACE_IRQS_OFF to keep things symmetrical
 541         TRACE_IRQS_OFF
 542         brasl   %r14,preempt_schedule_irq
 543         j       io_return
 544 #else
 545         j       io_restore
 546 #endif
 547
 548 #
 549 # Need to do work before returning to userspace, switch to kernel stack
 550 #
 551 io_work_user:
 552         lg      %r1,__LC_KERNEL_STACK
 553         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 554         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 555         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 556         lgr     %r15,%r1
 557
 558 #
 559 # One of the work bits is on. Find out which one.
 560 #
 561 io_work_tif:
 562         tm      __LC_CPU_FLAGS+7,_CIF_MCCK_PENDING
 563         jo      io_mcck_pending
 564         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 565         jo      io_reschedule
 566         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 567         jo      io_sigpending
 568         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 569         jo      io_notify_resume
 570         tm      __LC_CPU_FLAGS+7,_CIF_ASCE
 571         jo      io_uaccess
 572         j       io_return               # beware of critical section cleanup
 573
 574 #
 575 # _CIF_MCCK_PENDING is set, call handler
 576 #
 577 io_mcck_pending:
 578         # TRACE_IRQS_ON already done at io_return
 579         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 580         TRACE_IRQS_OFF
 581         j       io_return
 582
 583 #
 584 # _CIF_ASCE is set, load user space asce
 585 #
 586 io_uaccess:
 587         ni      __LC_CPU_FLAGS+7,255-_CIF_ASCE
 588         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 589         j       io_return
 590
 591 #
 592 # _TIF_NEED_RESCHED is set, call schedule
 593 #
 594 io_reschedule:
 595         # TRACE_IRQS_ON already done at io_return
 596         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 597         brasl   %r14,schedule           # call scheduler
 598         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 599         TRACE_IRQS_OFF
 600         j       io_return
 601
 602 #
 603 # _TIF_SIGPENDING or is set, call do_signal
 604 #
 605 io_sigpending:
 606         # TRACE_IRQS_ON already done at io_return
 607         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 608         lgr     %r2,%r11                # pass pointer to pt_regs
 609         brasl   %r14,do_signal
 610         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 611         TRACE_IRQS_OFF
 612         j       io_return
 613
 614 #
 615 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 616 #
 617 io_notify_resume:
 618         # TRACE_IRQS_ON already done at io_return
 619         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 620         lgr     %r2,%r11                # pass pointer to pt_regs
 621         brasl   %r14,do_notify_resume
 622         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 623         TRACE_IRQS_OFF
 624         j       io_return
 625
 626 /*
 627  * External interrupt handler routine
 628  */
 629 ENTRY(ext_int_handler)
 630         STCK    __LC_INT_CLOCK
 631         stpt    __LC_ASYNC_ENTER_TIMER
 632         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 633         lg      %r10,__LC_LAST_BREAK
 634         lg      %r12,__LC_THREAD_INFO
 635         larl    %r13,system_call
 636         lmg     %r8,%r9,__LC_EXT_OLD_PSW
 637         HANDLE_SIE_INTERCEPT %r14,3
 638         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 639         tmhh    %r8,0x0001              # interrupting from user ?
 640         jz      ext_skip
 641         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
 642         LAST_BREAK %r14
 643 ext_skip:
 644         stmg    %r0,%r7,__PT_R0(%r11)
 645         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 646         stmg    %r8,%r9,__PT_PSW(%r11)
 647         lghi    %r1,__LC_EXT_PARAMS2
 648         mvc     __PT_INT_CODE(4,%r11),__LC_EXT_CPU_ADDR
 649         mvc     __PT_INT_PARM(4,%r11),__LC_EXT_PARAMS
 650         mvc     __PT_INT_PARM_LONG(8,%r11),0(%r1)
 651         xc      __PT_FLAGS(8,%r11),__PT_FLAGS(%r11)
 652         TRACE_IRQS_OFF
 653         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 654         lgr     %r2,%r11                # pass pointer to pt_regs
 655         lghi    %r3,EXT_INTERRUPT
 656         brasl   %r14,do_IRQ
 657         j       io_return
 658
 659 /*
 660  * Load idle PSW. The second "half" of this function is in cleanup_idle.
 661  */
 662 ENTRY(psw_idle)
 663         stg     %r3,__SF_EMPTY(%r15)
 664         larl    %r1,psw_idle_lpsw+4
 665         stg     %r1,__SF_EMPTY+8(%r15)
 666         STCK    __CLOCK_IDLE_ENTER(%r2)
 667         stpt    __TIMER_IDLE_ENTER(%r2)
 668 psw_idle_lpsw:
 669         lpswe   __SF_EMPTY(%r15)
 670         br      %r14
 671 psw_idle_end:
 672
 673 __critical_end:
 674
 675 /*
 676  * Machine check handler routines
 677  */
 678 ENTRY(mcck_int_handler)
 679         STCK    __LC_MCCK_CLOCK
 680         la      %r1,4095                # revalidate r1
 681         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 682         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 683         lg      %r10,__LC_LAST_BREAK
 684         lg      %r12,__LC_THREAD_INFO
 685         larl    %r13,system_call
 686         lmg     %r8,%r9,__LC_MCK_OLD_PSW
 687         HANDLE_SIE_INTERCEPT %r14,4
 688         tm      __LC_MCCK_CODE,0x80     # system damage?
 689         jo      mcck_panic              # yes -> rest of mcck code invalid
 690         lghi    %r14,__LC_CPU_TIMER_SAVE_AREA
 691         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 692         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 693         jo      3f
 694         la      %r14,__LC_SYNC_ENTER_TIMER
 695         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 696         jl      0f
 697         la      %r14,__LC_ASYNC_ENTER_TIMER
 698 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 699         jl      1f
 700         la      %r14,__LC_EXIT_TIMER
 701 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 702         jl      2f
 703         la      %r14,__LC_LAST_UPDATE_TIMER
 704 2:      spt     0(%r14)
 705         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 706 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 707         jno     mcck_panic              # no -> skip cleanup critical
 708         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
 709         tm      %r8,0x0001              # interrupting from user ?
 710         jz      mcck_skip
 711         UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
 712         LAST_BREAK %r14
 713 mcck_skip:
 714         lghi    %r14,__LC_GPREGS_SAVE_AREA+64
 715         stmg    %r0,%r7,__PT_R0(%r11)
 716         mvc     __PT_R8(64,%r11),0(%r14)
 717         stmg    %r8,%r9,__PT_PSW(%r11)
 718         xc      __PT_FLAGS(8,%r11),__PT_FLAGS(%r11)
 719         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 720         lgr     %r2,%r11                # pass pointer to pt_regs
 721         brasl   %r14,s390_do_machine_check
 722         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 723         jno     mcck_return
 724         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 725         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 726         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 727         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 728         lgr     %r15,%r1
 729         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
 730         tm      __LC_CPU_FLAGS+7,_CIF_MCCK_PENDING
 731         jno     mcck_return
 732         TRACE_IRQS_OFF
 733         brasl   %r14,s390_handle_mcck
 734         TRACE_IRQS_ON
 735 mcck_return:
 736         lg      %r14,__LC_VDSO_PER_CPU
 737         lmg     %r0,%r10,__PT_R0(%r11)
 738         mvc     __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
 739         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 740         jno     0f
 741         stpt    __LC_EXIT_TIMER
 742         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 743 0:      lmg     %r11,%r15,__PT_R11(%r11)
 744         lpswe   __LC_RETURN_MCCK_PSW
 745
 746 mcck_panic:
 747         lg      %r14,__LC_PANIC_STACK
 748         slgr    %r14,%r15
 749         srag    %r14,%r14,PAGE_SHIFT
 750         jz      0f
 751         lg      %r15,__LC_PANIC_STACK
 752 0:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 753         j       mcck_skip
 754
 755 #
 756 # PSW restart interrupt handler
 757 #
 758 ENTRY(restart_int_handler)
 759         stg     %r15,__LC_SAVE_AREA_RESTART
 760         lg      %r15,__LC_RESTART_STACK
 761         aghi    %r15,-__PT_SIZE                 # create pt_regs on stack
 762         xc      0(__PT_SIZE,%r15),0(%r15)
 763         stmg    %r0,%r14,__PT_R0(%r15)
 764         mvc     __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
 765         mvc     __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
 766         aghi    %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
 767         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
 768         lg      %r1,__LC_RESTART_FN             # load fn, parm & source cpu
 769         lg      %r2,__LC_RESTART_DATA
 770         lg      %r3,__LC_RESTART_SOURCE
 771         ltgr    %r3,%r3                         # test source cpu address
 772         jm      1f                              # negative -> skip source stop
 773 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
 774         brc     10,0b                           # wait for status stored
 775 1:      basr    %r14,%r1                        # call function
 776         stap    __SF_EMPTY(%r15)                # store cpu address
 777         llgh    %r3,__SF_EMPTY(%r15)
 778 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
 779         brc     2,2b
 780 3:      j       3b
 781
 782         .section .kprobes.text, "ax"
 783
 784 #ifdef CONFIG_CHECK_STACK
 785 /*
 786  * The synchronous or the asynchronous stack overflowed. We are dead.
 787  * No need to properly save the registers, we are going to panic anyway.
 788  * Setup a pt_regs so that show_trace can provide a good call trace.
 789  */
 790 stack_overflow:
 791         lg      %r15,__LC_PANIC_STACK   # change to panic stack
 792         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 793         stmg    %r0,%r7,__PT_R0(%r11)
 794         stmg    %r8,%r9,__PT_PSW(%r11)
 795         mvc     __PT_R8(64,%r11),0(%r14)
 796         stg     %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
 797         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 798         lgr     %r2,%r11                # pass pointer to pt_regs
 799         jg      kernel_stack_overflow
 800 #endif
 801
 802         .align  8
 803 cleanup_table:
 804         .quad   system_call
 805         .quad   sysc_do_svc
 806         .quad   sysc_tif
 807         .quad   sysc_restore
 808         .quad   sysc_done
 809         .quad   io_tif
 810         .quad   io_restore
 811         .quad   io_done
 812         .quad   psw_idle
 813         .quad   psw_idle_end
 814
 815 cleanup_critical:
 816         clg     %r9,BASED(cleanup_table)        # system_call
 817         jl      0f
 818         clg     %r9,BASED(cleanup_table+8)      # sysc_do_svc
 819         jl      cleanup_system_call
 820         clg     %r9,BASED(cleanup_table+16)     # sysc_tif
 821         jl      0f
 822         clg     %r9,BASED(cleanup_table+24)     # sysc_restore
 823         jl      cleanup_sysc_tif
 824         clg     %r9,BASED(cleanup_table+32)     # sysc_done
 825         jl      cleanup_sysc_restore
 826         clg     %r9,BASED(cleanup_table+40)     # io_tif
 827         jl      0f
 828         clg     %r9,BASED(cleanup_table+48)     # io_restore
 829         jl      cleanup_io_tif
 830         clg     %r9,BASED(cleanup_table+56)     # io_done
 831         jl      cleanup_io_restore
 832         clg     %r9,BASED(cleanup_table+64)     # psw_idle
 833         jl      0f
 834         clg     %r9,BASED(cleanup_table+72)     # psw_idle_end
 835         jl      cleanup_idle
 836 0:      br      %r14
 837
 838
 839 cleanup_system_call:
 840         # check if stpt has been executed
 841         clg     %r9,BASED(cleanup_system_call_insn)
 842         jh      0f
 843         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 844         cghi    %r11,__LC_SAVE_AREA_ASYNC
 845         je      0f
 846         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 847 0:      # check if stmg has been executed
 848         clg     %r9,BASED(cleanup_system_call_insn+8)
 849         jh      0f
 850         mvc     __LC_SAVE_AREA_SYNC(64),0(%r11)
 851 0:      # check if base register setup + TIF bit load has been done
 852         clg     %r9,BASED(cleanup_system_call_insn+16)
 853         jhe     0f
 854         # set up saved registers r10 and r12
 855         stg     %r10,16(%r11)           # r10 last break
 856         stg     %r12,32(%r11)           # r12 thread-info pointer
 857 0:      # check if the user time update has been done
 858         clg     %r9,BASED(cleanup_system_call_insn+24)
 859         jh      0f
 860         lg      %r15,__LC_EXIT_TIMER
 861         slg     %r15,__LC_SYNC_ENTER_TIMER
 862         alg     %r15,__LC_USER_TIMER
 863         stg     %r15,__LC_USER_TIMER
 864 0:      # check if the system time update has been done
 865         clg     %r9,BASED(cleanup_system_call_insn+32)
 866         jh      0f
 867         lg      %r15,__LC_LAST_UPDATE_TIMER
 868         slg     %r15,__LC_EXIT_TIMER
 869         alg     %r15,__LC_SYSTEM_TIMER
 870         stg     %r15,__LC_SYSTEM_TIMER
 871 0:      # update accounting time stamp
 872         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 873         # do LAST_BREAK
 874         lg      %r9,16(%r11)
 875         srag    %r9,%r9,23
 876         jz      0f
 877         mvc     __TI_last_break(8,%r12),16(%r11)
 878 0:      # set up saved register r11
 879         lg      %r15,__LC_KERNEL_STACK
 880         la      %r9,STACK_FRAME_OVERHEAD(%r15)
 881         stg     %r9,24(%r11)            # r11 pt_regs pointer
 882         # fill pt_regs
 883         mvc     __PT_R8(64,%r9),__LC_SAVE_AREA_SYNC
 884         stmg    %r0,%r7,__PT_R0(%r9)
 885         mvc     __PT_PSW(16,%r9),__LC_SVC_OLD_PSW
 886         mvc     __PT_INT_CODE(4,%r9),__LC_SVC_ILC
 887         xc      __PT_FLAGS(8,%r9),__PT_FLAGS(%r9)
 888         mvi     __PT_FLAGS+7(%r9),_PIF_SYSCALL
 889         # setup saved register r15
 890         stg     %r15,56(%r11)           # r15 stack pointer
 891         # set new psw address and exit
 892         larl    %r9,sysc_do_svc
 893         br      %r14
 894 cleanup_system_call_insn:
 895         .quad   system_call
 896         .quad   sysc_stmg
 897         .quad   sysc_per
 898         .quad   sysc_vtime+18
 899         .quad   sysc_vtime+42
 900
 901 cleanup_sysc_tif:
 902         larl    %r9,sysc_tif
 903         br      %r14
 904
 905 cleanup_sysc_restore:
 906         clg     %r9,BASED(cleanup_sysc_restore_insn)
 907         je      0f
 908         lg      %r9,24(%r11)            # get saved pointer to pt_regs
 909         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
 910         mvc     0(64,%r11),__PT_R8(%r9)
 911         lmg     %r0,%r7,__PT_R0(%r9)
 912 0:      lmg     %r8,%r9,__LC_RETURN_PSW
 913         br      %r14
 914 cleanup_sysc_restore_insn:
 915         .quad   sysc_done - 4
 916
 917 cleanup_io_tif:
 918         larl    %r9,io_tif
 919         br      %r14
 920
 921 cleanup_io_restore:
 922         clg     %r9,BASED(cleanup_io_restore_insn)
 923         je      0f
 924         lg      %r9,24(%r11)            # get saved r11 pointer to pt_regs
 925         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
 926         mvc     0(64,%r11),__PT_R8(%r9)
 927         lmg     %r0,%r7,__PT_R0(%r9)
 928 0:      lmg     %r8,%r9,__LC_RETURN_PSW
 929         br      %r14
 930 cleanup_io_restore_insn:
 931         .quad   io_done - 4
 932
 933 cleanup_idle:
 934         # copy interrupt clock & cpu timer
 935         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
 936         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
 937         cghi    %r11,__LC_SAVE_AREA_ASYNC
 938         je      0f
 939         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
 940         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
 941 0:      # check if stck & stpt have been executed
 942         clg     %r9,BASED(cleanup_idle_insn)
 943         jhe     1f
 944         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
 945         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
 946 1:      # account system time going idle
 947         lg      %r9,__LC_STEAL_TIMER
 948         alg     %r9,__CLOCK_IDLE_ENTER(%r2)
 949         slg     %r9,__LC_LAST_UPDATE_CLOCK
 950         stg     %r9,__LC_STEAL_TIMER
 951         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
 952         lg      %r9,__LC_SYSTEM_TIMER
 953         alg     %r9,__LC_LAST_UPDATE_TIMER
 954         slg     %r9,__TIMER_IDLE_ENTER(%r2)
 955         stg     %r9,__LC_SYSTEM_TIMER
 956         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
 957         # prepare return psw
 958         nihh    %r8,0xfcfd              # clear irq & wait state bits
 959         lg      %r9,48(%r11)            # return from psw_idle
 960         br      %r14
 961 cleanup_idle_insn:
 962         .quad   psw_idle_lpsw
 963
 964 /*
 965  * Integer constants
 966  */
 967         .align  8
 968 .Lcritical_start:
 969         .quad   __critical_start
 970 .Lcritical_length:
 971         .quad   __critical_end - __critical_start
 972
 973
 974 #if IS_ENABLED(CONFIG_KVM)
 975 /*
 976  * sie64a calling convention:
 977  * %r2 pointer to sie control block
 978  * %r3 guest register save area
 979  */
 980 ENTRY(sie64a)
 981         stmg    %r6,%r14,__SF_GPRS(%r15)        # save kernel registers
 982         stg     %r2,__SF_EMPTY(%r15)            # save control block pointer
 983         stg     %r3,__SF_EMPTY+8(%r15)          # save guest register save area
 984         xc      __SF_EMPTY+16(16,%r15),__SF_EMPTY+16(%r15) # host id & reason
 985         lmg     %r0,%r13,0(%r3)                 # load guest gprs 0-13
 986         lg      %r14,__LC_GMAP                  # get gmap pointer
 987         ltgr    %r14,%r14
 988         jz      sie_gmap
 989         lctlg   %c1,%c1,__GMAP_ASCE(%r14)       # load primary asce
 990 sie_gmap:
 991         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
 992         oi      __SIE_PROG0C+3(%r14),1          # we are going into SIE now
 993         tm      __SIE_PROG20+3(%r14),1          # last exit...
 994         jnz     sie_done
 995         LPP     __SF_EMPTY(%r15)                # set guest id
 996         sie     0(%r14)
 997 sie_done:
 998         LPP     __SF_EMPTY+16(%r15)             # set host id
 999         ni      __SIE_PROG0C+3(%r14),0xfe       # no longer in SIE
1000         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
1001 # some program checks are suppressing. C code (e.g. do_protection_exception)
1002 # will rewind the PSW by the ILC, which is 4 bytes in case of SIE. Other
1003 # instructions between sie64a and sie_done should not cause program
1004 # interrupts. So lets use a nop (47 00 00 00) as a landing pad.
1005 # See also HANDLE_SIE_INTERCEPT
1006 rewind_pad:
1007         nop     0
1008         .globl sie_exit
1009 sie_exit:
1010         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
1011         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
1012         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
1013         lg      %r2,__SF_EMPTY+24(%r15)         # return exit reason code
1014         br      %r14
1015 sie_fault:
1016         lghi    %r14,-EFAULT
1017         stg     %r14,__SF_EMPTY+24(%r15)        # set exit reason code
1018         j       sie_exit
1019
1020         .align  8
1021 .Lsie_critical:
1022         .quad   sie_gmap
1023 .Lsie_critical_length:
1024         .quad   sie_done - sie_gmap
1025
1026         EX_TABLE(rewind_pad,sie_fault)
1027         EX_TABLE(sie_exit,sie_fault)
1028 #endif
1029
1030                 .section .rodata, "a"
1031 #define SYSCALL(esa,esame,emu)  .long esame
1032         .globl  sys_call_table
1033 sys_call_table:
1034 #include "syscalls.S"
1035 #undef SYSCALL
1036
1037 #ifdef CONFIG_COMPAT
1038
1039 #define SYSCALL(esa,esame,emu)  .long emu
1040         .globl  sys_call_table_emu
1041 sys_call_table_emu:
1042 #include "syscalls.S"
1043 #undef SYSCALL
1044 #endif