arch/nds32/cpu/n1213/ag101/lowlevel_init.S

   1 /*
   2  * Copyright (C) 2011 Andes Technology Corporation
   3  * Shawn Lin, Andes Technology Corporation <nobuhiro@andestech.com>
   4  * Macpaul Lin, Andes Technology Corporation <macpaul@andestech.com>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 .text
  26
  27 #include <common.h>
  28 #include <config.h>
  29
  30 #include <asm/macro.h>
  31 #include <generated/asm-offsets.h>
  32
  33 /*
  34  * parameters for the SDRAM controller
  35  */
  36 #define SDMC_TP1_A              (CONFIG_FTSDMC021_BASE + FTSDMC021_TP1)
  37 #define SDMC_TP2_A              (CONFIG_FTSDMC021_BASE + FTSDMC021_TP2)
  38 #define SDMC_CR1_A              (CONFIG_FTSDMC021_BASE + FTSDMC021_CR1)
  39 #define SDMC_CR2_A              (CONFIG_FTSDMC021_BASE + FTSDMC021_CR2)
  40 #define SDMC_B0_BSR_A           (CONFIG_FTSDMC021_BASE + FTSDMC021_BANK0_BSR)
  41 #define SDMC_B1_BSR_A           (CONFIG_FTSDMC021_BASE + FTSDMC021_BANK1_BSR)
  42
  43 #define SDMC_TP1_D              CONFIG_SYS_FTSDMC021_TP1
  44 #define SDMC_TP2_D              CONFIG_SYS_FTSDMC021_TP2
  45 #define SDMC_CR1_D              CONFIG_SYS_FTSDMC021_CR1
  46 #define SDMC_CR2_D              CONFIG_SYS_FTSDMC021_CR2
  47
  48 #define SDMC_B0_BSR_D           CONFIG_SYS_FTSDMC021_BANK0_BSR
  49 #define SDMC_B1_BSR_D           CONFIG_SYS_FTSDMC021_BANK1_BSR
  50
  51 /*
  52  * parameters for the static memory controller
  53  */
  54 #define SMC_BANK0_CR_A          (CONFIG_FTSMC020_BASE + FTSMC020_BANK0_CR)
  55 #define SMC_BANK0_TPR_A         (CONFIG_FTSMC020_BASE + FTSMC020_BANK0_TPR)
  56
  57 #define SMC_BANK0_CR_D          FTSMC020_BANK0_LOWLV_CONFIG
  58 #define SMC_BANK0_TPR_D         FTSMC020_BANK0_LOWLV_TIMING
  59
  60 /*
  61  * parameters for the ahbc controller
  62  */
  63 #define AHBC_CR_A               (CONFIG_FTAHBC020S_BASE + FTAHBC020S_CR)
  64 #define AHBC_BSR6_A     (CONFIG_FTAHBC020S_BASE + FTAHBC020S_SLAVE_BSR_6)
  65
  66 #define AHBC_BSR6_D             CONFIG_SYS_FTAHBC020S_SLAVE_BSR_6
  67
  68 /*
  69  * parameters for the pmu controoler
  70  */
  71 #define PMU_PDLLCR0_A           (CONFIG_FTPMU010_BASE + FTPMU010_PDLLCR0)
  72
  73 /*
  74  * numeric 7 segment display
  75  */
  76 .macro  led, num
  77         write32 CONFIG_DEBUG_LED, \num
  78 .endm
  79
  80 /*
  81  * Waiting for SDRAM to set up
  82  */
  83 .macro  wait_sdram
  84         li      $r0, CONFIG_FTSDMC021_BASE
  85 1:
  86         lwi     $r1, [$r0+FTSDMC021_CR2]
  87         bnez    $r1, 1b
  88 .endm
  89
  90 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
  91 .globl  lowlevel_init
  92 lowlevel_init:
  93         move    $r10, $lp
  94
  95         led     0x0
  96         jal     mem_init
  97
  98         led     0x10
  99         jal     remap
 100
 101 #if (defined(NDS32_EXT_FPU_DP) || defined(NDS32_EXT_FPU_SP))
 102         led     0x1f
 103         jal     enable_fpu
 104 #endif
 105
 106         led     0x20
 107         ret     $r10
 108
 109 mem_init:
 110         move    $r11, $lp
 111
 112         /*
 113          * mem_init:
 114          *      There are 2 bank connected to FTSMC020 on AG101
 115          *      BANK0: FLASH/ROM (SW5, J16), BANK1: OnBoard SDRAM.
 116          *      we need to set onboard SDRAM before remap and relocation.
 117          */
 118         led     0x01
 119         write32 SMC_BANK0_CR_A, SMC_BANK0_CR_D                  ! 0x10000052
 120         write32 SMC_BANK0_TPR_A, SMC_BANK0_TPR_D                ! 0x00151151
 121
 122         /*
 123          * config AHB Controller
 124          */
 125         led     0x02
 126         write32 AHBC_BSR6_A, AHBC_BSR6_D
 127
 128         /*
 129          * config PMU controller
 130          */
 131         /* ftpmu010_dlldis_disable, must do it in lowleve_init */
 132         led     0x03
 133         setbf32 PMU_PDLLCR0_A, FTPMU010_PDLLCR0_DLLDIS          ! 0x00010000
 134
 135         /*
 136          * config SDRAM controller
 137          */
 138         led     0x04
 139         write32 SDMC_TP1_A, SDMC_TP1_D                          ! 0x00011312
 140         led     0x05
 141         write32 SDMC_TP2_A, SDMC_TP2_D                          ! 0x00480180
 142         led     0x06
 143         write32 SDMC_CR1_A, SDMC_CR1_D                          ! 0x00002326
 144
 145         led     0x07
 146         write32 SDMC_CR2_A, FTSDMC021_CR2_IPREC                 ! 0x00000010
 147         wait_sdram
 148
 149         led     0x08
 150         write32 SDMC_CR2_A, FTSDMC021_CR2_ISMR                  ! 0x00000004
 151         wait_sdram
 152
 153         led     0x09
 154         write32 SDMC_CR2_A, FTSDMC021_CR2_IREF                  ! 0x00000008
 155         wait_sdram
 156
 157         led     0x0a
 158         move    $lp, $r11
 159         ret
 160
 161 remap:
 162         move    $r11, $lp
 163 #ifdef __NDS32_N1213_43U1H__    /* NDS32 V0 ISA - AG101 Only */
 164         bal     2f
 165 relo_base:
 166         move    $r0, $lp
 167 #else
 168 relo_base:
 169         mfusr   $r0, $pc
 170 #endif /* __NDS32_N1213_43U1H__ */
 171
 172         /*
 173          * Remapping
 174          */
 175         led     0x1a
 176         write32 SDMC_B0_BSR_A, SDMC_B0_BSR_D            ! 0x00001100
 177         write32 SDMC_B1_BSR_A, SDMC_B1_BSR_D            ! 0x00001140
 178
 179         /* clear empty BSR registers */
 180         led     0x1b
 181         li      $r4, CONFIG_FTSDMC021_BASE
 182         li      $r5, 0x0
 183         swi     $r5, [$r4 + FTSDMC021_BANK2_BSR]
 184         swi     $r5, [$r4 + FTSDMC021_BANK3_BSR]
 185
 186 #ifdef CONFIG_MEM_REMAP
 187         /*
 188          * Copy ROM code to SDRAM base for memory remap layout.
 189          * This is not the real relocation, the real relocation is the function
 190          * relocate_code() is start.S which supports the systems is memory
 191          * remapped or not.
 192          */
 193         /*
 194          * Doing memory remap is essential for preparing some non-OS or RTOS
 195          * applications.
 196          *
 197          * This is also a must on ADP-AG101 board.
 198          * The reason is because the ROM/FLASH circuit on PCB board.
 199          * AG101-A0 board has 2 jumpers MA17 and SW5 to configure which
 200          * ROM/FLASH is used to boot.
 201          *
 202          * When SW5 = "0101", MA17 = LO, the ROM is connected to BANK0,
 203          * and the FLASH is connected to BANK1.
 204          * When SW5 = "1010", MA17 = HI, the ROM is disabled (still at BANK0),
 205          * and the FLASH is connected to BANK0.
 206          * It will occur problem when doing flash probing if the flash is at
 207          * BANK0 (0x00000000) while memory remapping was skipped.
 208          *
 209          * Other board like ADP-AG101P may not enable this since there is only
 210          * a FLASH connected to bank0.
 211          */
 212         led     0x11
 213         li      $r4, PHYS_SDRAM_0_AT_INIT               /* 0x10000000 */
 214         li      $r5, 0x0
 215         la      $r1, relo_base                          /* get $pc or $lp */
 216         sub     $r2, $r0, $r1
 217         sethi   $r6, hi20(_end)
 218         ori     $r6, $r6, lo12(_end)
 219         add     $r6, $r6, $r2
 220 1:
 221         lwi.p   $r7, [$r5], #4
 222         swi.p   $r7, [$r4], #4
 223         blt     $r5, $r6, 1b
 224
 225         /* set remap bit */
 226         /*
 227          * MEM remap bit is operational
 228          * - use it to map writeable memory at 0x00000000, in place of flash
 229          * - before remap: flash/rom 0x00000000, sdram: 0x10000000-0x4fffffff
 230          * - after  remap: flash/rom 0x80000000, sdram: 0x00000000
 231          */
 232         led     0x1c
 233         write32 SDMC_B0_BSR_A, 0x00001000
 234         write32 SDMC_B1_BSR_A, 0x00001040
 235         setbf15 AHBC_CR_A, FTAHBC020S_CR_REMAP          ! 0x1
 236
 237 #endif /* #ifdef CONFIG_MEM_REMAP */
 238         move    $lp, $r11
 239 2:
 240         ret
 241
 242         /*
 243          * enable_fpu:
 244          *  Some of Andes CPU version support FPU coprocessor, if so,
 245          *  and toolchain support FPU instruction set, we should enable it.
 246          */
 247 #if (defined(NDS32_EXT_FPU_DP) || defined(NDS32_EXT_FPU_SP))
 248 enable_fpu:
 249         mfsr    $r0, $CPU_VER     /* enable FPU if it exists */
 250         srli    $r0, $r0, 3
 251         andi    $r0, $r0, 1
 252         beqz    $r0, 1f           /* skip if no COP */
 253         mfsr    $r0, $FUCOP_EXIST
 254         srli    $r0, $r0, 31
 255         beqz    $r0, 1f           /* skip if no FPU */
 256         mfsr    $r0, $FUCOP_CTL
 257         ori     $r0, $r0, 1
 258         mtsr    $r0, $FUCOP_CTL
 259 1:
 260         ret
 261 #endif
 262
 263 .globl show_led
 264 show_led:
 265     li      $r8, (CONFIG_DEBUG_LED)
 266     swi     $r7, [$r8]
 267     ret
 268 #endif /* #ifndef CONFIG_SKIP_LOWLEVEL_INIT */