arch/arm/cpu/arm925t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM925 CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1510 from ARM920 code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij  <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33 #include <asm-offsets.h>
  34 #include <config.h>
  35 #include <version.h>
  36
  37 #if defined(CONFIG_OMAP1510)
  38 #include <./configs/omap1510.h>
  39 #endif
  40
  41 /*
  42  *************************************************************************
  43  *
  44  * Jump vector table as in table 3.1 in [1]
  45  *
  46  *************************************************************************
  47  */
  48
  49
  50 .globl _start
  51 _start: b       reset
  52         ldr     pc, _undefined_instruction
  53         ldr     pc, _software_interrupt
  54         ldr     pc, _prefetch_abort
  55         ldr     pc, _data_abort
  56         ldr     pc, _not_used
  57         ldr     pc, _irq
  58         ldr     pc, _fiq
  59
  60 _undefined_instruction: .word undefined_instruction
  61 _software_interrupt:    .word software_interrupt
  62 _prefetch_abort:        .word prefetch_abort
  63 _data_abort:            .word data_abort
  64 _not_used:              .word not_used
  65 _irq:                   .word irq
  66 _fiq:                   .word fiq
  67
  68         .balignl 16,0xdeadbeef
  69
  70
  71 /*
  72  *************************************************************************
  73  *
  74  * Startup Code (reset vector)
  75  *
  76  * do important init only if we don't start from memory!
  77  * setup Memory and board specific bits prior to relocation.
  78  * relocate armboot to ram
  79  * setup stack
  80  *
  81  *************************************************************************
  82  */
  83
  84 .globl _TEXT_BASE
  85 _TEXT_BASE:
  86         .word   CONFIG_SYS_TEXT_BASE
  87
  88 /*
  89  * These are defined in the board-specific linker script.
  90  */
  91 .globl _bss_start
  92 _bss_start:
  93         .word __bss_start
  94
  95 .globl _bss_end
  96 _bss_end:
  97         .word _end
  98
  99 #ifdef CONFIG_USE_IRQ
 100 /* IRQ stack memory (calculated at run-time) */
 101 .globl IRQ_STACK_START
 102 IRQ_STACK_START:
 103         .word   0x0badc0de
 104
 105 /* IRQ stack memory (calculated at run-time) */
 106 .globl FIQ_STACK_START
 107 FIQ_STACK_START:
 108         .word 0x0badc0de
 109 #endif
 110
 111 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 112 .globl IRQ_STACK_START_IN
 113 IRQ_STACK_START_IN:
 114         .word   0x0badc0de
 115
 116 .globl _datarel_start
 117 _datarel_start:
 118         .word __datarel_start
 119
 120 .globl _datarelrolocal_start
 121 _datarelrolocal_start:
 122         .word __datarelrolocal_start
 123
 124 .globl _datarellocal_start
 125 _datarellocal_start:
 126         .word __datarellocal_start
 127
 128 .globl _datarelro_start
 129 _datarelro_start:
 130         .word __datarelro_start
 131
 132 .globl _got_start
 133 _got_start:
 134         .word __got_start
 135
 136 .globl _got_end
 137 _got_end:
 138         .word __got_end
 139
 140 /*
 141  * the actual reset code
 142  */
 143
 144 reset:
 145         /*
 146          * set the cpu to SVC32 mode
 147          */
 148         mrs     r0,cpsr
 149         bic     r0,r0,#0x1f
 150         orr     r0,r0,#0xd3
 151         msr     cpsr,r0
 152
 153         /*
 154          * Set up 925T mode
 155          */
 156         mov r1, #0x81               /* Set ARM925T configuration. */
 157         mcr p15, 0, r1, c15, c1, 0  /* Write ARM925T configuration register. */
 158
 159         /*
 160          * turn off the watchdog, unlock/diable sequence
 161          */
 162         mov  r1, #0xF5
 163         ldr  r0, =WDTIM_MODE
 164         strh r1, [r0]
 165         mov  r1, #0xA0
 166         strh r1, [r0]
 167
 168         /*
 169          * mask all IRQs by setting all bits in the INTMR - default
 170          */
 171         mov r1, #0xffffffff
 172         ldr r0, =REG_IHL1_MIR
 173         str r1, [r0]
 174         ldr r0, =REG_IHL2_MIR
 175         str r1, [r0]
 176
 177         /*
 178          * wait for dpll to lock
 179          */
 180         ldr  r0, =CK_DPLL1
 181         mov  r1, #0x10
 182         strh r1, [r0]
 183 poll1:
 184         ldrh r1, [r0]
 185         ands r1, r1, #0x01
 186         beq poll1
 187
 188         /*
 189          * we do sys-critical inits only at reboot,
 190          * not when booting from ram!
 191          */
 192 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 193         bl  cpu_init_crit
 194 #endif
 195
 196 /* Set stackpointer in internal RAM to call board_init_f */
 197 call_board_init_f:
 198         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 199         ldr     r0,=0x00000000
 200         bl      board_init_f
 201
 202 /*------------------------------------------------------------------------------*/
 203
 204 /*
 205  * void relocate_code (addr_sp, gd, addr_moni)
 206  *
 207  * This "function" does not return, instead it continues in RAM
 208  * after relocating the monitor code.
 209  *
 210  */
 211         .globl  relocate_code
 212 relocate_code:
 213         mov     r4, r0  /* save addr_sp */
 214         mov     r5, r1  /* save addr of gd */
 215         mov     r6, r2  /* save addr of destination */
 216         mov     r7, r2  /* save addr of destination */
 217
 218         /* Set up the stack                                                 */
 219 stack_setup:
 220         mov     sp, r4
 221
 222         adr     r0, _start
 223         ldr     r2, _TEXT_BASE
 224         ldr     r3, _bss_start
 225         sub     r2, r3, r2              /* r2 <- size of armboot            */
 226         add     r2, r0, r2              /* r2 <- source end address         */
 227         cmp     r0, r6
 228         beq     clear_bss
 229
 230 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 231 copy_loop:
 232         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 233         stmia   r6!, {r9-r10}           /* copy to   target address [r1]    */
 234         cmp     r0, r2                  /* until source end address [r2]    */
 235         blo     copy_loop
 236
 237 #ifndef CONFIG_PRELOADER
 238         /* fix got entries */
 239         ldr     r1, _TEXT_BASE          /* Text base */
 240         mov     r0, r7                  /* reloc addr */
 241         ldr     r2, _got_start          /* addr in Flash */
 242         ldr     r3, _got_end            /* addr in Flash */
 243         sub     r3, r3, r1
 244         add     r3, r3, r0
 245         sub     r2, r2, r1
 246         add     r2, r2, r0
 247
 248 fixloop:
 249         ldr     r4, [r2]
 250         sub     r4, r4, r1
 251         add     r4, r4, r0
 252         str     r4, [r2]
 253         add     r2, r2, #4
 254         cmp     r2, r3
 255         blo     fixloop
 256 #endif
 257 #endif  /* #ifndef CONFIG_SKIP_RELOCATE_UBOOT */
 258
 259 clear_bss:
 260 #ifndef CONFIG_PRELOADER
 261         ldr     r0, _bss_start
 262         ldr     r1, _bss_end
 263         ldr     r3, _TEXT_BASE          /* Text base */
 264         mov     r4, r7                  /* reloc addr */
 265         sub     r0, r0, r3
 266         add     r0, r0, r4
 267         sub     r1, r1, r3
 268         add     r1, r1, r4
 269         mov     r2, #0x00000000         /* clear                            */
 270
 271 clbss_l:str     r2, [r0]                /* clear loop...                    */
 272         add     r0, r0, #4
 273         cmp     r0, r1
 274         bne     clbss_l
 275
 276 #endif
 277
 278 /*
 279  * We are done. Do not return, instead branch to second part of board
 280  * initialization, now running from RAM.
 281  */
 282 #ifdef CONFIG_NAND_SPL
 283         ldr     pc, _nand_boot
 284
 285 _nand_boot: .word nand_boot
 286 #else
 287         ldr     r0, _TEXT_BASE
 288         ldr     r2, _board_init_r
 289         sub     r2, r2, r0
 290         add     r2, r2, r7      /* position from board_init_r in RAM */
 291         /* setup parameters for board_init_r */
 292         mov     r0, r5          /* gd_t */
 293         mov     r1, r7          /* dest_addr */
 294         /* jump to it ... */
 295         mov     lr, r2
 296         mov     pc, lr
 297
 298 _board_init_r: .word board_init_r
 299 #endif
 300
 301 /*
 302  *************************************************************************
 303  *
 304  * CPU_init_critical registers
 305  *
 306  * setup important registers
 307  * setup memory timing
 308  *
 309  *************************************************************************
 310  */
 311
 312
 313 cpu_init_crit:
 314         /*
 315          * flush v4 I/D caches
 316          */
 317         mov     r0, #0
 318         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 319         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 320
 321         /*
 322          * disable MMU stuff and caches
 323          */
 324         mrc     p15, 0, r0, c1, c0, 0
 325         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 326         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 327         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 328         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 329         mcr     p15, 0, r0, c1, c0, 0
 330
 331         /*
 332          * Go setup Memory and board specific bits prior to relocation.
 333          */
 334         mov     ip, lr          /* perserve link reg across call */
 335         bl      lowlevel_init   /* go setup pll,mux,memory */
 336         mov     lr, ip          /* restore link */
 337         mov     pc, lr          /* back to my caller */
 338 /*
 339  *************************************************************************
 340  *
 341  * Interrupt handling
 342  *
 343  *************************************************************************
 344  */
 345
 346 @
 347 @ IRQ stack frame.
 348 @
 349 #define S_FRAME_SIZE    72
 350
 351 #define S_OLD_R0        68
 352 #define S_PSR           64
 353 #define S_PC            60
 354 #define S_LR            56
 355 #define S_SP            52
 356
 357 #define S_IP            48
 358 #define S_FP            44
 359 #define S_R10           40
 360 #define S_R9            36
 361 #define S_R8            32
 362 #define S_R7            28
 363 #define S_R6            24
 364 #define S_R5            20
 365 #define S_R4            16
 366 #define S_R3            12
 367 #define S_R2            8
 368 #define S_R1            4
 369 #define S_R0            0
 370
 371 #define MODE_SVC 0x13
 372 #define I_BIT    0x80
 373
 374 /*
 375  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 376  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 377  */
 378
 379         .macro  bad_save_user_regs
 380         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current user stack
 381         stmia   sp, {r0 - r12}                  @ Save user registers (now in svc mode) r0-r12
 382
 383         ldr     r2, IRQ_STACK_START_IN
 384         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc and cpsr (into parm regs)
 385         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 386
 387         add     r5, sp, #S_SP
 388         mov     r1, lr
 389         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 390         mov     r0, sp                          @ save current stack into r0 (param register)
 391         .endm
 392
 393         .macro  irq_save_user_regs
 394         sub     sp, sp, #S_FRAME_SIZE
 395         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 396         add     r8, sp, #S_PC                   @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 397         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 398         str     lr, [r8, #0]                    @ Save calling PC
 399         mrs     r6, spsr
 400         str     r6, [r8, #4]                    @ Save CPSR
 401         str     r0, [r8, #8]                    @ Save OLD_R0
 402         mov     r0, sp
 403         .endm
 404
 405         .macro  irq_restore_user_regs
 406         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 407         mov     r0, r0
 408         ldr     lr, [sp, #S_PC]                 @ Get PC
 409         add     sp, sp, #S_FRAME_SIZE
 410         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 411         .endm
 412
 413         .macro get_bad_stack
 414         ldr     r13, IRQ_STACK_START_IN
 415
 416         str     lr, [r13]                       @ save caller lr in position 0 of saved stack
 417         mrs     lr, spsr                        @ get the spsr
 418         str     lr, [r13, #4]                   @ save spsr in position 1 of saved stack
 419
 420         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 421         @ msr   spsr_c, r13
 422         msr     spsr, r13                       @ switch modes, make sure moves will execute
 423         mov     lr, pc                          @ capture return pc
 424         movs    pc, lr                          @ jump to next instruction & switch modes.
 425         .endm
 426
 427         .macro get_irq_stack                    @ setup IRQ stack
 428         ldr     sp, IRQ_STACK_START
 429         .endm
 430
 431         .macro get_fiq_stack                    @ setup FIQ stack
 432         ldr     sp, FIQ_STACK_START
 433         .endm
 434
 435 /*
 436  * exception handlers
 437  */
 438         .align  5
 439 undefined_instruction:
 440         get_bad_stack
 441         bad_save_user_regs
 442         bl      do_undefined_instruction
 443
 444         .align  5
 445 software_interrupt:
 446         get_bad_stack
 447         bad_save_user_regs
 448         bl      do_software_interrupt
 449
 450         .align  5
 451 prefetch_abort:
 452         get_bad_stack
 453         bad_save_user_regs
 454         bl      do_prefetch_abort
 455
 456         .align  5
 457 data_abort:
 458         get_bad_stack
 459         bad_save_user_regs
 460         bl      do_data_abort
 461
 462         .align  5
 463 not_used:
 464         get_bad_stack
 465         bad_save_user_regs
 466         bl      do_not_used
 467
 468 #ifdef CONFIG_USE_IRQ
 469
 470         .align  5
 471 irq:
 472         get_irq_stack
 473         irq_save_user_regs
 474         bl      do_irq
 475         irq_restore_user_regs
 476
 477         .align  5
 478 fiq:
 479         get_fiq_stack
 480         /* someone ought to write a more effiction fiq_save_user_regs */
 481         irq_save_user_regs
 482         bl      do_fiq
 483         irq_restore_user_regs
 484
 485 #else
 486
 487         .align  5
 488 irq:
 489         get_bad_stack
 490         bad_save_user_regs
 491         bl      do_irq
 492
 493         .align  5
 494 fiq:
 495         get_bad_stack
 496         bad_save_user_regs
 497         bl      do_fiq
 498
 499 #endif
 500
 501         .align  5
 502 .globl reset_cpu
 503 reset_cpu:
 504         ldr     r1, rstctl1     /* get clkm1 reset ctl */
 505         mov     r3, #0x3        /* dsp_en + arm_rst = global reset */
 506         strh    r3, [r1]        /* force reset */
 507         mov     r0, r0
 508 _loop_forever:
 509         b       _loop_forever
 510 rstctl1:
 511         .word   0xfffece10