arch/arm/lib/relocate.S

   1 /*
   2  *  relocate - common relocation function for ARM U-Boot
   3  *
   4  *  Copyright (c) 2013  Albert ARIBAUD <albert.u.boot@aribaud.net>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <linux/linkage.h>
  26
  27 /*
  28  * void relocate_code(addr_moni)
  29  *
  30  * This function relocates the monitor code.
  31  *
  32  * NOTE:
  33  * To prevent the code below from containing references with an R_ARM_ABS32
  34  * relocation record type, we never refer to linker-defined symbols directly.
  35  * Instead, we declare literals which contain their relative location with
  36  * respect to relocate_code, and at run time, add relocate_code back to them.
  37  */
  38
  39 ENTRY(relocate_code)
  40         mov     r6, r0  /* save addr of destination */
  41
  42         ldr     r0, =_start             /* r0 <- SRC &_start */
  43         subs    r9, r6, r0              /* r9 <- relocation offset */
  44         beq     relocate_done           /* skip relocation */
  45         mov     r1, r6                  /* r1 <- scratch for copy loop */
  46         adr     r7, relocate_code       /* r7 <- SRC &relocate_code */
  47         ldr     r3, _image_copy_end_ofs /* r3 <- __image_copy_end local ofs */
  48         add     r2, r7, r3              /* r2 <- SRC &__image_copy_end */
  49
  50 copy_loop:
  51         ldmia   r0!, {r10-r11}          /* copy from source address [r0]    */
  52         stmia   r1!, {r10-r11}          /* copy to   target address [r1]    */
  53         cmp     r0, r2                  /* until source end address [r2]    */
  54         blo     copy_loop
  55
  56         /*
  57          * fix .rel.dyn relocations
  58          */
  59         ldr     r2, _rel_dyn_start_ofs  /* r2 <- __rel_dyn_start local ofs */
  60         add     r2, r2, r7              /* r2 <- SRC &__rel_dyn_start */
  61         ldr     r3, _rel_dyn_end_ofs    /* r3 <- __rel_dyn_end local ofs */
  62         add     r3, r3, r7              /* r3 <- SRC &__rel_dyn_end */
  63 fixloop:
  64         ldr     r0, [r2]                /* r0 <- SRC location to fix up */
  65         add     r0, r0, r9              /* r0 <- DST location to fix up */
  66         ldr     r1, [r2, #4]
  67         and     r7, r1, #0xff
  68         cmp     r7, #23                 /* relative fixup? */
  69         beq     fixrel
  70         /* ignore unknown type of fixup */
  71         b       fixnext
  72 fixrel:
  73         /* relative fix: increase location by offset */
  74         ldr     r1, [r0]
  75         add     r1, r1, r9
  76 fixnext:
  77         str     r1, [r0]
  78         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
  79         cmp     r2, r3
  80         blo     fixloop
  81
  82 relocate_done:
  83
  84         /* ARMv4- don't know bx lr but the assembler fails to see that */
  85
  86 #ifdef __ARM_ARCH_4__
  87         mov        pc, lr
  88 #else
  89         bx        lr
  90 #endif
  91
  92 _image_copy_end_ofs:
  93         .word __image_copy_end - relocate_code
  94 _rel_dyn_start_ofs:
  95         .word __rel_dyn_start - relocate_code
  96 _rel_dyn_end_ofs:
  97         .word __rel_dyn_end - relocate_code
  98
  99 ENDPROC(relocate_code)