packages/hal/sparclite/arch/v2_0/src/sparclite.ld

   1 //===========================================================================
   2 //
   3 // MLT linker script for SPARClite
   4 //
   5 //===========================================================================
   6 //####ECOSGPLCOPYRIGHTBEGIN####
   7 // -------------------------------------------
   8 // This file is part of eCos, the Embedded Configurable Operating System.
   9 // Copyright (C) 1998, 1999, 2000, 2001, 2002 Red Hat, Inc.
  10 //
  11 // eCos is free software; you can redistribute it and/or modify it under
  12 // the terms of the GNU General Public License as published by the Free
  13 // Software Foundation; either version 2 or (at your option) any later version.
  14 //
  15 // eCos is distributed in the hope that it will be useful, but WITHOUT ANY
  16 // WARRANTY; without even the implied warranty of MERCHANTABILITY or
  17 // FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  18 // for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License along
  21 // with eCos; if not, write to the Free Software Foundation, Inc.,
  22 // 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  23 //
  24 // As a special exception, if other files instantiate templates or use macros
  25 // or inline functions from this file, or you compile this file and link it
  26 // with other works to produce a work based on this file, this file does not
  27 // by itself cause the resulting work to be covered by the GNU General Public
  28 // License. However the source code for this file must still be made available
  29 // in accordance with section (3) of the GNU General Public License.
  30 //
  31 // This exception does not invalidate any other reasons why a work based on
  32 // this file might be covered by the GNU General Public License.
  33 //
  34 // Alternative licenses for eCos may be arranged by contacting Red Hat, Inc.
  35 // at http://sources.redhat.com/ecos/ecos-license/
  36 // -------------------------------------------
  37 //####ECOSGPLCOPYRIGHTEND####
  38 //===========================================================================
  39
  40 STARTUP(vectors.o)
  41 ENTRY(reset_vector)
  42 #ifdef EXTRAS
  43 INPUT(extras.o)
  44 #endif
  45 #if (__GNUC__ >= 3)
  46 GROUP(libtarget.a libgcc.a libsupc++.a)
  47 #else
  48 GROUP(libtarget.a libgcc.a)
  49 #endif
  50
  51 #define ALIGN_LMA 8
  52 #define FOLLOWING(_section_) AT ((LOADADDR (_section_) + SIZEOF (_section_) + ALIGN_LMA - 1) & ~ (ALIGN_LMA - 1))
  53 #define LMA_EQ_VMA
  54 #define FORCE_OUTPUT . = .
  55
  56 #define SECTIONS_BEGIN
  57
  58 #define SECTION_rom_vectors(_region_, _vma_, _lma_) \
  59     .rom_vectors _vma_ : _lma_ \
  60     { FORCE_OUTPUT; KEEP (*(.vectors)) } \
  61     > _region_
  62
  63 #define SECTION_text(_region_, _vma_, _lma_) \
  64     .text _vma_ : _lma_ \
  65     { _stext = ABSOLUTE(.); \
  66     *(.text*) *(.gnu.warning) *(.gnu.linkonce*) *(.init) } \
  67     > _region_ \
  68     _etext = .; PROVIDE (etext = .);
  69
  70 #define SECTION_fini(_region_, _vma_, _lma_) \
  71     .fini _vma_ : _lma_ \
  72     { FORCE_OUTPUT; *(.fini) } \
  73     > _region_
  74
  75 #define SECTION_rodata(_region_, _vma_, _lma_) \
  76     .rodata _vma_ : _lma_ \
  77     { FORCE_OUTPUT; *(.rodata*) } \
  78     > _region_
  79
  80 #define SECTION_rodata1(_region_, _vma_, _lma_) \
  81     .rodata1 _vma_ : _lma_ \
  82     { FORCE_OUTPUT; *(.rodata1) } \
  83     > _region_
  84
  85 #define SECTION_fixup(_region_, _vma_, _lma_) \
  86     .fixup _vma_ : _lma_ \
  87     { FORCE_OUTPUT; *(.fixup) } \
  88     > _region_
  89
  90 #define SECTION_gcc_except_table(_region_, _vma_, _lma_) \
  91     .gcc_except_table _vma_ : _lma_ \
  92     { FORCE_OUTPUT; *(.gcc_except_table) } \
  93     > _region_
  94
  95 #define SECTION_ram_vectors(_region_, _vma_, _lma_) \
  96     .ram_vectors _vma_ : _lma_ \
  97     { __ram_vectors_start = ABSOLUTE(.); \
  98     KEEP (*(.ram_vectors)) \
  99     __ram_vectors_end = ABSOLUTE(.); } \
 100     > _region_
 101
 102 #define SECTION_data(_region_, _vma_, _lma_) \
 103     .data _vma_ : _lma_ \
 104     { __ram_data_start = ABSOLUTE (.); \
 105     *(.data*) *(.data1) \
 106     _GOT1_START_ = ABSOLUTE (.); *(.got1) _GOT1_END_ = ABSOLUTE (.); \
 107     _GOT2_START_ = ABSOLUTE (.); *(.got2) _GOT2_END_ = ABSOLUTE (.); \
 108     . = ALIGN (4); \
 109     KEEP(*( SORT (.ecos.table.*))) ;            \
 110     __CTOR_LIST__ = ABSOLUTE (.); \
 111     KEEP(*(SORT(.ctors*))) \
 112     __CTOR_END__ = ABSOLUTE (.); \
 113     __DTOR_LIST__ = ABSOLUTE (.); \
 114     KEEP(*(SORT(.dtors*))) \
 115     __DTOR_END__ = ABSOLUTE (.); \
 116     _GOT_START = ABSOLUTE (.); _GLOBAL_OFFSET_TABLE_ = ABSOLUTE (.) + 32768; \
 117     _SDA_BASE_ = ABSOLUTE (.); \
 118     *(.got.plt) *(.got) _GOT_END_ = ABSOLUTE (.); \
 119     *(.dynamic) *(.sdata*) *(.sbss*) *(.eh_frame) } \
 120     > _region_ \
 121     __rom_data_start = LOADADDR (.data); \
 122     . = ALIGN (8); \
 123     __ram_data_end = .; PROVIDE (__ram_data_end = .); _edata = .; PROVIDE (edata = .);
 124
 125 #define SECTION_bss(_region_, _vma_, _lma_) \
 126     .bss _vma_ : _lma_ \
 127     { __bss_start = ABSOLUTE (.); \
 128     *(.scommon) *(.dynbss) *(.bss) *(COMMON) \
 129     __bss_end = ABSOLUTE (.); } \
 130     > _region_
 131
 132 #define SECTIONS_END . = ALIGN(8); _end = .; PROVIDE (end = .); \
 133     .debug          0 : { *(.debug) } \
 134     .line           0 : { *(.line) } \
 135     .debug_srcinfo  0 : { *(.debug_srcinfo) } \
 136     .debug_sfnames  0 : { *(.debug_sfnames) } \
 137     .debug_aranges  0 : { *(.debug_aranges) } \
 138     .debug_pubnames 0 : { *(.debug_pubnames) } \
 139     .debug_info     0 : { *(.debug_info) } \
 140     .debug_abbrev   0 : { *(.debug_abbrev) } \
 141     .debug_line     0 : { *(.debug_line) } \
 142     .debug_frame    0 : { *(.debug_frame) } \
 143     .debug_str      0 : { *(.debug_str) } \
 144     .debug_loc      0 : { *(.debug_loc) } \
 145     .debug_macinfo  0 : { *(.debug_macinfo) } \
 146     .debug_weaknames 0 : { *(.debug_weaknames) } \
 147     .debug_funcnames 0 : { *(.debug_funcnames) } \
 148     .debug_typenames 0 : { *(.debug_typenames) } \
 149     .debug_varnames  0 : { *(.debug_varnames) }
 150
 151 #include <pkgconf/system.h>
 152 #include CYGHWR_MEMORY_LAYOUT_LDI