arch/i386/cpu/start.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002  Omicron Ceti AB, Daniel Engström <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25
  26 #include <config.h>
  27 #include <version.h>
  28 #include <asm/global_data.h>
  29 #include <asm/processor-flags.h>
  30
  31
  32 .section .text
  33 .code32
  34 .globl _start
  35 .type _start, @function
  36 .globl _i386boot_start
  37 _i386boot_start:
  38         /*
  39          * This is the fail safe 32-bit bootstrap entry point. The
  40          * following code is not executed from a cold-reset (actually, a
  41          * lot of it is, but from real-mode after cold reset. It is
  42          * repeated here to put the board into a state as close to cold
  43          * reset as necessary)
  44          */
  45         cli
  46         cld
  47
  48         /* Turn of cache (this might require a 486-class CPU) */
  49         movl    %cr0, %eax
  50         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  51         movl    %eax, %cr0
  52         wbinvd
  53
  54         /* Tell 32-bit code it is being entered from an in-RAM copy */
  55         movw    $GD_FLG_WARM_BOOT, %bx
  56 _start:
  57         /* This is the 32-bit cold-reset entry point */
  58
  59         movl    $0x18, %eax     /* Load our segement registes, the
  60                                  * gdt have already been loaded by start16.S */
  61         movw    %ax, %fs
  62         movw    %ax, %ds
  63         movw    %ax, %gs
  64         movw    %ax, %es
  65         movw    %ax, %ss
  66
  67         /* Clear the interupt vectors */
  68         lidt    blank_idt_ptr
  69
  70         /* Early platform init (setup gpio, etc ) */
  71         jmp     early_board_init
  72 .globl early_board_init_ret
  73 early_board_init_ret:
  74
  75         /* Initialise Cache-As-RAM */
  76         jmp     car_init
  77 .globl car_init_ret
  78 car_init_ret:
  79         /*
  80          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  81          * or fully initialised SDRAM - we really don't care which)
  82          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
  83          */
  84         movl    $CONFIG_SYS_INIT_SP_ADDR, %esp
  85         movl    $CONFIG_SYS_INIT_GD_ADDR, %ebp
  86
  87         /* Set Boot Flags in Global Data */
  88         movl    %ebx, (GD_FLAGS * 4)(%ebp)
  89
  90         /* Determine our load offset (and put in Global Data) */
  91         call    1f
  92 1:      popl    %ecx
  93         subl    $1b, %ecx
  94         movl    %ecx, (GD_LOAD_OFF * 4)(%ebp)
  95
  96         /* size memory */
  97         call    dram_init_f
  98
  99         /* Set parameter to board_init_f() to boot flags */
 100         movl    (GD_FLAGS * 4)(%ebp), %eax
 101
 102         call    board_init_f    /* Enter, U-boot! */
 103
 104         /* indicate (lack of) progress */
 105         movw    $0x85, %ax
 106         jmp     die
 107
 108 .globl relocate_code
 109 .type relocate_code, @function
 110 relocate_code:
 111         /*
 112          * SDRAM has been initialised, U-Boot code has been copied into
 113          * RAM, BSS has been cleared and relocation adjustments have been
 114          * made. It is now time to jump into the in-RAM copy of U-Boot
 115          *
 116          * %eax = Address of top of stack
 117          * %edx = Address of Global Data
 118          * %ecx = Base address of in-RAM copy of U-Boot
 119          */
 120
 121         /* Setup stack in RAM */
 122         movl    %eax, %esp
 123
 124         /* Setup call address of in-RAM copy of board_init_r() */
 125         movl    $board_init_r, %ebp
 126         subl    (GD_RELOC_OFF * 4)(%edx), %ebp
 127
 128         /* Setup parameters to board_init_r() */
 129         movl    %edx, %eax
 130         movl    %ecx, %edx
 131
 132         /* Jump to in-RAM copy of board_init_r() */
 133         call    *%ebp
 134
 135 die:    hlt
 136         jmp     die
 137         hlt
 138
 139 blank_idt_ptr:
 140         .word   0               /* limit */
 141         .long   0               /* base */