packages/hal/arm/at91/eb42/v2_0/include/hal_platform_setup.h

   1 #ifndef CYGONCE_HAL_PLATFORM_SETUP_H
   2 #define CYGONCE_HAL_PLATFORM_SETUP_H
   3
   4 /*=============================================================================
   5 //
   6 //      hal_platform_setup.h
   7 //
   8 //      Platform specific support for HAL (assembly code)
   9 //
  10 //=============================================================================
  11 //####ECOSGPLCOPYRIGHTBEGIN####
  12 // -------------------------------------------
  13 // This file is part of eCos, the Embedded Configurable Operating System.
  14 // Copyright (C) 1998, 1999, 2000, 2001, 2002 Red Hat, Inc.
  15 // Copyright (C) 2003 Nick Garnett <nickg@calivar.com>
  16 //
  17 // eCos is free software; you can redistribute it and/or modify it under
  18 // the terms of the GNU General Public License as published by the Free
  19 // Software Foundation; either version 2 or (at your option) any later version.
  20 //
  21 // eCos is distributed in the hope that it will be useful, but WITHOUT ANY
  22 // WARRANTY; without even the implied warranty of MERCHANTABILITY or
  23 // FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  24 // for more details.
  25 //
  26 // You should have received a copy of the GNU General Public License along
  27 // with eCos; if not, write to the Free Software Foundation, Inc.,
  28 // 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  29 //
  30 // As a special exception, if other files instantiate templates or use macros
  31 // or inline functions from this file, or you compile this file and link it
  32 // with other works to produce a work based on this file, this file does not
  33 // by itself cause the resulting work to be covered by the GNU General Public
  34 // License. However the source code for this file must still be made available
  35 // in accordance with section (3) of the GNU General Public License.
  36 //
  37 // This exception does not invalidate any other reasons why a work based on
  38 // this file might be covered by the GNU General Public License.
  39 //
  40 // Alternative licenses for eCos may be arranged by contacting Red Hat, Inc.
  41 // at http://sources.redhat.com/ecos/ecos-license/
  42 // -------------------------------------------
  43 //####ECOSGPLCOPYRIGHTEND####
  44 //=============================================================================
  45 //#####DESCRIPTIONBEGIN####
  46 //
  47 // Author(s):   gthomas
  48 // Contributors:gthomas, tdrury, nickg
  49 // Date:        2001-07-12
  50 // Purpose:     AT91/EB42 platform specific support routines
  51 // Description:
  52 // Usage:       #include <cyg/hal/hal_platform_setup.h>
  53 //
  54 //####DESCRIPTIONEND####
  55 //
  56 //===========================================================================*/
  57
  58 #include <cyg/hal/var_io.h>
  59
  60 //===========================================================================*/
  61
  62         .macro  _led_init
  63         ldr     r0,=AT91_PIOB
  64         mov     r1,#0x0000FF00
  65         str     r1,[r0,#AT91_PIO_PER]
  66         str     r1,[r0,#AT91_PIO_OER]
  67         _led    0
  68         _led    15
  69         .endm
  70
  71         .macro _led y
  72         ldr     r0,=AT91_PIOB
  73         mov     r1,#0x0000FF00
  74         str     r1,[r0,#AT91_PIO_SODR]
  75         mov     r1,#(\y<<8)
  76         str     r1,[r0,#AT91_PIO_CODR]
  77 #if 0
  78         mov     r0,#0x00100000
  79 1:      sub     r0,r0,#1
  80         cmp     r0,#0
  81         bne     1b
  82 #endif
  83         .endm
  84
  85         .macro  _pclock_init
  86         ldr     r0,=AT91_PMC            // Power saving interface
  87         ldr     r1,=0xFFFFFFFF          // Enable all peripheral [clocks]
  88         str     r1,[r0,#AT91_PMC_PCER]
  89         .endm
  90
  91         .macro  _pio_init
  92         ldr     r0,=AT91_PIOA           // Disable PIO (so peripherals can use bits)
  93         ldr     r1,=0x000007E0          // Enable UARTS
  94         str     r1,[r0,#AT91_PIO_PDR]
  95         .endm
  96
  97 #define CYGHWR_LED_MACRO _led \x
  98
  99 //===========================================================================*/
 100
 101 #if defined(CYG_HAL_STARTUP_ROM) || defined(CYG_HAL_STARTUP_ROMRAM)
 102
 103
 104 #define AT91_PMC_CGMR_INIT0     AT91_PMC_CGMR_PRES_NONE         |       \
 105                                 AT91_PMC_CGMR_PLLB              |       \
 106                                 AT91_PMC_CGMR_PLL_MUL(999)      |       \
 107                                 AT91_PMC_CGMR_PLL_CNT(197)
 108
 109 #define AT91_PMC_CGMR_INIT1     AT91_PMC_CGMR_INIT0             |       \
 110                                 AT91_PMC_CGMR_MCKO_ENA          |       \
 111                                 AT91_PMC_CGMR_MCK_MCK           |       \
 112                                 AT91_PMC_CGMR_CSS_PLL
 113
 114
 115         .macro  _setup
 116
 117         _led_init
 118
 119
 120         ldr     r10,=_InitMemory        // Initialize memory controller
 121         movs    r0,pc,lsr #20           // If ROM startup, PC < 0x100000
 122         moveq   r10,r10,lsl #12         //   mask address to low 20 bits
 123         moveq   r10,r10,lsr #12
 124         ldmia   r10!,{r0-r9,r11-r12}    // Table of initialization constants
 125 #if defined(CYG_HAL_STARTUP_ROMRAM)
 126         ldr     r10,=0x0000FFFF
 127         and     r12,r12,r10
 128         ldr     r10,=0x01000000
 129         orr     r12,r12,r10
 130 #endif
 131         stmia   r11!,{r0-r9}            // Write to controller
 132         mov     pc,r12                  // Change address space, break pipeline
 133 _InitMemory:
 134         .long   0x01002535  // 0x01000000, 16MB,  2 cycles after transfer, 16-bit, 6 wait states
 135         .long   0x02002121  // 0x02000000, 16MB,  0 cycles after transfer, 16-bit, 1 wait state
 136         .long   0x20003E3E  // 0x20000000, 1MB,   7 cycles after transfer, 8-bit, 8 wait states
 137         .long   0x30000000  // unused
 138         .long   0x40000000  // unused
 139         .long   0x50000000  // unused
 140         .long   0x60000000  // unused
 141         .long   0x70000000  // unused
 142         .long   0x00000001  // REMAP commande
 143         .long   0x00000006  // 7 memory regions, standard read
 144         .long   AT91_EBI    // External Bus Interface address
 145         .long   10f         // address where to jump
 146 10:
 147
 148         // Change system frequency from 32kHz to 32MHz.
 149
 150         // First enable the PLL
 151         ldr     r2,=AT91_PMC
 152         ldr     r3,=AT91_PMC_CGMR_INIT0
 153         str     r3,[r2,#AT91_PMC_CGMR]
 154
 155         // Wait for PLL to stabilize
 156         mov     r4,#AT91_PMC_SR_LOCK
 157 2:
 158         ldr     r3,[r2,#AT91_PMC_SR]
 159         cmp     r3,r4
 160         bne     2b
 161
 162         // Now, switch CPU clock from Slow Clock to PLL
 163         ldr     r3,=AT91_PMC_CGMR_INIT1
 164         str     r3,[r2,#AT91_PMC_CGMR]
 165
 166         // All done, we should be running at 32MHz now
 167
 168 #if defined(CYG_HAL_STARTUP_ROMRAM)
 169         ldr     r0,=0x01000000          // Relocate FLASH/ROM to on-chip RAM
 170         ldr     r1,=0x02000000          // RAM base & length
 171         ldr     r2,=0x02010000
 172 20:     ldr     r3,[r0],#4
 173         str     r3,[r1],#4
 174         cmp     r1,r2
 175         bne     20b
 176         ldr     r0,=30f
 177         mov     pc,r0
 178 30:
 179 #endif
 180         _pclock_init
 181         _pio_init
 182         .endm
 183
 184 #define CYGSEM_HAL_ROM_RESET_USES_JUMP
 185
 186 #else
 187
 188         .macro  _setup
 189         _led_init
 190         _pclock_init
 191         _pio_init
 192         .endm
 193
 194 #endif
 195
 196 #define PLATFORM_SETUP1     _setup
 197
 198
 199 //-----------------------------------------------------------------------------
 200 // end of hal_platform_setup.h
 201 #endif // CYGONCE_HAL_PLATFORM_SETUP_H