arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60 #include <asm/smap.h>
  61
  62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  63 #include <linux/elf-em.h>
  64 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67 #ifndef CONFIG_AUDITSYSCALL
  68 #define sysenter_audit  syscall_trace_entry
  69 #define sysexit_audit   syscall_exit_work
  70 #endif
  71
  72         .section .entry.text, "ax"
  73
  74 /*
  75  * We use macros for low-level operations which need to be overridden
  76  * for paravirtualization.  The following will never clobber any registers:
  77  *   INTERRUPT_RETURN (aka. "iret")
  78  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  79  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  80  *
  81  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  82  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  83  * Allowing a register to be clobbered can shrink the paravirt replacement
  84  * enough to patch inline, increasing performance.
  85  */
  86
  87 #ifdef CONFIG_PREEMPT
  88 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  89 #else
  90 #define preempt_stop(clobbers)
  91 #define resume_kernel           restore_all
  92 #endif
  93
  94 .macro TRACE_IRQS_IRET
  95 #ifdef CONFIG_TRACE_IRQFLAGS
  96         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  97         jz 1f
  98         TRACE_IRQS_ON
  99 1:
 100 #endif
 101 .endm
 102
 103 /*
 104  * User gs save/restore
 105  *
 106  * %gs is used for userland TLS and kernel only uses it for stack
 107  * canary which is required to be at %gs:20 by gcc.  Read the comment
 108  * at the top of stackprotector.h for more info.
 109  *
 110  * Local labels 98 and 99 are used.
 111  */
 112 #ifdef CONFIG_X86_32_LAZY_GS
 113
 114  /* unfortunately push/pop can't be no-op */
 115 .macro PUSH_GS
 116         pushl_cfi $0
 117 .endm
 118 .macro POP_GS pop=0
 119         addl $(4 + \pop), %esp
 120         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 121 .endm
 122 .macro POP_GS_EX
 123 .endm
 124
 125  /* all the rest are no-op */
 126 .macro PTGS_TO_GS
 127 .endm
 128 .macro PTGS_TO_GS_EX
 129 .endm
 130 .macro GS_TO_REG reg
 131 .endm
 132 .macro REG_TO_PTGS reg
 133 .endm
 134 .macro SET_KERNEL_GS reg
 135 .endm
 136
 137 #else   /* CONFIG_X86_32_LAZY_GS */
 138
 139 .macro PUSH_GS
 140         pushl_cfi %gs
 141         /*CFI_REL_OFFSET gs, 0*/
 142 .endm
 143
 144 .macro POP_GS pop=0
 145 98:     popl_cfi %gs
 146         /*CFI_RESTORE gs*/
 147   .if \pop <> 0
 148         add $\pop, %esp
 149         CFI_ADJUST_CFA_OFFSET -\pop
 150   .endif
 151 .endm
 152 .macro POP_GS_EX
 153 .pushsection .fixup, "ax"
 154 99:     movl $0, (%esp)
 155         jmp 98b
 156 .popsection
 157         _ASM_EXTABLE(98b,99b)
 158 .endm
 159
 160 .macro PTGS_TO_GS
 161 98:     mov PT_GS(%esp), %gs
 162 .endm
 163 .macro PTGS_TO_GS_EX
 164 .pushsection .fixup, "ax"
 165 99:     movl $0, PT_GS(%esp)
 166         jmp 98b
 167 .popsection
 168         _ASM_EXTABLE(98b,99b)
 169 .endm
 170
 171 .macro GS_TO_REG reg
 172         movl %gs, \reg
 173         /*CFI_REGISTER gs, \reg*/
 174 .endm
 175 .macro REG_TO_PTGS reg
 176         movl \reg, PT_GS(%esp)
 177         /*CFI_REL_OFFSET gs, PT_GS*/
 178 .endm
 179 .macro SET_KERNEL_GS reg
 180         movl $(__KERNEL_STACK_CANARY), \reg
 181         movl \reg, %gs
 182 .endm
 183
 184 #endif  /* CONFIG_X86_32_LAZY_GS */
 185
 186 .macro SAVE_ALL
 187         cld
 188         PUSH_GS
 189         pushl_cfi %fs
 190         /*CFI_REL_OFFSET fs, 0;*/
 191         pushl_cfi %es
 192         /*CFI_REL_OFFSET es, 0;*/
 193         pushl_cfi %ds
 194         /*CFI_REL_OFFSET ds, 0;*/
 195         pushl_cfi %eax
 196         CFI_REL_OFFSET eax, 0
 197         pushl_cfi %ebp
 198         CFI_REL_OFFSET ebp, 0
 199         pushl_cfi %edi
 200         CFI_REL_OFFSET edi, 0
 201         pushl_cfi %esi
 202         CFI_REL_OFFSET esi, 0
 203         pushl_cfi %edx
 204         CFI_REL_OFFSET edx, 0
 205         pushl_cfi %ecx
 206         CFI_REL_OFFSET ecx, 0
 207         pushl_cfi %ebx
 208         CFI_REL_OFFSET ebx, 0
 209         movl $(__USER_DS), %edx
 210         movl %edx, %ds
 211         movl %edx, %es
 212         movl $(__KERNEL_PERCPU), %edx
 213         movl %edx, %fs
 214         SET_KERNEL_GS %edx
 215 .endm
 216
 217 .macro RESTORE_INT_REGS
 218         popl_cfi %ebx
 219         CFI_RESTORE ebx
 220         popl_cfi %ecx
 221         CFI_RESTORE ecx
 222         popl_cfi %edx
 223         CFI_RESTORE edx
 224         popl_cfi %esi
 225         CFI_RESTORE esi
 226         popl_cfi %edi
 227         CFI_RESTORE edi
 228         popl_cfi %ebp
 229         CFI_RESTORE ebp
 230         popl_cfi %eax
 231         CFI_RESTORE eax
 232 .endm
 233
 234 .macro RESTORE_REGS pop=0
 235         RESTORE_INT_REGS
 236 1:      popl_cfi %ds
 237         /*CFI_RESTORE ds;*/
 238 2:      popl_cfi %es
 239         /*CFI_RESTORE es;*/
 240 3:      popl_cfi %fs
 241         /*CFI_RESTORE fs;*/
 242         POP_GS \pop
 243 .pushsection .fixup, "ax"
 244 4:      movl $0, (%esp)
 245         jmp 1b
 246 5:      movl $0, (%esp)
 247         jmp 2b
 248 6:      movl $0, (%esp)
 249         jmp 3b
 250 .popsection
 251         _ASM_EXTABLE(1b,4b)
 252         _ASM_EXTABLE(2b,5b)
 253         _ASM_EXTABLE(3b,6b)
 254         POP_GS_EX
 255 .endm
 256
 257 .macro RING0_INT_FRAME
 258         CFI_STARTPROC simple
 259         CFI_SIGNAL_FRAME
 260         CFI_DEF_CFA esp, 3*4
 261         /*CFI_OFFSET cs, -2*4;*/
 262         CFI_OFFSET eip, -3*4
 263 .endm
 264
 265 .macro RING0_EC_FRAME
 266         CFI_STARTPROC simple
 267         CFI_SIGNAL_FRAME
 268         CFI_DEF_CFA esp, 4*4
 269         /*CFI_OFFSET cs, -2*4;*/
 270         CFI_OFFSET eip, -3*4
 271 .endm
 272
 273 .macro RING0_PTREGS_FRAME
 274         CFI_STARTPROC simple
 275         CFI_SIGNAL_FRAME
 276         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 277         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 278         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 279         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 280         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 281         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 282         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 283         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 284         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 285         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 286         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 287         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 288 .endm
 289
 290 ENTRY(ret_from_fork)
 291         CFI_STARTPROC
 292         pushl_cfi %eax
 293         call schedule_tail
 294         GET_THREAD_INFO(%ebp)
 295         popl_cfi %eax
 296         pushl_cfi $0x0202               # Reset kernel eflags
 297         popfl_cfi
 298         jmp syscall_exit
 299         CFI_ENDPROC
 300 END(ret_from_fork)
 301
 302 ENTRY(ret_from_kernel_thread)
 303         CFI_STARTPROC
 304         pushl_cfi %eax
 305         call schedule_tail
 306         GET_THREAD_INFO(%ebp)
 307         popl_cfi %eax
 308         pushl_cfi $0x0202               # Reset kernel eflags
 309         popfl_cfi
 310         movl PT_EBP(%esp),%eax
 311         call *PT_EBX(%esp)
 312         movl $0,PT_EAX(%esp)
 313         jmp syscall_exit
 314         CFI_ENDPROC
 315 ENDPROC(ret_from_kernel_thread)
 316
 317 /*
 318  * Return to user mode is not as complex as all this looks,
 319  * but we want the default path for a system call return to
 320  * go as quickly as possible which is why some of this is
 321  * less clear than it otherwise should be.
 322  */
 323
 324         # userspace resumption stub bypassing syscall exit tracing
 325         ALIGN
 326         RING0_PTREGS_FRAME
 327 ret_from_exception:
 328         preempt_stop(CLBR_ANY)
 329 ret_from_intr:
 330         GET_THREAD_INFO(%ebp)
 331 #ifdef CONFIG_VM86
 332         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 333         movb PT_CS(%esp), %al
 334         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 335 #else
 336         /*
 337          * We can be coming here from child spawned by kernel_thread().
 338          */
 339         movl PT_CS(%esp), %eax
 340         andl $SEGMENT_RPL_MASK, %eax
 341 #endif
 342         cmpl $USER_RPL, %eax
 343         jb resume_kernel                # not returning to v8086 or userspace
 344
 345 ENTRY(resume_userspace)
 346         LOCKDEP_SYS_EXIT
 347         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 348                                         # setting need_resched or sigpending
 349                                         # between sampling and the iret
 350         TRACE_IRQS_OFF
 351         movl TI_flags(%ebp), %ecx
 352         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 353                                         # int/exception return?
 354         jne work_pending
 355         jmp restore_all
 356 END(ret_from_exception)
 357
 358 #ifdef CONFIG_PREEMPT
 359 ENTRY(resume_kernel)
 360         DISABLE_INTERRUPTS(CLBR_ANY)
 361 need_resched:
 362         cmpl $0,PER_CPU_VAR(__preempt_count)
 363         jnz restore_all
 364         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 365         jz restore_all
 366         call preempt_schedule_irq
 367         jmp need_resched
 368 END(resume_kernel)
 369 #endif
 370         CFI_ENDPROC
 371
 372 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 373    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 374
 375         # sysenter call handler stub
 376 ENTRY(ia32_sysenter_target)
 377         CFI_STARTPROC simple
 378         CFI_SIGNAL_FRAME
 379         CFI_DEF_CFA esp, 0
 380         CFI_REGISTER esp, ebp
 381         movl TSS_sysenter_sp0(%esp),%esp
 382 sysenter_past_esp:
 383         /*
 384          * Interrupts are disabled here, but we can't trace it until
 385          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 386          * we immediately enable interrupts at that point anyway.
 387          */
 388         pushl_cfi $__USER_DS
 389         /*CFI_REL_OFFSET ss, 0*/
 390         pushl_cfi %ebp
 391         CFI_REL_OFFSET esp, 0
 392         pushfl_cfi
 393         orl $X86_EFLAGS_IF, (%esp)
 394         pushl_cfi $__USER_CS
 395         /*CFI_REL_OFFSET cs, 0*/
 396         /*
 397          * Push current_thread_info()->sysenter_return to the stack.
 398          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 399          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 400          */
 401         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 402         CFI_REL_OFFSET eip, 0
 403
 404         pushl_cfi %eax
 405         SAVE_ALL
 406         ENABLE_INTERRUPTS(CLBR_NONE)
 407
 408 /*
 409  * Load the potential sixth argument from user stack.
 410  * Careful about security.
 411  */
 412         cmpl $__PAGE_OFFSET-3,%ebp
 413         jae syscall_fault
 414         ASM_STAC
 415 1:      movl (%ebp),%ebp
 416         ASM_CLAC
 417         movl %ebp,PT_EBP(%esp)
 418         _ASM_EXTABLE(1b,syscall_fault)
 419
 420         GET_THREAD_INFO(%ebp)
 421
 422         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 423         jnz sysenter_audit
 424 sysenter_do_call:
 425         cmpl $(NR_syscalls), %eax
 426         jae syscall_badsys
 427         call *sys_call_table(,%eax,4)
 428         movl %eax,PT_EAX(%esp)
 429         LOCKDEP_SYS_EXIT
 430         DISABLE_INTERRUPTS(CLBR_ANY)
 431         TRACE_IRQS_OFF
 432         movl TI_flags(%ebp), %ecx
 433         testl $_TIF_ALLWORK_MASK, %ecx
 434         jne sysexit_audit
 435 sysenter_exit:
 436 /* if something modifies registers it must also disable sysexit */
 437         movl PT_EIP(%esp), %edx
 438         movl PT_OLDESP(%esp), %ecx
 439         xorl %ebp,%ebp
 440         TRACE_IRQS_ON
 441 1:      mov  PT_FS(%esp), %fs
 442         PTGS_TO_GS
 443         ENABLE_INTERRUPTS_SYSEXIT
 444
 445 #ifdef CONFIG_AUDITSYSCALL
 446 sysenter_audit:
 447         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 448         jnz syscall_trace_entry
 449         addl $4,%esp
 450         CFI_ADJUST_CFA_OFFSET -4
 451         movl %esi,4(%esp)               /* 5th arg: 4th syscall arg */
 452         movl %edx,(%esp)                /* 4th arg: 3rd syscall arg */
 453         /* %ecx already in %ecx            3rd arg: 2nd syscall arg */
 454         movl %ebx,%edx                  /* 2nd arg: 1st syscall arg */
 455         /* %eax already in %eax            1st arg: syscall number */
 456         call __audit_syscall_entry
 457         pushl_cfi %ebx
 458         movl PT_EAX(%esp),%eax          /* reload syscall number */
 459         jmp sysenter_do_call
 460
 461 sysexit_audit:
 462         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 463         jne syscall_exit_work
 464         TRACE_IRQS_ON
 465         ENABLE_INTERRUPTS(CLBR_ANY)
 466         movl %eax,%edx          /* second arg, syscall return value */
 467         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 468         setbe %al               /* 1 if so, 0 if not */
 469         movzbl %al,%eax         /* zero-extend that */
 470         call __audit_syscall_exit
 471         DISABLE_INTERRUPTS(CLBR_ANY)
 472         TRACE_IRQS_OFF
 473         movl TI_flags(%ebp), %ecx
 474         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 475         jne syscall_exit_work
 476         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 477         jmp sysenter_exit
 478 #endif
 479
 480         CFI_ENDPROC
 481 .pushsection .fixup,"ax"
 482 2:      movl $0,PT_FS(%esp)
 483         jmp 1b
 484 .popsection
 485         _ASM_EXTABLE(1b,2b)
 486         PTGS_TO_GS_EX
 487 ENDPROC(ia32_sysenter_target)
 488
 489         # system call handler stub
 490 ENTRY(system_call)
 491         RING0_INT_FRAME                 # can't unwind into user space anyway
 492         ASM_CLAC
 493         pushl_cfi %eax                  # save orig_eax
 494         SAVE_ALL
 495         GET_THREAD_INFO(%ebp)
 496                                         # system call tracing in operation / emulation
 497         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 498         jnz syscall_trace_entry
 499         cmpl $(NR_syscalls), %eax
 500         jae syscall_badsys
 501 syscall_call:
 502         call *sys_call_table(,%eax,4)
 503         movl %eax,PT_EAX(%esp)          # store the return value
 504 syscall_exit:
 505         LOCKDEP_SYS_EXIT
 506         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 507                                         # setting need_resched or sigpending
 508                                         # between sampling and the iret
 509         TRACE_IRQS_OFF
 510         movl TI_flags(%ebp), %ecx
 511         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 512         jne syscall_exit_work
 513
 514 restore_all:
 515         TRACE_IRQS_IRET
 516 restore_all_notrace:
 517 #ifdef CONFIG_X86_ESPFIX32
 518         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 519         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 520         # are returning to the kernel.
 521         # See comments in process.c:copy_thread() for details.
 522         movb PT_OLDSS(%esp), %ah
 523         movb PT_CS(%esp), %al
 524         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 525         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 526         CFI_REMEMBER_STATE
 527         je ldt_ss                       # returning to user-space with LDT SS
 528 #endif
 529 restore_nocheck:
 530         RESTORE_REGS 4                  # skip orig_eax/error_code
 531 irq_return:
 532         INTERRUPT_RETURN
 533 .section .fixup,"ax"
 534 ENTRY(iret_exc)
 535         pushl $0                        # no error code
 536         pushl $do_iret_error
 537         jmp error_code
 538 .previous
 539         _ASM_EXTABLE(irq_return,iret_exc)
 540
 541 #ifdef CONFIG_X86_ESPFIX32
 542         CFI_RESTORE_STATE
 543 ldt_ss:
 544 #ifdef CONFIG_PARAVIRT
 545         /*
 546          * The kernel can't run on a non-flat stack if paravirt mode
 547          * is active.  Rather than try to fixup the high bits of
 548          * ESP, bypass this code entirely.  This may break DOSemu
 549          * and/or Wine support in a paravirt VM, although the option
 550          * is still available to implement the setting of the high
 551          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 552          */
 553         cmpl $0, pv_info+PARAVIRT_enabled
 554         jne restore_nocheck
 555 #endif
 556
 557 /*
 558  * Setup and switch to ESPFIX stack
 559  *
 560  * We're returning to userspace with a 16 bit stack. The CPU will not
 561  * restore the high word of ESP for us on executing iret... This is an
 562  * "official" bug of all the x86-compatible CPUs, which we can work
 563  * around to make dosemu and wine happy. We do this by preloading the
 564  * high word of ESP with the high word of the userspace ESP while
 565  * compensating for the offset by changing to the ESPFIX segment with
 566  * a base address that matches for the difference.
 567  */
 568 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 569         mov %esp, %edx                  /* load kernel esp */
 570         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 571         mov %dx, %ax                    /* eax: new kernel esp */
 572         sub %eax, %edx                  /* offset (low word is 0) */
 573         shr $16, %edx
 574         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 575         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 576         pushl_cfi $__ESPFIX_SS
 577         pushl_cfi %eax                  /* new kernel esp */
 578         /* Disable interrupts, but do not irqtrace this section: we
 579          * will soon execute iret and the tracer was already set to
 580          * the irqstate after the iret */
 581         DISABLE_INTERRUPTS(CLBR_EAX)
 582         lss (%esp), %esp                /* switch to espfix segment */
 583         CFI_ADJUST_CFA_OFFSET -8
 584         jmp restore_nocheck
 585 #endif
 586         CFI_ENDPROC
 587 ENDPROC(system_call)
 588
 589         # perform work that needs to be done immediately before resumption
 590         ALIGN
 591         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 592 work_pending:
 593         testb $_TIF_NEED_RESCHED, %cl
 594         jz work_notifysig
 595 work_resched:
 596         call schedule
 597         LOCKDEP_SYS_EXIT
 598         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 599                                         # setting need_resched or sigpending
 600                                         # between sampling and the iret
 601         TRACE_IRQS_OFF
 602         movl TI_flags(%ebp), %ecx
 603         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 604                                         # than syscall tracing?
 605         jz restore_all
 606         testb $_TIF_NEED_RESCHED, %cl
 607         jnz work_resched
 608
 609 work_notifysig:                         # deal with pending signals and
 610                                         # notify-resume requests
 611 #ifdef CONFIG_VM86
 612         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 613         movl %esp, %eax
 614         jne work_notifysig_v86          # returning to kernel-space or
 615                                         # vm86-space
 616 1:
 617 #else
 618         movl %esp, %eax
 619 #endif
 620         TRACE_IRQS_ON
 621         ENABLE_INTERRUPTS(CLBR_NONE)
 622         movb PT_CS(%esp), %bl
 623         andb $SEGMENT_RPL_MASK, %bl
 624         cmpb $USER_RPL, %bl
 625         jb resume_kernel
 626         xorl %edx, %edx
 627         call do_notify_resume
 628         jmp resume_userspace
 629
 630 #ifdef CONFIG_VM86
 631         ALIGN
 632 work_notifysig_v86:
 633         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 634         call save_v86_state             # %eax contains pt_regs pointer
 635         popl_cfi %ecx
 636         movl %eax, %esp
 637         jmp 1b
 638 #endif
 639 END(work_pending)
 640
 641         # perform syscall exit tracing
 642         ALIGN
 643 syscall_trace_entry:
 644         movl $-ENOSYS,PT_EAX(%esp)
 645         movl %esp, %eax
 646         call syscall_trace_enter
 647         /* What it returned is what we'll actually use.  */
 648         cmpl $(NR_syscalls), %eax
 649         jnae syscall_call
 650         jmp syscall_exit
 651 END(syscall_trace_entry)
 652
 653         # perform syscall exit tracing
 654         ALIGN
 655 syscall_exit_work:
 656         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 657         jz work_pending
 658         TRACE_IRQS_ON
 659         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 660                                         # schedule() instead
 661         movl %esp, %eax
 662         call syscall_trace_leave
 663         jmp resume_userspace
 664 END(syscall_exit_work)
 665         CFI_ENDPROC
 666
 667         RING0_INT_FRAME                 # can't unwind into user space anyway
 668 syscall_fault:
 669         ASM_CLAC
 670         GET_THREAD_INFO(%ebp)
 671         movl $-EFAULT,PT_EAX(%esp)
 672         jmp resume_userspace
 673 END(syscall_fault)
 674
 675 syscall_badsys:
 676         movl $-ENOSYS,PT_EAX(%esp)
 677         jmp resume_userspace
 678 END(syscall_badsys)
 679         CFI_ENDPROC
 680
 681 .macro FIXUP_ESPFIX_STACK
 682 /*
 683  * Switch back for ESPFIX stack to the normal zerobased stack
 684  *
 685  * We can't call C functions using the ESPFIX stack. This code reads
 686  * the high word of the segment base from the GDT and swiches to the
 687  * normal stack and adjusts ESP with the matching offset.
 688  */
 689 #ifdef CONFIG_X86_ESPFIX32
 690         /* fixup the stack */
 691         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 692         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 693         shl $16, %eax
 694         addl %esp, %eax                 /* the adjusted stack pointer */
 695         pushl_cfi $__KERNEL_DS
 696         pushl_cfi %eax
 697         lss (%esp), %esp                /* switch to the normal stack segment */
 698         CFI_ADJUST_CFA_OFFSET -8
 699 #endif
 700 .endm
 701 .macro UNWIND_ESPFIX_STACK
 702 #ifdef CONFIG_X86_ESPFIX32
 703         movl %ss, %eax
 704         /* see if on espfix stack */
 705         cmpw $__ESPFIX_SS, %ax
 706         jne 27f
 707         movl $__KERNEL_DS, %eax
 708         movl %eax, %ds
 709         movl %eax, %es
 710         /* switch to normal stack */
 711         FIXUP_ESPFIX_STACK
 712 27:
 713 #endif
 714 .endm
 715
 716 /*
 717  * Build the entry stubs and pointer table with some assembler magic.
 718  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 719  * single cache line on all modern x86 implementations.
 720  */
 721 .section .init.rodata,"a"
 722 ENTRY(interrupt)
 723 .section .entry.text, "ax"
 724         .p2align 5
 725         .p2align CONFIG_X86_L1_CACHE_SHIFT
 726 ENTRY(irq_entries_start)
 727         RING0_INT_FRAME
 728 vector=FIRST_EXTERNAL_VECTOR
 729 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 730         .balign 32
 731   .rept 7
 732     .if vector < NR_VECTORS
 733       .if vector <> FIRST_EXTERNAL_VECTOR
 734         CFI_ADJUST_CFA_OFFSET -4
 735       .endif
 736 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 737       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 738         jmp 2f
 739       .endif
 740       .previous
 741         .long 1b
 742       .section .entry.text, "ax"
 743 vector=vector+1
 744     .endif
 745   .endr
 746 2:      jmp common_interrupt
 747 .endr
 748 END(irq_entries_start)
 749
 750 .previous
 751 END(interrupt)
 752 .previous
 753
 754 /*
 755  * the CPU automatically disables interrupts when executing an IRQ vector,
 756  * so IRQ-flags tracing has to follow that:
 757  */
 758         .p2align CONFIG_X86_L1_CACHE_SHIFT
 759 common_interrupt:
 760         ASM_CLAC
 761         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 762         SAVE_ALL
 763         TRACE_IRQS_OFF
 764         movl %esp,%eax
 765         call do_IRQ
 766         jmp ret_from_intr
 767 ENDPROC(common_interrupt)
 768         CFI_ENDPROC
 769
 770 #define BUILD_INTERRUPT3(name, nr, fn)  \
 771 ENTRY(name)                             \
 772         RING0_INT_FRAME;                \
 773         ASM_CLAC;                       \
 774         pushl_cfi $~(nr);               \
 775         SAVE_ALL;                       \
 776         TRACE_IRQS_OFF                  \
 777         movl %esp,%eax;                 \
 778         call fn;                        \
 779         jmp ret_from_intr;              \
 780         CFI_ENDPROC;                    \
 781 ENDPROC(name)
 782
 783
 784 #ifdef CONFIG_TRACING
 785 #define TRACE_BUILD_INTERRUPT(name, nr)         \
 786         BUILD_INTERRUPT3(trace_##name, nr, smp_trace_##name)
 787 #else
 788 #define TRACE_BUILD_INTERRUPT(name, nr)
 789 #endif
 790
 791 #define BUILD_INTERRUPT(name, nr) \
 792         BUILD_INTERRUPT3(name, nr, smp_##name); \
 793         TRACE_BUILD_INTERRUPT(name, nr)
 794
 795 /* The include is where all of the SMP etc. interrupts come from */
 796 #include <asm/entry_arch.h>
 797
 798 ENTRY(coprocessor_error)
 799         RING0_INT_FRAME
 800         ASM_CLAC
 801         pushl_cfi $0
 802         pushl_cfi $do_coprocessor_error
 803         jmp error_code
 804         CFI_ENDPROC
 805 END(coprocessor_error)
 806
 807 ENTRY(simd_coprocessor_error)
 808         RING0_INT_FRAME
 809         ASM_CLAC
 810         pushl_cfi $0
 811 #ifdef CONFIG_X86_INVD_BUG
 812         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 813 661:    pushl_cfi $do_general_protection
 814 662:
 815 .section .altinstructions,"a"
 816         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 817 .previous
 818 .section .altinstr_replacement,"ax"
 819 663:    pushl $do_simd_coprocessor_error
 820 664:
 821 .previous
 822 #else
 823         pushl_cfi $do_simd_coprocessor_error
 824 #endif
 825         jmp error_code
 826         CFI_ENDPROC
 827 END(simd_coprocessor_error)
 828
 829 ENTRY(device_not_available)
 830         RING0_INT_FRAME
 831         ASM_CLAC
 832         pushl_cfi $-1                   # mark this as an int
 833         pushl_cfi $do_device_not_available
 834         jmp error_code
 835         CFI_ENDPROC
 836 END(device_not_available)
 837
 838 #ifdef CONFIG_PARAVIRT
 839 ENTRY(native_iret)
 840         iret
 841         _ASM_EXTABLE(native_iret, iret_exc)
 842 END(native_iret)
 843
 844 ENTRY(native_irq_enable_sysexit)
 845         sti
 846         sysexit
 847 END(native_irq_enable_sysexit)
 848 #endif
 849
 850 ENTRY(overflow)
 851         RING0_INT_FRAME
 852         ASM_CLAC
 853         pushl_cfi $0
 854         pushl_cfi $do_overflow
 855         jmp error_code
 856         CFI_ENDPROC
 857 END(overflow)
 858
 859 ENTRY(bounds)
 860         RING0_INT_FRAME
 861         ASM_CLAC
 862         pushl_cfi $0
 863         pushl_cfi $do_bounds
 864         jmp error_code
 865         CFI_ENDPROC
 866 END(bounds)
 867
 868 ENTRY(invalid_op)
 869         RING0_INT_FRAME
 870         ASM_CLAC
 871         pushl_cfi $0
 872         pushl_cfi $do_invalid_op
 873         jmp error_code
 874         CFI_ENDPROC
 875 END(invalid_op)
 876
 877 ENTRY(coprocessor_segment_overrun)
 878         RING0_INT_FRAME
 879         ASM_CLAC
 880         pushl_cfi $0
 881         pushl_cfi $do_coprocessor_segment_overrun
 882         jmp error_code
 883         CFI_ENDPROC
 884 END(coprocessor_segment_overrun)
 885
 886 ENTRY(invalid_TSS)
 887         RING0_EC_FRAME
 888         ASM_CLAC
 889         pushl_cfi $do_invalid_TSS
 890         jmp error_code
 891         CFI_ENDPROC
 892 END(invalid_TSS)
 893
 894 ENTRY(segment_not_present)
 895         RING0_EC_FRAME
 896         ASM_CLAC
 897         pushl_cfi $do_segment_not_present
 898         jmp error_code
 899         CFI_ENDPROC
 900 END(segment_not_present)
 901
 902 ENTRY(stack_segment)
 903         RING0_EC_FRAME
 904         ASM_CLAC
 905         pushl_cfi $do_stack_segment
 906         jmp error_code
 907         CFI_ENDPROC
 908 END(stack_segment)
 909
 910 ENTRY(alignment_check)
 911         RING0_EC_FRAME
 912         ASM_CLAC
 913         pushl_cfi $do_alignment_check
 914         jmp error_code
 915         CFI_ENDPROC
 916 END(alignment_check)
 917
 918 ENTRY(divide_error)
 919         RING0_INT_FRAME
 920         ASM_CLAC
 921         pushl_cfi $0                    # no error code
 922         pushl_cfi $do_divide_error
 923         jmp error_code
 924         CFI_ENDPROC
 925 END(divide_error)
 926
 927 #ifdef CONFIG_X86_MCE
 928 ENTRY(machine_check)
 929         RING0_INT_FRAME
 930         ASM_CLAC
 931         pushl_cfi $0
 932         pushl_cfi machine_check_vector
 933         jmp error_code
 934         CFI_ENDPROC
 935 END(machine_check)
 936 #endif
 937
 938 ENTRY(spurious_interrupt_bug)
 939         RING0_INT_FRAME
 940         ASM_CLAC
 941         pushl_cfi $0
 942         pushl_cfi $do_spurious_interrupt_bug
 943         jmp error_code
 944         CFI_ENDPROC
 945 END(spurious_interrupt_bug)
 946
 947 #ifdef CONFIG_XEN
 948 /* Xen doesn't set %esp to be precisely what the normal sysenter
 949    entrypoint expects, so fix it up before using the normal path. */
 950 ENTRY(xen_sysenter_target)
 951         RING0_INT_FRAME
 952         addl $5*4, %esp         /* remove xen-provided frame */
 953         CFI_ADJUST_CFA_OFFSET -5*4
 954         jmp sysenter_past_esp
 955         CFI_ENDPROC
 956
 957 ENTRY(xen_hypervisor_callback)
 958         CFI_STARTPROC
 959         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
 960         SAVE_ALL
 961         TRACE_IRQS_OFF
 962
 963         /* Check to see if we got the event in the critical
 964            region in xen_iret_direct, after we've reenabled
 965            events and checked for pending events.  This simulates
 966            iret instruction's behaviour where it delivers a
 967            pending interrupt when enabling interrupts. */
 968         movl PT_EIP(%esp),%eax
 969         cmpl $xen_iret_start_crit,%eax
 970         jb   1f
 971         cmpl $xen_iret_end_crit,%eax
 972         jae  1f
 973
 974         jmp  xen_iret_crit_fixup
 975
 976 ENTRY(xen_do_upcall)
 977 1:      mov %esp, %eax
 978         call xen_evtchn_do_upcall
 979         jmp  ret_from_intr
 980         CFI_ENDPROC
 981 ENDPROC(xen_hypervisor_callback)
 982
 983 # Hypervisor uses this for application faults while it executes.
 984 # We get here for two reasons:
 985 #  1. Fault while reloading DS, ES, FS or GS
 986 #  2. Fault while executing IRET
 987 # Category 1 we fix up by reattempting the load, and zeroing the segment
 988 # register if the load fails.
 989 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
 990 # normal Linux return path in this case because if we use the IRET hypercall
 991 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
 992 # We distinguish between categories by maintaining a status value in EAX.
 993 ENTRY(xen_failsafe_callback)
 994         CFI_STARTPROC
 995         pushl_cfi %eax
 996         movl $1,%eax
 997 1:      mov 4(%esp),%ds
 998 2:      mov 8(%esp),%es
 999 3:      mov 12(%esp),%fs
1000 4:      mov 16(%esp),%gs
1001         /* EAX == 0 => Category 1 (Bad segment)
1002            EAX != 0 => Category 2 (Bad IRET) */
1003         testl %eax,%eax
1004         popl_cfi %eax
1005         lea 16(%esp),%esp
1006         CFI_ADJUST_CFA_OFFSET -16
1007         jz 5f
1008         jmp iret_exc
1009 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1010         SAVE_ALL
1011         jmp ret_from_exception
1012         CFI_ENDPROC
1013
1014 .section .fixup,"ax"
1015 6:      xorl %eax,%eax
1016         movl %eax,4(%esp)
1017         jmp 1b
1018 7:      xorl %eax,%eax
1019         movl %eax,8(%esp)
1020         jmp 2b
1021 8:      xorl %eax,%eax
1022         movl %eax,12(%esp)
1023         jmp 3b
1024 9:      xorl %eax,%eax
1025         movl %eax,16(%esp)
1026         jmp 4b
1027 .previous
1028         _ASM_EXTABLE(1b,6b)
1029         _ASM_EXTABLE(2b,7b)
1030         _ASM_EXTABLE(3b,8b)
1031         _ASM_EXTABLE(4b,9b)
1032 ENDPROC(xen_failsafe_callback)
1033
1034 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1035                 xen_evtchn_do_upcall)
1036
1037 #endif  /* CONFIG_XEN */
1038
1039 #if IS_ENABLED(CONFIG_HYPERV)
1040
1041 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1042         hyperv_vector_handler)
1043
1044 #endif /* CONFIG_HYPERV */
1045
1046 #ifdef CONFIG_FUNCTION_TRACER
1047 #ifdef CONFIG_DYNAMIC_FTRACE
1048
1049 ENTRY(mcount)
1050         ret
1051 END(mcount)
1052
1053 ENTRY(ftrace_caller)
1054         cmpl $0, function_trace_stop
1055         jne  ftrace_stub
1056
1057         pushl %eax
1058         pushl %ecx
1059         pushl %edx
1060         pushl $0        /* Pass NULL as regs pointer */
1061         movl 4*4(%esp), %eax
1062         movl 0x4(%ebp), %edx
1063         movl function_trace_op, %ecx
1064         subl $MCOUNT_INSN_SIZE, %eax
1065
1066 .globl ftrace_call
1067 ftrace_call:
1068         call ftrace_stub
1069
1070         addl $4,%esp    /* skip NULL pointer */
1071         popl %edx
1072         popl %ecx
1073         popl %eax
1074 ftrace_ret:
1075 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1076 .globl ftrace_graph_call
1077 ftrace_graph_call:
1078         jmp ftrace_stub
1079 #endif
1080
1081 .globl ftrace_stub
1082 ftrace_stub:
1083         ret
1084 END(ftrace_caller)
1085
1086 ENTRY(ftrace_regs_caller)
1087         pushf   /* push flags before compare (in cs location) */
1088         cmpl $0, function_trace_stop
1089         jne ftrace_restore_flags
1090
1091         /*
1092          * i386 does not save SS and ESP when coming from kernel.
1093          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1094          * Unfortunately, that means eflags must be at the same location
1095          * as the current return ip is. We move the return ip into the
1096          * ip location, and move flags into the return ip location.
1097          */
1098         pushl 4(%esp)   /* save return ip into ip slot */
1099
1100         pushl $0        /* Load 0 into orig_ax */
1101         pushl %gs
1102         pushl %fs
1103         pushl %es
1104         pushl %ds
1105         pushl %eax
1106         pushl %ebp
1107         pushl %edi
1108         pushl %esi
1109         pushl %edx
1110         pushl %ecx
1111         pushl %ebx
1112
1113         movl 13*4(%esp), %eax   /* Get the saved flags */
1114         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1115                                 /* clobbering return ip */
1116         movl $__KERNEL_CS,13*4(%esp)
1117
1118         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1119         subl $MCOUNT_INSN_SIZE, %eax    /* Adjust ip */
1120         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1121         movl function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1122         pushl %esp              /* Save pt_regs as 4th parameter */
1123
1124 GLOBAL(ftrace_regs_call)
1125         call ftrace_stub
1126
1127         addl $4, %esp           /* Skip pt_regs */
1128         movl 14*4(%esp), %eax   /* Move flags back into cs */
1129         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1130         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1131         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1132
1133         popl %ebx
1134         popl %ecx
1135         popl %edx
1136         popl %esi
1137         popl %edi
1138         popl %ebp
1139         popl %eax
1140         popl %ds
1141         popl %es
1142         popl %fs
1143         popl %gs
1144         addl $8, %esp           /* Skip orig_ax and ip */
1145         popf                    /* Pop flags at end (no addl to corrupt flags) */
1146         jmp ftrace_ret
1147
1148 ftrace_restore_flags:
1149         popf
1150         jmp  ftrace_stub
1151 #else /* ! CONFIG_DYNAMIC_FTRACE */
1152
1153 ENTRY(mcount)
1154         cmpl $__PAGE_OFFSET, %esp
1155         jb ftrace_stub          /* Paging not enabled yet? */
1156
1157         cmpl $0, function_trace_stop
1158         jne  ftrace_stub
1159
1160         cmpl $ftrace_stub, ftrace_trace_function
1161         jnz trace
1162 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1163         cmpl $ftrace_stub, ftrace_graph_return
1164         jnz ftrace_graph_caller
1165
1166         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1167         jnz ftrace_graph_caller
1168 #endif
1169 .globl ftrace_stub
1170 ftrace_stub:
1171         ret
1172
1173         /* taken from glibc */
1174 trace:
1175         pushl %eax
1176         pushl %ecx
1177         pushl %edx
1178         movl 0xc(%esp), %eax
1179         movl 0x4(%ebp), %edx
1180         subl $MCOUNT_INSN_SIZE, %eax
1181
1182         call *ftrace_trace_function
1183
1184         popl %edx
1185         popl %ecx
1186         popl %eax
1187         jmp ftrace_stub
1188 END(mcount)
1189 #endif /* CONFIG_DYNAMIC_FTRACE */
1190 #endif /* CONFIG_FUNCTION_TRACER */
1191
1192 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1193 ENTRY(ftrace_graph_caller)
1194         pushl %eax
1195         pushl %ecx
1196         pushl %edx
1197         movl 0xc(%esp), %edx
1198         lea 0x4(%ebp), %eax
1199         movl (%ebp), %ecx
1200         subl $MCOUNT_INSN_SIZE, %edx
1201         call prepare_ftrace_return
1202         popl %edx
1203         popl %ecx
1204         popl %eax
1205         ret
1206 END(ftrace_graph_caller)
1207
1208 .globl return_to_handler
1209 return_to_handler:
1210         pushl %eax
1211         pushl %edx
1212         movl %ebp, %eax
1213         call ftrace_return_to_handler
1214         movl %eax, %ecx
1215         popl %edx
1216         popl %eax
1217         jmp *%ecx
1218 #endif
1219
1220 #ifdef CONFIG_TRACING
1221 ENTRY(trace_page_fault)
1222         RING0_EC_FRAME
1223         ASM_CLAC
1224         pushl_cfi $trace_do_page_fault
1225         jmp error_code
1226         CFI_ENDPROC
1227 END(trace_page_fault)
1228 #endif
1229
1230 ENTRY(page_fault)
1231         RING0_EC_FRAME
1232         ASM_CLAC
1233         pushl_cfi $do_page_fault
1234         ALIGN
1235 error_code:
1236         /* the function address is in %gs's slot on the stack */
1237         pushl_cfi %fs
1238         /*CFI_REL_OFFSET fs, 0*/
1239         pushl_cfi %es
1240         /*CFI_REL_OFFSET es, 0*/
1241         pushl_cfi %ds
1242         /*CFI_REL_OFFSET ds, 0*/
1243         pushl_cfi %eax
1244         CFI_REL_OFFSET eax, 0
1245         pushl_cfi %ebp
1246         CFI_REL_OFFSET ebp, 0
1247         pushl_cfi %edi
1248         CFI_REL_OFFSET edi, 0
1249         pushl_cfi %esi
1250         CFI_REL_OFFSET esi, 0
1251         pushl_cfi %edx
1252         CFI_REL_OFFSET edx, 0
1253         pushl_cfi %ecx
1254         CFI_REL_OFFSET ecx, 0
1255         pushl_cfi %ebx
1256         CFI_REL_OFFSET ebx, 0
1257         cld
1258         movl $(__KERNEL_PERCPU), %ecx
1259         movl %ecx, %fs
1260         UNWIND_ESPFIX_STACK
1261         GS_TO_REG %ecx
1262         movl PT_GS(%esp), %edi          # get the function address
1263         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1264         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1265         REG_TO_PTGS %ecx
1266         SET_KERNEL_GS %ecx
1267         movl $(__USER_DS), %ecx
1268         movl %ecx, %ds
1269         movl %ecx, %es
1270         TRACE_IRQS_OFF
1271         movl %esp,%eax                  # pt_regs pointer
1272         call *%edi
1273         jmp ret_from_exception
1274         CFI_ENDPROC
1275 END(page_fault)
1276
1277 /*
1278  * Debug traps and NMI can happen at the one SYSENTER instruction
1279  * that sets up the real kernel stack. Check here, since we can't
1280  * allow the wrong stack to be used.
1281  *
1282  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1283  * already pushed 3 words if it hits on the sysenter instruction:
1284  * eflags, cs and eip.
1285  *
1286  * We just load the right stack, and push the three (known) values
1287  * by hand onto the new stack - while updating the return eip past
1288  * the instruction that would have done it for sysenter.
1289  */
1290 .macro FIX_STACK offset ok label
1291         cmpw $__KERNEL_CS, 4(%esp)
1292         jne \ok
1293 \label:
1294         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1295         CFI_DEF_CFA esp, 0
1296         CFI_UNDEFINED eip
1297         pushfl_cfi
1298         pushl_cfi $__KERNEL_CS
1299         pushl_cfi $sysenter_past_esp
1300         CFI_REL_OFFSET eip, 0
1301 .endm
1302
1303 ENTRY(debug)
1304         RING0_INT_FRAME
1305         ASM_CLAC
1306         cmpl $ia32_sysenter_target,(%esp)
1307         jne debug_stack_correct
1308         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1309 debug_stack_correct:
1310         pushl_cfi $-1                   # mark this as an int
1311         SAVE_ALL
1312         TRACE_IRQS_OFF
1313         xorl %edx,%edx                  # error code 0
1314         movl %esp,%eax                  # pt_regs pointer
1315         call do_debug
1316         jmp ret_from_exception
1317         CFI_ENDPROC
1318 END(debug)
1319
1320 /*
1321  * NMI is doubly nasty. It can happen _while_ we're handling
1322  * a debug fault, and the debug fault hasn't yet been able to
1323  * clear up the stack. So we first check whether we got  an
1324  * NMI on the sysenter entry path, but after that we need to
1325  * check whether we got an NMI on the debug path where the debug
1326  * fault happened on the sysenter path.
1327  */
1328 ENTRY(nmi)
1329         RING0_INT_FRAME
1330         ASM_CLAC
1331 #ifdef CONFIG_X86_ESPFIX32
1332         pushl_cfi %eax
1333         movl %ss, %eax
1334         cmpw $__ESPFIX_SS, %ax
1335         popl_cfi %eax
1336         je nmi_espfix_stack
1337 #endif
1338         cmpl $ia32_sysenter_target,(%esp)
1339         je nmi_stack_fixup
1340         pushl_cfi %eax
1341         movl %esp,%eax
1342         /* Do not access memory above the end of our stack page,
1343          * it might not exist.
1344          */
1345         andl $(THREAD_SIZE-1),%eax
1346         cmpl $(THREAD_SIZE-20),%eax
1347         popl_cfi %eax
1348         jae nmi_stack_correct
1349         cmpl $ia32_sysenter_target,12(%esp)
1350         je nmi_debug_stack_check
1351 nmi_stack_correct:
1352         /* We have a RING0_INT_FRAME here */
1353         pushl_cfi %eax
1354         SAVE_ALL
1355         xorl %edx,%edx          # zero error code
1356         movl %esp,%eax          # pt_regs pointer
1357         call do_nmi
1358         jmp restore_all_notrace
1359         CFI_ENDPROC
1360
1361 nmi_stack_fixup:
1362         RING0_INT_FRAME
1363         FIX_STACK 12, nmi_stack_correct, 1
1364         jmp nmi_stack_correct
1365
1366 nmi_debug_stack_check:
1367         /* We have a RING0_INT_FRAME here */
1368         cmpw $__KERNEL_CS,16(%esp)
1369         jne nmi_stack_correct
1370         cmpl $debug,(%esp)
1371         jb nmi_stack_correct
1372         cmpl $debug_esp_fix_insn,(%esp)
1373         ja nmi_stack_correct
1374         FIX_STACK 24, nmi_stack_correct, 1
1375         jmp nmi_stack_correct
1376
1377 #ifdef CONFIG_X86_ESPFIX32
1378 nmi_espfix_stack:
1379         /* We have a RING0_INT_FRAME here.
1380          *
1381          * create the pointer to lss back
1382          */
1383         pushl_cfi %ss
1384         pushl_cfi %esp
1385         addl $4, (%esp)
1386         /* copy the iret frame of 12 bytes */
1387         .rept 3
1388         pushl_cfi 16(%esp)
1389         .endr
1390         pushl_cfi %eax
1391         SAVE_ALL
1392         FIXUP_ESPFIX_STACK              # %eax == %esp
1393         xorl %edx,%edx                  # zero error code
1394         call do_nmi
1395         RESTORE_REGS
1396         lss 12+4(%esp), %esp            # back to espfix stack
1397         CFI_ADJUST_CFA_OFFSET -24
1398         jmp irq_return
1399 #endif
1400         CFI_ENDPROC
1401 END(nmi)
1402
1403 ENTRY(int3)
1404         RING0_INT_FRAME
1405         ASM_CLAC
1406         pushl_cfi $-1                   # mark this as an int
1407         SAVE_ALL
1408         TRACE_IRQS_OFF
1409         xorl %edx,%edx          # zero error code
1410         movl %esp,%eax          # pt_regs pointer
1411         call do_int3
1412         jmp ret_from_exception
1413         CFI_ENDPROC
1414 END(int3)
1415
1416 ENTRY(general_protection)
1417         RING0_EC_FRAME
1418         pushl_cfi $do_general_protection
1419         jmp error_code
1420         CFI_ENDPROC
1421 END(general_protection)
1422
1423 #ifdef CONFIG_KVM_GUEST
1424 ENTRY(async_page_fault)
1425         RING0_EC_FRAME
1426         ASM_CLAC
1427         pushl_cfi $do_async_page_fault
1428         jmp error_code
1429         CFI_ENDPROC
1430 END(async_page_fault)
1431 #endif
1432