arch/i386/kernel/entry.S

   1 /*
   2  *  linux/arch/i386/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  */
   6
   7 /*
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  * This also contains the timer-interrupt handler, as well as all interrupts
  10  * and faults that can result in a task-switch.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after a timer-interrupt and after each system call.
  14  *
  15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  16  * on a 486.
  17  *
  18  * Stack layout in 'ret_from_system_call':
  19  *      ptrace needs to have all regs on the stack.
  20  *      if the order here is changed, it needs to be
  21  *      updated in fork.c:copy_process, signal.c:do_signal,
  22  *      ptrace.c and ptrace.h
  23  *
  24  *       0(%esp) - %ebx
  25  *       4(%esp) - %ecx
  26  *       8(%esp) - %edx
  27  *       C(%esp) - %esi
  28  *      10(%esp) - %edi
  29  *      14(%esp) - %ebp
  30  *      18(%esp) - %eax
  31  *      1C(%esp) - %ds
  32  *      20(%esp) - %es
  33  *      24(%esp) - orig_eax
  34  *      28(%esp) - %eip
  35  *      2C(%esp) - %cs
  36  *      30(%esp) - %eflags
  37  *      34(%esp) - %oldesp
  38  *      38(%esp) - %oldss
  39  *
  40  * "current" is in register %ebx during any slow entries.
  41  */
  42
  43 #include <linux/config.h>
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/errno.h>
  47 #include <asm/segment.h>
  48 #include <asm/smp.h>
  49 #include <asm/page.h>
  50 #include <asm/desc.h>
  51 #include "irq_vectors.h"
  52
  53 #define nr_syscalls ((syscall_table_size)/4)
  54
  55 EBX             = 0x00
  56 ECX             = 0x04
  57 EDX             = 0x08
  58 ESI             = 0x0C
  59 EDI             = 0x10
  60 EBP             = 0x14
  61 EAX             = 0x18
  62 DS              = 0x1C
  63 ES              = 0x20
  64 ORIG_EAX        = 0x24
  65 EIP             = 0x28
  66 CS              = 0x2C
  67 EFLAGS          = 0x30
  68 OLDESP          = 0x34
  69 OLDSS           = 0x38
  70
  71 CF_MASK         = 0x00000001
  72 TF_MASK         = 0x00000100
  73 IF_MASK         = 0x00000200
  74 DF_MASK         = 0x00000400
  75 NT_MASK         = 0x00004000
  76 VM_MASK         = 0x00020000
  77
  78 #ifdef CONFIG_PREEMPT
  79 #define preempt_stop            cli
  80 #else
  81 #define preempt_stop
  82 #define resume_kernel           restore_nocheck
  83 #endif
  84
  85 #define SAVE_ALL \
  86         cld; \
  87         pushl %es; \
  88         pushl %ds; \
  89         pushl %eax; \
  90         pushl %ebp; \
  91         pushl %edi; \
  92         pushl %esi; \
  93         pushl %edx; \
  94         pushl %ecx; \
  95         pushl %ebx; \
  96         movl $(__USER_DS), %edx; \
  97         movl %edx, %ds; \
  98         movl %edx, %es;
  99
 100 #define RESTORE_INT_REGS \
 101         popl %ebx;      \
 102         popl %ecx;      \
 103         popl %edx;      \
 104         popl %esi;      \
 105         popl %edi;      \
 106         popl %ebp;      \
 107         popl %eax
 108
 109 #define RESTORE_REGS    \
 110         RESTORE_INT_REGS; \
 111 1:      popl %ds;       \
 112 2:      popl %es;       \
 113 .section .fixup,"ax";   \
 114 3:      movl $0,(%esp); \
 115         jmp 1b;         \
 116 4:      movl $0,(%esp); \
 117         jmp 2b;         \
 118 .previous;              \
 119 .section __ex_table,"a";\
 120         .align 4;       \
 121         .long 1b,3b;    \
 122         .long 2b,4b;    \
 123 .previous
 124
 125
 126 ENTRY(ret_from_fork)
 127         pushl %eax
 128         call schedule_tail
 129         GET_THREAD_INFO(%ebp)
 130         popl %eax
 131         jmp syscall_exit
 132
 133 /*
 134  * Return to user mode is not as complex as all this looks,
 135  * but we want the default path for a system call return to
 136  * go as quickly as possible which is why some of this is
 137  * less clear than it otherwise should be.
 138  */
 139
 140         # userspace resumption stub bypassing syscall exit tracing
 141         ALIGN
 142 ret_from_exception:
 143         preempt_stop
 144 ret_from_intr:
 145         GET_THREAD_INFO(%ebp)
 146         movl EFLAGS(%esp), %eax         # mix EFLAGS and CS
 147         movb CS(%esp), %al
 148         testl $(VM_MASK | 3), %eax
 149         jz resume_kernel
 150 ENTRY(resume_userspace)
 151         cli                             # make sure we don't miss an interrupt
 152                                         # setting need_resched or sigpending
 153                                         # between sampling and the iret
 154         movl TI_flags(%ebp), %ecx
 155         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 156                                         # int/exception return?
 157         jne work_pending
 158         jmp restore_all
 159
 160 #ifdef CONFIG_PREEMPT
 161 ENTRY(resume_kernel)
 162         cli
 163         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 164         jnz restore_nocheck
 165 need_resched:
 166         movl TI_flags(%ebp), %ecx       # need_resched set ?
 167         testb $_TIF_NEED_RESCHED, %cl
 168         jz restore_all
 169         testl $IF_MASK,EFLAGS(%esp)     # interrupts off (exception path) ?
 170         jz restore_all
 171         call preempt_schedule_irq
 172         jmp need_resched
 173 #endif
 174
 175 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 176    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 177
 178         # sysenter call handler stub
 179 ENTRY(sysenter_entry)
 180         movl TSS_sysenter_esp0(%esp),%esp
 181 sysenter_past_esp:
 182         sti
 183         pushl $(__USER_DS)
 184         pushl %ebp
 185         pushfl
 186         pushl $(__USER_CS)
 187         pushl $SYSENTER_RETURN
 188
 189 /*
 190  * Load the potential sixth argument from user stack.
 191  * Careful about security.
 192  */
 193         cmpl $__PAGE_OFFSET-3,%ebp
 194         jae syscall_fault
 195 1:      movl (%ebp),%ebp
 196 .section __ex_table,"a"
 197         .align 4
 198         .long 1b,syscall_fault
 199 .previous
 200
 201         pushl %eax
 202         SAVE_ALL
 203         GET_THREAD_INFO(%ebp)
 204
 205         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 206         testw $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),TI_flags(%ebp)
 207         jnz syscall_trace_entry
 208         cmpl $(nr_syscalls), %eax
 209         jae syscall_badsys
 210         call *sys_call_table(,%eax,4)
 211         movl %eax,EAX(%esp)
 212         cli
 213         movl TI_flags(%ebp), %ecx
 214         testw $_TIF_ALLWORK_MASK, %cx
 215         jne syscall_exit_work
 216 /* if something modifies registers it must also disable sysexit */
 217         movl EIP(%esp), %edx
 218         movl OLDESP(%esp), %ecx
 219         xorl %ebp,%ebp
 220         sti
 221         sysexit
 222
 223
 224         # system call handler stub
 225 ENTRY(system_call)
 226         pushl %eax                      # save orig_eax
 227         SAVE_ALL
 228         GET_THREAD_INFO(%ebp)
 229                                         # system call tracing in operation
 230         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 231         testw $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),TI_flags(%ebp)
 232         jnz syscall_trace_entry
 233         cmpl $(nr_syscalls), %eax
 234         jae syscall_badsys
 235 syscall_call:
 236         call *sys_call_table(,%eax,4)
 237         movl %eax,EAX(%esp)             # store the return value
 238 syscall_exit:
 239         cli                             # make sure we don't miss an interrupt
 240                                         # setting need_resched or sigpending
 241                                         # between sampling and the iret
 242         movl TI_flags(%ebp), %ecx
 243         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 244         jne syscall_exit_work
 245
 246 restore_all:
 247         movl EFLAGS(%esp), %eax         # mix EFLAGS, SS and CS
 248         # Warning: OLDSS(%esp) contains the wrong/random values if we
 249         # are returning to the kernel.
 250         # See comments in process.c:copy_thread() for details.
 251         movb OLDSS(%esp), %ah
 252         movb CS(%esp), %al
 253         andl $(VM_MASK | (4 << 8) | 3), %eax
 254         cmpl $((4 << 8) | 3), %eax
 255         je ldt_ss                       # returning to user-space with LDT SS
 256 restore_nocheck:
 257         RESTORE_REGS
 258         addl $4, %esp
 259 1:      iret
 260 .section .fixup,"ax"
 261 iret_exc:
 262         sti
 263         pushl $0                        # no error code
 264         pushl $do_iret_error
 265         jmp error_code
 266 .previous
 267 .section __ex_table,"a"
 268         .align 4
 269         .long 1b,iret_exc
 270 .previous
 271
 272 ldt_ss:
 273         larl OLDSS(%esp), %eax
 274         jnz restore_nocheck
 275         testl $0x00400000, %eax         # returning to 32bit stack?
 276         jnz restore_nocheck             # allright, normal return
 277         /* If returning to userspace with 16bit stack,
 278          * try to fix the higher word of ESP, as the CPU
 279          * won't restore it.
 280          * This is an "official" bug of all the x86-compatible
 281          * CPUs, which we can try to work around to make
 282          * dosemu and wine happy. */
 283         subl $8, %esp           # reserve space for switch16 pointer
 284         cli
 285         movl %esp, %eax
 286         /* Set up the 16bit stack frame with switch32 pointer on top,
 287          * and a switch16 pointer on top of the current frame. */
 288         call setup_x86_bogus_stack
 289         RESTORE_REGS
 290         lss 20+4(%esp), %esp    # switch to 16bit stack
 291 1:      iret
 292 .section __ex_table,"a"
 293         .align 4
 294         .long 1b,iret_exc
 295 .previous
 296
 297         # perform work that needs to be done immediately before resumption
 298         ALIGN
 299 work_pending:
 300         testb $_TIF_NEED_RESCHED, %cl
 301         jz work_notifysig
 302 work_resched:
 303         call schedule
 304         cli                             # make sure we don't miss an interrupt
 305                                         # setting need_resched or sigpending
 306                                         # between sampling and the iret
 307         movl TI_flags(%ebp), %ecx
 308         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 309                                         # than syscall tracing?
 310         jz restore_all
 311         testb $_TIF_NEED_RESCHED, %cl
 312         jnz work_resched
 313
 314 work_notifysig:                         # deal with pending signals and
 315                                         # notify-resume requests
 316         testl $VM_MASK, EFLAGS(%esp)
 317         movl %esp, %eax
 318         jne work_notifysig_v86          # returning to kernel-space or
 319                                         # vm86-space
 320         xorl %edx, %edx
 321         call do_notify_resume
 322         jmp restore_all
 323
 324         ALIGN
 325 work_notifysig_v86:
 326         pushl %ecx                      # save ti_flags for do_notify_resume
 327         call save_v86_state             # %eax contains pt_regs pointer
 328         popl %ecx
 329         movl %eax, %esp
 330         xorl %edx, %edx
 331         call do_notify_resume
 332         jmp restore_all
 333
 334         # perform syscall exit tracing
 335         ALIGN
 336 syscall_trace_entry:
 337         movl $-ENOSYS,EAX(%esp)
 338         movl %esp, %eax
 339         xorl %edx,%edx
 340         call do_syscall_trace
 341         movl ORIG_EAX(%esp), %eax
 342         cmpl $(nr_syscalls), %eax
 343         jnae syscall_call
 344         jmp syscall_exit
 345
 346         # perform syscall exit tracing
 347         ALIGN
 348 syscall_exit_work:
 349         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
 350         jz work_pending
 351         sti                             # could let do_syscall_trace() call
 352                                         # schedule() instead
 353         movl %esp, %eax
 354         movl $1, %edx
 355         call do_syscall_trace
 356         jmp resume_userspace
 357
 358         ALIGN
 359 syscall_fault:
 360         pushl %eax                      # save orig_eax
 361         SAVE_ALL
 362         GET_THREAD_INFO(%ebp)
 363         movl $-EFAULT,EAX(%esp)
 364         jmp resume_userspace
 365
 366         ALIGN
 367 syscall_badsys:
 368         movl $-ENOSYS,EAX(%esp)
 369         jmp resume_userspace
 370
 371 #define FIXUP_ESPFIX_STACK \
 372         movl %esp, %eax; \
 373         /* switch to 32bit stack using the pointer on top of 16bit stack */ \
 374         lss %ss:CPU_16BIT_STACK_SIZE-8, %esp; \
 375         /* copy data from 16bit stack to 32bit stack */ \
 376         call fixup_x86_bogus_stack; \
 377         /* put ESP to the proper location */ \
 378         movl %eax, %esp;
 379 #define UNWIND_ESPFIX_STACK \
 380         pushl %eax; \
 381         movl %ss, %eax; \
 382         /* see if on 16bit stack */ \
 383         cmpw $__ESPFIX_SS, %ax; \
 384         jne 28f; \
 385         movl $__KERNEL_DS, %edx; \
 386         movl %edx, %ds; \
 387         movl %edx, %es; \
 388         /* switch to 32bit stack */ \
 389         FIXUP_ESPFIX_STACK \
 390 28:     popl %eax;
 391
 392 /*
 393  * Build the entry stubs and pointer table with
 394  * some assembler magic.
 395  */
 396 .data
 397 ENTRY(interrupt)
 398 .text
 399
 400 vector=0
 401 ENTRY(irq_entries_start)
 402 .rept NR_IRQS
 403         ALIGN
 404 1:      pushl $vector-256
 405         jmp common_interrupt
 406 .data
 407         .long 1b
 408 .text
 409 vector=vector+1
 410 .endr
 411
 412         ALIGN
 413 common_interrupt:
 414         SAVE_ALL
 415         movl %esp,%eax
 416         call do_IRQ
 417         jmp ret_from_intr
 418
 419 #define BUILD_INTERRUPT(name, nr)       \
 420 ENTRY(name)                             \
 421         pushl $nr-256;                  \
 422         SAVE_ALL                        \
 423         movl %esp,%eax;                 \
 424         call smp_/**/name;              \
 425         jmp ret_from_intr;
 426
 427 /* The include is where all of the SMP etc. interrupts come from */
 428 #include "entry_arch.h"
 429
 430 ENTRY(divide_error)
 431         pushl $0                        # no error code
 432         pushl $do_divide_error
 433         ALIGN
 434 error_code:
 435         pushl %ds
 436         pushl %eax
 437         xorl %eax, %eax
 438         pushl %ebp
 439         pushl %edi
 440         pushl %esi
 441         pushl %edx
 442         decl %eax                       # eax = -1
 443         pushl %ecx
 444         pushl %ebx
 445         cld
 446         pushl %es
 447         UNWIND_ESPFIX_STACK
 448         popl %ecx
 449         movl ES(%esp), %edi             # get the function address
 450         movl ORIG_EAX(%esp), %edx       # get the error code
 451         movl %eax, ORIG_EAX(%esp)
 452         movl %ecx, ES(%esp)
 453         movl $(__USER_DS), %ecx
 454         movl %ecx, %ds
 455         movl %ecx, %es
 456         movl %esp,%eax                  # pt_regs pointer
 457         call *%edi
 458         jmp ret_from_exception
 459
 460 ENTRY(coprocessor_error)
 461         pushl $0
 462         pushl $do_coprocessor_error
 463         jmp error_code
 464
 465 ENTRY(simd_coprocessor_error)
 466         pushl $0
 467         pushl $do_simd_coprocessor_error
 468         jmp error_code
 469
 470 ENTRY(device_not_available)
 471         pushl $-1                       # mark this as an int
 472         SAVE_ALL
 473         movl %cr0, %eax
 474         testl $0x4, %eax                # EM (math emulation bit)
 475         jne device_not_available_emulate
 476         preempt_stop
 477         call math_state_restore
 478         jmp ret_from_exception
 479 device_not_available_emulate:
 480         pushl $0                        # temporary storage for ORIG_EIP
 481         call math_emulate
 482         addl $4, %esp
 483         jmp ret_from_exception
 484
 485 /*
 486  * Debug traps and NMI can happen at the one SYSENTER instruction
 487  * that sets up the real kernel stack. Check here, since we can't
 488  * allow the wrong stack to be used.
 489  *
 490  * "TSS_sysenter_esp0+12" is because the NMI/debug handler will have
 491  * already pushed 3 words if it hits on the sysenter instruction:
 492  * eflags, cs and eip.
 493  *
 494  * We just load the right stack, and push the three (known) values
 495  * by hand onto the new stack - while updating the return eip past
 496  * the instruction that would have done it for sysenter.
 497  */
 498 #define FIX_STACK(offset, ok, label)            \
 499         cmpw $__KERNEL_CS,4(%esp);              \
 500         jne ok;                                 \
 501 label:                                          \
 502         movl TSS_sysenter_esp0+offset(%esp),%esp;       \
 503         pushfl;                                 \
 504         pushl $__KERNEL_CS;                     \
 505         pushl $sysenter_past_esp
 506
 507 ENTRY(debug)
 508         cmpl $sysenter_entry,(%esp)
 509         jne debug_stack_correct
 510         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
 511 debug_stack_correct:
 512         pushl $-1                       # mark this as an int
 513         SAVE_ALL
 514         xorl %edx,%edx                  # error code 0
 515         movl %esp,%eax                  # pt_regs pointer
 516         call do_debug
 517         testl %eax,%eax
 518         jnz restore_all
 519         jmp ret_from_exception
 520
 521 /*
 522  * NMI is doubly nasty. It can happen _while_ we're handling
 523  * a debug fault, and the debug fault hasn't yet been able to
 524  * clear up the stack. So we first check whether we got  an
 525  * NMI on the sysenter entry path, but after that we need to
 526  * check whether we got an NMI on the debug path where the debug
 527  * fault happened on the sysenter path.
 528  */
 529 ENTRY(nmi)
 530         pushl %eax
 531         movl %ss, %eax
 532         cmpw $__ESPFIX_SS, %ax
 533         popl %eax
 534         je nmi_16bit_stack
 535         cmpl $sysenter_entry,(%esp)
 536         je nmi_stack_fixup
 537         pushl %eax
 538         movl %esp,%eax
 539         /* Do not access memory above the end of our stack page,
 540          * it might not exist.
 541          */
 542         andl $(THREAD_SIZE-1),%eax
 543         cmpl $(THREAD_SIZE-20),%eax
 544         popl %eax
 545         jae nmi_stack_correct
 546         cmpl $sysenter_entry,12(%esp)
 547         je nmi_debug_stack_check
 548 nmi_stack_correct:
 549         pushl %eax
 550         SAVE_ALL
 551         xorl %edx,%edx          # zero error code
 552         movl %esp,%eax          # pt_regs pointer
 553         call do_nmi
 554         jmp restore_all
 555
 556 nmi_stack_fixup:
 557         FIX_STACK(12,nmi_stack_correct, 1)
 558         jmp nmi_stack_correct
 559 nmi_debug_stack_check:
 560         cmpw $__KERNEL_CS,16(%esp)
 561         jne nmi_stack_correct
 562         cmpl $debug - 1,(%esp)
 563         jle nmi_stack_correct
 564         cmpl $debug_esp_fix_insn,(%esp)
 565         jle nmi_debug_stack_fixup
 566 nmi_debug_stack_fixup:
 567         FIX_STACK(24,nmi_stack_correct, 1)
 568         jmp nmi_stack_correct
 569
 570 nmi_16bit_stack:
 571         /* create the pointer to lss back */
 572         pushl %ss
 573         pushl %esp
 574         movzwl %sp, %esp
 575         addw $4, (%esp)
 576         /* copy the iret frame of 12 bytes */
 577         .rept 3
 578         pushl 16(%esp)
 579         .endr
 580         pushl %eax
 581         SAVE_ALL
 582         FIXUP_ESPFIX_STACK              # %eax == %esp
 583         xorl %edx,%edx                  # zero error code
 584         call do_nmi
 585         RESTORE_REGS
 586         lss 12+4(%esp), %esp            # back to 16bit stack
 587 1:      iret
 588 .section __ex_table,"a"
 589         .align 4
 590         .long 1b,iret_exc
 591 .previous
 592
 593 ENTRY(int3)
 594         pushl $-1                       # mark this as an int
 595         SAVE_ALL
 596         xorl %edx,%edx          # zero error code
 597         movl %esp,%eax          # pt_regs pointer
 598         call do_int3
 599         testl %eax,%eax
 600         jnz restore_all
 601         jmp ret_from_exception
 602
 603 ENTRY(overflow)
 604         pushl $0
 605         pushl $do_overflow
 606         jmp error_code
 607
 608 ENTRY(bounds)
 609         pushl $0
 610         pushl $do_bounds
 611         jmp error_code
 612
 613 ENTRY(invalid_op)
 614         pushl $0
 615         pushl $do_invalid_op
 616         jmp error_code
 617
 618 ENTRY(coprocessor_segment_overrun)
 619         pushl $0
 620         pushl $do_coprocessor_segment_overrun
 621         jmp error_code
 622
 623 ENTRY(invalid_TSS)
 624         pushl $do_invalid_TSS
 625         jmp error_code
 626
 627 ENTRY(segment_not_present)
 628         pushl $do_segment_not_present
 629         jmp error_code
 630
 631 ENTRY(stack_segment)
 632         pushl $do_stack_segment
 633         jmp error_code
 634
 635 ENTRY(general_protection)
 636         pushl $do_general_protection
 637         jmp error_code
 638
 639 ENTRY(alignment_check)
 640         pushl $do_alignment_check
 641         jmp error_code
 642
 643 ENTRY(page_fault)
 644         pushl $do_page_fault
 645         jmp error_code
 646
 647 #ifdef CONFIG_X86_MCE
 648 ENTRY(machine_check)
 649         pushl $0
 650         pushl machine_check_vector
 651         jmp error_code
 652 #endif
 653
 654 ENTRY(spurious_interrupt_bug)
 655         pushl $0
 656         pushl $do_spurious_interrupt_bug
 657         jmp error_code
 658
 659 .data
 660 ENTRY(sys_call_table)
 661         .long sys_restart_syscall       /* 0 - old "setup()" system call, used for restarting */
 662         .long sys_exit
 663         .long sys_fork
 664         .long sys_read
 665         .long sys_write
 666         .long sys_open          /* 5 */
 667         .long sys_close
 668         .long sys_waitpid
 669         .long sys_creat
 670         .long sys_link
 671         .long sys_unlink        /* 10 */
 672         .long sys_execve
 673         .long sys_chdir
 674         .long sys_time
 675         .long sys_mknod
 676         .long sys_chmod         /* 15 */
 677         .long sys_lchown16
 678         .long sys_ni_syscall    /* old break syscall holder */
 679         .long sys_stat
 680         .long sys_lseek
 681         .long sys_getpid        /* 20 */
 682         .long sys_mount
 683         .long sys_oldumount
 684         .long sys_setuid16
 685         .long sys_getuid16
 686         .long sys_stime         /* 25 */
 687         .long sys_ptrace
 688         .long sys_alarm
 689         .long sys_fstat
 690         .long sys_pause
 691         .long sys_utime         /* 30 */
 692         .long sys_ni_syscall    /* old stty syscall holder */
 693         .long sys_ni_syscall    /* old gtty syscall holder */
 694         .long sys_access
 695         .long sys_nice
 696         .long sys_ni_syscall    /* 35 - old ftime syscall holder */
 697         .long sys_sync
 698         .long sys_kill
 699         .long sys_rename
 700         .long sys_mkdir
 701         .long sys_rmdir         /* 40 */
 702         .long sys_dup
 703         .long sys_pipe
 704         .long sys_times
 705         .long sys_ni_syscall    /* old prof syscall holder */
 706         .long sys_brk           /* 45 */
 707         .long sys_setgid16
 708         .long sys_getgid16
 709         .long sys_signal
 710         .long sys_geteuid16
 711         .long sys_getegid16     /* 50 */
 712         .long sys_acct
 713         .long sys_umount        /* recycled never used phys() */
 714         .long sys_ni_syscall    /* old lock syscall holder */
 715         .long sys_ioctl
 716         .long sys_fcntl         /* 55 */
 717         .long sys_ni_syscall    /* old mpx syscall holder */
 718         .long sys_setpgid
 719         .long sys_ni_syscall    /* old ulimit syscall holder */
 720         .long sys_olduname
 721         .long sys_umask         /* 60 */
 722         .long sys_chroot
 723         .long sys_ustat
 724         .long sys_dup2
 725         .long sys_getppid
 726         .long sys_getpgrp       /* 65 */
 727         .long sys_setsid
 728         .long sys_sigaction
 729         .long sys_sgetmask
 730         .long sys_ssetmask
 731         .long sys_setreuid16    /* 70 */
 732         .long sys_setregid16
 733         .long sys_sigsuspend
 734         .long sys_sigpending
 735         .long sys_sethostname
 736         .long sys_setrlimit     /* 75 */
 737         .long sys_old_getrlimit
 738         .long sys_getrusage
 739         .long sys_gettimeofday
 740         .long sys_settimeofday
 741         .long sys_getgroups16   /* 80 */
 742         .long sys_setgroups16
 743         .long old_select
 744         .long sys_symlink
 745         .long sys_lstat
 746         .long sys_readlink      /* 85 */
 747         .long sys_uselib
 748         .long sys_swapon
 749         .long sys_reboot
 750         .long old_readdir
 751         .long old_mmap          /* 90 */
 752         .long sys_munmap
 753         .long sys_truncate
 754         .long sys_ftruncate
 755         .long sys_fchmod
 756         .long sys_fchown16      /* 95 */
 757         .long sys_getpriority
 758         .long sys_setpriority
 759         .long sys_ni_syscall    /* old profil syscall holder */
 760         .long sys_statfs
 761         .long sys_fstatfs       /* 100 */
 762         .long sys_ioperm
 763         .long sys_socketcall
 764         .long sys_syslog
 765         .long sys_setitimer
 766         .long sys_getitimer     /* 105 */
 767         .long sys_newstat
 768         .long sys_newlstat
 769         .long sys_newfstat
 770         .long sys_uname
 771         .long sys_iopl          /* 110 */
 772         .long sys_vhangup
 773         .long sys_ni_syscall    /* old "idle" system call */
 774         .long sys_vm86old
 775         .long sys_wait4
 776         .long sys_swapoff       /* 115 */
 777         .long sys_sysinfo
 778         .long sys_ipc
 779         .long sys_fsync
 780         .long sys_sigreturn
 781         .long sys_clone         /* 120 */
 782         .long sys_setdomainname
 783         .long sys_newuname
 784         .long sys_modify_ldt
 785         .long sys_adjtimex
 786         .long sys_mprotect      /* 125 */
 787         .long sys_sigprocmask
 788         .long sys_ni_syscall    /* old "create_module" */
 789         .long sys_init_module
 790         .long sys_delete_module
 791         .long sys_ni_syscall    /* 130: old "get_kernel_syms" */
 792         .long sys_quotactl
 793         .long sys_getpgid
 794         .long sys_fchdir
 795         .long sys_bdflush
 796         .long sys_sysfs         /* 135 */
 797         .long sys_personality
 798         .long sys_ni_syscall    /* reserved for afs_syscall */
 799         .long sys_setfsuid16
 800         .long sys_setfsgid16
 801         .long sys_llseek        /* 140 */
 802         .long sys_getdents
 803         .long sys_select
 804         .long sys_flock
 805         .long sys_msync
 806         .long sys_readv         /* 145 */
 807         .long sys_writev
 808         .long sys_getsid
 809         .long sys_fdatasync
 810         .long sys_sysctl
 811         .long sys_mlock         /* 150 */
 812         .long sys_munlock
 813         .long sys_mlockall
 814         .long sys_munlockall
 815         .long sys_sched_setparam
 816         .long sys_sched_getparam   /* 155 */
 817         .long sys_sched_setscheduler
 818         .long sys_sched_getscheduler
 819         .long sys_sched_yield
 820         .long sys_sched_get_priority_max
 821         .long sys_sched_get_priority_min  /* 160 */
 822         .long sys_sched_rr_get_interval
 823         .long sys_nanosleep
 824         .long sys_mremap
 825         .long sys_setresuid16
 826         .long sys_getresuid16   /* 165 */
 827         .long sys_vm86
 828         .long sys_ni_syscall    /* Old sys_query_module */
 829         .long sys_poll
 830         .long sys_nfsservctl
 831         .long sys_setresgid16   /* 170 */
 832         .long sys_getresgid16
 833         .long sys_prctl
 834         .long sys_rt_sigreturn
 835         .long sys_rt_sigaction
 836         .long sys_rt_sigprocmask        /* 175 */
 837         .long sys_rt_sigpending
 838         .long sys_rt_sigtimedwait
 839         .long sys_rt_sigqueueinfo
 840         .long sys_rt_sigsuspend
 841         .long sys_pread64       /* 180 */
 842         .long sys_pwrite64
 843         .long sys_chown16
 844         .long sys_getcwd
 845         .long sys_capget
 846         .long sys_capset        /* 185 */
 847         .long sys_sigaltstack
 848         .long sys_sendfile
 849         .long sys_ni_syscall    /* reserved for streams1 */
 850         .long sys_ni_syscall    /* reserved for streams2 */
 851         .long sys_vfork         /* 190 */
 852         .long sys_getrlimit
 853         .long sys_mmap2
 854         .long sys_truncate64
 855         .long sys_ftruncate64
 856         .long sys_stat64        /* 195 */
 857         .long sys_lstat64
 858         .long sys_fstat64
 859         .long sys_lchown
 860         .long sys_getuid
 861         .long sys_getgid        /* 200 */
 862         .long sys_geteuid
 863         .long sys_getegid
 864         .long sys_setreuid
 865         .long sys_setregid
 866         .long sys_getgroups     /* 205 */
 867         .long sys_setgroups
 868         .long sys_fchown
 869         .long sys_setresuid
 870         .long sys_getresuid
 871         .long sys_setresgid     /* 210 */
 872         .long sys_getresgid
 873         .long sys_chown
 874         .long sys_setuid
 875         .long sys_setgid
 876         .long sys_setfsuid      /* 215 */
 877         .long sys_setfsgid
 878         .long sys_pivot_root
 879         .long sys_mincore
 880         .long sys_madvise
 881         .long sys_getdents64    /* 220 */
 882         .long sys_fcntl64
 883         .long sys_ni_syscall    /* reserved for TUX */
 884         .long sys_ni_syscall
 885         .long sys_gettid
 886         .long sys_readahead     /* 225 */
 887         .long sys_setxattr
 888         .long sys_lsetxattr
 889         .long sys_fsetxattr
 890         .long sys_getxattr
 891         .long sys_lgetxattr     /* 230 */
 892         .long sys_fgetxattr
 893         .long sys_listxattr
 894         .long sys_llistxattr
 895         .long sys_flistxattr
 896         .long sys_removexattr   /* 235 */
 897         .long sys_lremovexattr
 898         .long sys_fremovexattr
 899         .long sys_tkill
 900         .long sys_sendfile64
 901         .long sys_futex         /* 240 */
 902         .long sys_sched_setaffinity
 903         .long sys_sched_getaffinity
 904         .long sys_set_thread_area
 905         .long sys_get_thread_area
 906         .long sys_io_setup      /* 245 */
 907         .long sys_io_destroy
 908         .long sys_io_getevents
 909         .long sys_io_submit
 910         .long sys_io_cancel
 911         .long sys_fadvise64     /* 250 */
 912         .long sys_ni_syscall
 913         .long sys_exit_group
 914         .long sys_lookup_dcookie
 915         .long sys_epoll_create
 916         .long sys_epoll_ctl     /* 255 */
 917         .long sys_epoll_wait
 918         .long sys_remap_file_pages
 919         .long sys_set_tid_address
 920         .long sys_timer_create
 921         .long sys_timer_settime         /* 260 */
 922         .long sys_timer_gettime
 923         .long sys_timer_getoverrun
 924         .long sys_timer_delete
 925         .long sys_clock_settime
 926         .long sys_clock_gettime         /* 265 */
 927         .long sys_clock_getres
 928         .long sys_clock_nanosleep
 929         .long sys_statfs64
 930         .long sys_fstatfs64
 931         .long sys_tgkill        /* 270 */
 932         .long sys_utimes
 933         .long sys_fadvise64_64
 934         .long sys_ni_syscall    /* sys_vserver */
 935         .long sys_mbind
 936         .long sys_get_mempolicy
 937         .long sys_set_mempolicy
 938         .long sys_mq_open
 939         .long sys_mq_unlink
 940         .long sys_mq_timedsend
 941         .long sys_mq_timedreceive       /* 280 */
 942         .long sys_mq_notify
 943         .long sys_mq_getsetattr
 944         .long sys_ni_syscall            /* reserved for kexec */
 945         .long sys_waitid
 946         .long sys_ni_syscall            /* 285 */ /* available */
 947         .long sys_add_key
 948         .long sys_request_key
 949         .long sys_keyctl
 950
 951 syscall_table_size=(.-sys_call_table)