arch/i386/cpu/start.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002  Omicron Ceti AB, Daniel Engstr�m <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25
  26 #include <config.h>
  27 #include <version.h>
  28
  29
  30 .section .text
  31 .code32
  32 .globl _start
  33 .type _start, @function
  34 .globl _i386boot_start
  35 _i386boot_start:
  36         /*
  37          * This is the fail safe 32-bit bootstrap entry point. The
  38          * following code is not executed from a cold-reset (actually, a
  39          * lot of it is, but from real-mode after cold reset. It is
  40          * repeated here to put the board into a state as close to cold
  41          * reset as necessary)
  42          */
  43         cli
  44         cld
  45
  46         /* Turn of cache (this might require a 486-class CPU) */
  47         movl    %cr0, %eax
  48         orl     $0x60000000, %eax
  49         movl    %eax, %cr0
  50         wbinvd
  51
  52         /* Tell 32-bit code it is being entered from an in-RAM copy */
  53         movw    $0x0000, %bx
  54 _start:
  55         /* This is the 32-bit cold-reset entry point */
  56
  57         movl    $0x18, %eax     /* Load our segement registes, the
  58                                  * gdt have already been loaded by start16.S */
  59         movw    %ax, %fs
  60         movw    %ax, %ds
  61         movw    %ax, %gs
  62         movw    %ax, %es
  63         movw    %ax, %ss
  64
  65         /* Clear the interupt vectors */
  66         lidt    blank_idt_ptr
  67
  68         /*
  69          * Skip low-level board and memory initialization if not starting
  70          * from cold-reset. This allows us to do a fail safe boot-strap
  71          * into a new build of U-Boot from a known-good boot flash
  72          */
  73         movw    $0x0001, %ax
  74         cmpw    %ax, %bx
  75         jne     mem_init_ret
  76
  77         /* We call a few functions in the board support package
  78          * since we have no stack yet we'll have to use %ebp
  79          * to store the return address */
  80
  81         /* Early platform init (setup gpio, etc ) */
  82         jmp     early_board_init
  83 .globl early_board_init_ret
  84 early_board_init_ret:
  85
  86         /* size memory */
  87         jmp     mem_init
  88 .globl mem_init_ret
  89 mem_init_ret:
  90
  91         /* fetch memory size (into %eax) */
  92         jmp     get_mem_size
  93 .globl get_mem_size_ret
  94 get_mem_size_ret:
  95
  96 #if CONFIG_SYS_SDRAM_ECC_ENABLE
  97         /* Skip ECC initialization if not starting from cold-reset */
  98         movl    %ebx, %ecx
  99         andl    $GD_FLG_COLD_BOOT, %ecx
 100         jz      init_ecc_ret
 101         jmp     init_ecc
 102
 103 .globl init_ecc_ret
 104 init_ecc_ret:
 105 #endif
 106
 107         /* Check we have enough memory for stack */
 108         movl    $CONFIG_SYS_STACK_SIZE, %ecx
 109         cmpl    %ecx, %eax
 110         jb      die
 111 mem_ok:
 112         /* Set stack pointer to upper memory limit*/
 113         movl    %eax, %esp
 114
 115         /* Test the stack */
 116         pushl   $0
 117         popl    %ecx
 118         cmpl    $0, %ecx
 119         jne     die
 120         push    $0x55aa55aa
 121         popl    %ecx
 122         cmpl    $0x55aa55aa, %ecx
 123         jne     die
 124
 125         wbinvd
 126
 127         /* Set the upper memory limit parameter */
 128         subl    $CONFIG_SYS_STACK_SIZE, %eax
 129
 130         call    board_init_f    /* Enter, U-boot! */
 131
 132         /* indicate (lack of) progress */
 133         movw    $0x85, %ax
 134 die:    hlt
 135         jmp     die
 136         hlt
 137
 138 blank_idt_ptr:
 139         .word   0               /* limit */
 140         .long   0               /* base */