arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/cache.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/memory.h>
  10 #include <asm/page.h>
  11
  12 #define PROC_INFO                                                       \
  13         . = ALIGN(4);                                                   \
  14         VMLINUX_SYMBOL(__proc_info_begin) = .;                          \
  15         *(.proc.info.init)                                              \
  16         VMLINUX_SYMBOL(__proc_info_end) = .;
  17
  18 #define IDMAP_TEXT                                                      \
  19         ALIGN_FUNCTION();                                               \
  20         VMLINUX_SYMBOL(__idmap_text_start) = .;                         \
  21         *(.idmap.text)                                                  \
  22         VMLINUX_SYMBOL(__idmap_text_end) = .;
  23
  24 #ifdef CONFIG_HOTPLUG_CPU
  25 #define ARM_CPU_DISCARD(x)
  26 #define ARM_CPU_KEEP(x)         x
  27 #else
  28 #define ARM_CPU_DISCARD(x)      x
  29 #define ARM_CPU_KEEP(x)
  30 #endif
  31
  32 #if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
  33         defined(CONFIG_GENERIC_BUG)
  34 #define ARM_EXIT_KEEP(x)        x
  35 #define ARM_EXIT_DISCARD(x)
  36 #else
  37 #define ARM_EXIT_KEEP(x)
  38 #define ARM_EXIT_DISCARD(x)     x
  39 #endif
  40
  41 OUTPUT_ARCH(arm)
  42 ENTRY(stext)
  43
  44 #ifndef __ARMEB__
  45 jiffies = jiffies_64;
  46 #else
  47 jiffies = jiffies_64 + 4;
  48 #endif
  49
  50 SECTIONS
  51 {
  52         /*
  53          * XXX: The linker does not define how output sections are
  54          * assigned to input sections when there are multiple statements
  55          * matching the same input section name.  There is no documented
  56          * order of matching.
  57          *
  58          * unwind exit sections must be discarded before the rest of the
  59          * unwind sections get included.
  60          */
  61         /DISCARD/ : {
  62                 *(.ARM.exidx.exit.text)
  63                 *(.ARM.extab.exit.text)
  64                 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
  65                 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
  66                 ARM_EXIT_DISCARD(EXIT_TEXT)
  67                 ARM_EXIT_DISCARD(EXIT_DATA)
  68                 EXIT_CALL
  69 #ifndef CONFIG_HOTPLUG
  70                 *(.ARM.exidx.devexit.text)
  71                 *(.ARM.extab.devexit.text)
  72 #endif
  73 #ifndef CONFIG_MMU
  74                 *(.fixup)
  75                 *(__ex_table)
  76 #endif
  77 #ifndef CONFIG_SMP_ON_UP
  78                 *(.alt.smp.init)
  79 #endif
  80                 *(.discard)
  81                 *(.discard.*)
  82         }
  83
  84 #ifdef CONFIG_XIP_KERNEL
  85         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  86 #else
  87         . = PAGE_OFFSET + TEXT_OFFSET;
  88 #endif
  89         .head.text : {
  90                 _text = .;
  91                 HEAD_TEXT
  92         }
  93         .text : {                       /* Real text segment            */
  94                 _stext = .;             /* Text and read-only data      */
  95                         __exception_text_start = .;
  96                         *(.exception.text)
  97                         __exception_text_end = .;
  98                         IRQENTRY_TEXT
  99                         TEXT_TEXT
 100                         SCHED_TEXT
 101                         LOCK_TEXT
 102                         KPROBES_TEXT
 103                         IDMAP_TEXT
 104 #ifdef CONFIG_MMU
 105                         *(.fixup)
 106 #endif
 107                         *(.gnu.warning)
 108                         *(.glue_7)
 109                         *(.glue_7t)
 110                 . = ALIGN(4);
 111                 *(.got)                 /* Global offset table          */
 112                         ARM_CPU_KEEP(PROC_INFO)
 113         }
 114
 115         RO_DATA(PAGE_SIZE)
 116
 117         . = ALIGN(4);
 118         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
 119                 __start___ex_table = .;
 120 #ifdef CONFIG_MMU
 121                 *(__ex_table)
 122 #endif
 123                 __stop___ex_table = .;
 124         }
 125
 126 #ifdef CONFIG_ARM_UNWIND
 127         /*
 128          * Stack unwinding tables
 129          */
 130         . = ALIGN(8);
 131         .ARM.unwind_idx : {
 132                 __start_unwind_idx = .;
 133                 *(.ARM.exidx*)
 134                 __stop_unwind_idx = .;
 135         }
 136         .ARM.unwind_tab : {
 137                 __start_unwind_tab = .;
 138                 *(.ARM.extab*)
 139                 __stop_unwind_tab = .;
 140         }
 141 #endif
 142
 143         _etext = .;                     /* End of text and rodata section */
 144
 145 #ifndef CONFIG_XIP_KERNEL
 146         . = ALIGN(PAGE_SIZE);
 147         __init_begin = .;
 148 #endif
 149
 150         INIT_TEXT_SECTION(8)
 151         .exit.text : {
 152                 ARM_EXIT_KEEP(EXIT_TEXT)
 153         }
 154         .init.proc.info : {
 155                 ARM_CPU_DISCARD(PROC_INFO)
 156         }
 157         .init.arch.info : {
 158                 __arch_info_begin = .;
 159                 *(.arch.info.init)
 160                 __arch_info_end = .;
 161         }
 162         .init.tagtable : {
 163                 __tagtable_begin = .;
 164                 *(.taglist.init)
 165                 __tagtable_end = .;
 166         }
 167 #ifdef CONFIG_SMP_ON_UP
 168         .init.smpalt : {
 169                 __smpalt_begin = .;
 170                 *(.alt.smp.init)
 171                 __smpalt_end = .;
 172         }
 173 #endif
 174         .init.pv_table : {
 175                 __pv_table_begin = .;
 176                 *(.pv_table)
 177                 __pv_table_end = .;
 178         }
 179         .init.data : {
 180 #ifndef CONFIG_XIP_KERNEL
 181                 INIT_DATA
 182 #endif
 183                 INIT_SETUP(16)
 184                 INIT_CALLS
 185                 CON_INITCALL
 186                 SECURITY_INITCALL
 187                 INIT_RAM_FS
 188         }
 189 #ifndef CONFIG_XIP_KERNEL
 190         .exit.data : {
 191                 ARM_EXIT_KEEP(EXIT_DATA)
 192         }
 193 #endif
 194
 195 #ifdef CONFIG_SMP
 196         PERCPU_SECTION(L1_CACHE_BYTES)
 197 #endif
 198
 199 #ifdef CONFIG_XIP_KERNEL
 200         __data_loc = ALIGN(4);          /* location in binary */
 201         . = PAGE_OFFSET + TEXT_OFFSET;
 202 #else
 203         __init_end = .;
 204         . = ALIGN(THREAD_SIZE);
 205         __data_loc = .;
 206 #endif
 207
 208         .data : AT(__data_loc) {
 209                 _data = .;              /* address in memory */
 210                 _sdata = .;
 211
 212                 /*
 213                  * first, the init task union, aligned
 214                  * to an 8192 byte boundary.
 215                  */
 216                 INIT_TASK_DATA(THREAD_SIZE)
 217
 218 #ifdef CONFIG_XIP_KERNEL
 219                 . = ALIGN(PAGE_SIZE);
 220                 __init_begin = .;
 221                 INIT_DATA
 222                 ARM_EXIT_KEEP(EXIT_DATA)
 223                 . = ALIGN(PAGE_SIZE);
 224                 __init_end = .;
 225 #endif
 226
 227                 NOSAVE_DATA
 228                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 229                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 230
 231                 /*
 232                  * and the usual data section
 233                  */
 234                 DATA_DATA
 235                 CONSTRUCTORS
 236
 237                 _edata = .;
 238         }
 239         _edata_loc = __data_loc + SIZEOF(.data);
 240
 241 #ifdef CONFIG_HAVE_TCM
 242         /*
 243          * We align everything to a page boundary so we can
 244          * free it after init has commenced and TCM contents have
 245          * been copied to its destination.
 246          */
 247         .tcm_start : {
 248                 . = ALIGN(PAGE_SIZE);
 249                 __tcm_start = .;
 250                 __itcm_start = .;
 251         }
 252
 253         /*
 254          * Link these to the ITCM RAM
 255          * Put VMA to the TCM address and LMA to the common RAM
 256          * and we'll upload the contents from RAM to TCM and free
 257          * the used RAM after that.
 258          */
 259         .text_itcm ITCM_OFFSET : AT(__itcm_start)
 260         {
 261                 __sitcm_text = .;
 262                 *(.tcm.text)
 263                 *(.tcm.rodata)
 264                 . = ALIGN(4);
 265                 __eitcm_text = .;
 266         }
 267
 268         /*
 269          * Reset the dot pointer, this is needed to create the
 270          * relative __dtcm_start below (to be used as extern in code).
 271          */
 272         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
 273
 274         .dtcm_start : {
 275                 __dtcm_start = .;
 276         }
 277
 278         /* TODO: add remainder of ITCM as well, that can be used for data! */
 279         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
 280         {
 281                 . = ALIGN(4);
 282                 __sdtcm_data = .;
 283                 *(.tcm.data)
 284                 . = ALIGN(4);
 285                 __edtcm_data = .;
 286         }
 287
 288         /* Reset the dot pointer or the linker gets confused */
 289         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
 290
 291         /* End marker for freeing TCM copy in linked object */
 292         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
 293                 . = ALIGN(PAGE_SIZE);
 294                 __tcm_end = .;
 295         }
 296 #endif
 297
 298         NOTES
 299
 300         BSS_SECTION(0, 0, 0)
 301         _end = .;
 302
 303         STABS_DEBUG
 304         .comment 0 : { *(.comment) }
 305 }
 306
 307 /*
 308  * These must never be empty
 309  * If you have to comment these two assert statements out, your
 310  * binutils is too old (for other reasons as well)
 311  */
 312 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 313 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")