board/atmel/atstk1000/u-boot.lds.S

   1 /* -*- Fundamental -*-
   2  *
   3  * Copyright (C) 2005-2006 Atmel Corporation
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23 #include <config.h>
  24
  25 OUTPUT_FORMAT("elf32-avr32", "elf32-avr32", "elf32-avr32")
  26 OUTPUT_ARCH(avr32)
  27 ENTRY(_start)
  28
  29 SECTIONS
  30 {
  31         . = CFG_FLASH_BASE;
  32         _text = .;
  33         .text : {
  34                 *(.text)
  35                 *(.text.*)
  36         }
  37
  38         . = ALIGN(CFG_ICACHE_LINESZ);
  39         __flashprog_start = .;
  40         .flashprog : {
  41                 *(.flashprog)
  42         }
  43         . = ALIGN(CFG_ICACHE_LINESZ);
  44         __flashprog_end = .;
  45
  46         . = ALIGN(8);
  47         .rodata : {
  48                 *(.rodata)
  49                 *(.rodata.*)
  50         }
  51         _etext = .;
  52
  53         __data_lma = ALIGN(8);
  54         . = CFG_INTRAM_BASE;
  55         _data = .;
  56         .data : AT(__data_lma) {
  57                 *(.data)
  58                 *(.data.*)
  59         }
  60
  61         . = ALIGN(4);
  62         __u_boot_cmd_start = .;
  63         __u_boot_cmd_lma = __data_lma + (__u_boot_cmd_start - _data);
  64         .u_boot_cmd : AT(__u_boot_cmd_lma) {
  65                 KEEP(*(.u_boot_cmd))
  66         }
  67         __u_boot_cmd_end = .;
  68
  69         . = ALIGN(8);
  70         _edata = .;
  71         __edata_lma = __u_boot_cmd_lma + (_edata - __u_boot_cmd_start);
  72
  73         .bss : AT(__edata_lma) {
  74                 *(.bss)
  75                 *(.bss.*)
  76         }
  77         . = ALIGN(8);
  78         _end = .;
  79 }