arch/mips/cpu/xburst/start.S

   1 /*
   2  *  Startup Code for MIPS32 XBURST CPU-core
   3  *
   4  *  Copyright (c) 2010 Xiangfu Liu <xiangfu@sharism.cc>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <config.h>
  26 #include <version.h>
  27 #include <asm/regdef.h>
  28 #include <asm/mipsregs.h>
  29 #include <asm/addrspace.h>
  30 #include <asm/cacheops.h>
  31
  32         .set noreorder
  33
  34         .globl _start
  35         .text
  36 _start:
  37         /* Initialize $gp */
  38         bal     1f
  39          nop
  40         .word   _gp
  41 1:
  42         lw      gp, 0(ra)
  43
  44         /* Set up temporary stack */
  45         li      sp, CONFIG_SYS_SDRAM_BASE + CONFIG_SYS_INIT_SP_OFFSET
  46
  47         la      t9, board_init_f
  48         jr      t9
  49          nop
  50
  51 /*
  52  * void relocate_code (addr_sp, gd, addr_moni)
  53  *
  54  * This "function" does not return, instead it continues in RAM
  55  * after relocating the monitor code.
  56  *
  57  * a0 = addr_sp
  58  * a1 = gd
  59  * a2 = destination address
  60  */
  61         .globl  relocate_code
  62         .ent    relocate_code
  63 relocate_code:
  64         move    sp, a0                  # set new stack pointer
  65
  66         li      t0, CONFIG_SYS_MONITOR_BASE
  67         sub     t6, a2, t0              # t6 <-- relocation offset
  68
  69         la      t3, in_ram
  70         lw      t2, -12(t3)             # t2 <-- uboot_end_data
  71         move    t1, a2
  72
  73         add     gp, t6                  # adjust gp
  74
  75         /*
  76          * t0 = source address
  77          * t1 = target address
  78          * t2 = source end address
  79          */
  80 1:
  81         lw      t3, 0(t0)
  82         sw      t3, 0(t1)
  83         addu    t0, 4
  84         blt     t0, t2, 1b
  85          addu   t1, 4
  86
  87         /* If caches were enabled, we would have to flush them here. */
  88
  89         /* flush d-cache */
  90         li      t0, KSEG0
  91         addi    t1, t0, CONFIG_SYS_DCACHE_SIZE
  92 2:
  93         cache   INDEX_WRITEBACK_INV_D, 0(t0)
  94         bne     t0, t1, 2b
  95          addi   t0, CONFIG_SYS_CACHELINE_SIZE
  96
  97         sync
  98
  99         /* flush i-cache */
 100         li      t0, KSEG0
 101         addi    t1, t0, CONFIG_SYS_ICACHE_SIZE
 102 3:
 103         cache   INDEX_INVALIDATE_I, 0(t0)
 104         bne     t0, t1, 3b
 105          addi   t0, CONFIG_SYS_CACHELINE_SIZE
 106
 107         /* Invalidate BTB */
 108         mfc0    t0, CP0_CONFIG, 7
 109         nop
 110         ori     t0, 2
 111         mtc0    t0, CP0_CONFIG, 7
 112         nop
 113
 114         /* Jump to where we've relocated ourselves */
 115         addi    t0, a2, in_ram - _start
 116         jr      t0
 117          nop
 118
 119         .word   _GLOBAL_OFFSET_TABLE_
 120         .word   uboot_end_data
 121         .word   uboot_end
 122         .word   num_got_entries
 123
 124 in_ram:
 125         /*
 126          * Now we want to update GOT.
 127          *
 128          * GOT[0] is reserved. GOT[1] is also reserved for the dynamic object
 129          * generated by GNU ld. Skip these reserved entries from relocation.
 130          */
 131         lw      t3, -4(t0)              # t3 <-- num_got_entries
 132         lw      t4, -16(t0)             # t4 <-- _GLOBAL_OFFSET_TABLE_
 133         add     t4, t6                  # t4 now holds relocated _G_O_T_
 134         addi    t4, t4, 8               # skipping first two entries
 135         li      t2, 2
 136 1:
 137         lw      t1, 0(t4)
 138         beqz    t1, 2f
 139          add    t1, t6
 140         sw      t1, 0(t4)
 141 2:
 142         addi    t2, 1
 143         blt     t2, t3, 1b
 144          addi   t4, 4
 145
 146         /* Clear BSS */
 147         lw      t1, -12(t0)             # t1 <-- uboot_end_data
 148         lw      t2, -8(t0)              # t2 <-- uboot_end
 149         add     t1, t6                  # adjust pointers
 150         add     t2, t6
 151
 152         sub     t1, 4
 153 1:      addi    t1, 4
 154         bltl    t1, t2, 1b
 155          sw     zero, 0(t1)
 156
 157         move    a0, a1                  # a0 <-- gd
 158         la      t9, board_init_r
 159         jr      t9
 160          move   a1, a2
 161
 162         .end    relocate_code