arch/arm/cpu/arm926ejs/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *  Copyright (c) 2010  Albert Aribaud <albert.u.boot@aribaud.net>
  14  *
  15  * See file CREDITS for list of people who contributed to this
  16  * project.
  17  *
  18  * This program is free software; you can redistribute it and/or
  19  * modify it under the terms of the GNU General Public License as
  20  * published by the Free Software Foundation; either version 2 of
  21  * the License, or (at your option) any later version.
  22  *
  23  * This program is distributed in the hope that it will be useful,
  24  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  25  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26  * GNU General Public License for more details.
  27  *
  28  * You should have received a copy of the GNU General Public License
  29  * along with this program; if not, write to the Free Software
  30  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  31  * MA 02111-1307 USA
  32  */
  33
  34 #include <asm-offsets.h>
  35 #include <config.h>
  36 #include <common.h>
  37 #include <version.h>
  38
  39 /*
  40  *************************************************************************
  41  *
  42  * Jump vector table as in table 3.1 in [1]
  43  *
  44  *************************************************************************
  45  */
  46
  47
  48 #ifdef CONFIG_SYS_DV_NOR_BOOT_CFG
  49 .globl _start
  50 _start:
  51 .globl _NOR_BOOT_CFG
  52 _NOR_BOOT_CFG:
  53         .word   CONFIG_SYS_DV_NOR_BOOT_CFG
  54         b       reset
  55 #else
  56 .globl _start
  57 _start:
  58         b       reset
  59 #endif
  60 #ifdef CONFIG_SPL_BUILD
  61 /* No exception handlers in preloader */
  62         ldr     pc, _hang
  63         ldr     pc, _hang
  64         ldr     pc, _hang
  65         ldr     pc, _hang
  66         ldr     pc, _hang
  67         ldr     pc, _hang
  68         ldr     pc, _hang
  69
  70 _hang:
  71         .word   do_hang
  72 /* pad to 64 byte boundary */
  73         .word   0x12345678
  74         .word   0x12345678
  75         .word   0x12345678
  76         .word   0x12345678
  77         .word   0x12345678
  78         .word   0x12345678
  79         .word   0x12345678
  80 #else
  81         ldr     pc, _undefined_instruction
  82         ldr     pc, _software_interrupt
  83         ldr     pc, _prefetch_abort
  84         ldr     pc, _data_abort
  85         ldr     pc, _not_used
  86         ldr     pc, _irq
  87         ldr     pc, _fiq
  88
  89 _undefined_instruction:
  90         .word undefined_instruction
  91 _software_interrupt:
  92         .word software_interrupt
  93 _prefetch_abort:
  94         .word prefetch_abort
  95 _data_abort:
  96         .word data_abort
  97 _not_used:
  98         .word not_used
  99 _irq:
 100         .word irq
 101 _fiq:
 102         .word fiq
 103
 104 #endif  /* CONFIG_SPL_BUILD */
 105         .balignl 16,0xdeadbeef
 106
 107
 108 /*
 109  *************************************************************************
 110  *
 111  * Startup Code (reset vector)
 112  *
 113  * do important init only if we don't start from memory!
 114  * setup Memory and board specific bits prior to relocation.
 115  * relocate armboot to ram
 116  * setup stack
 117  *
 118  *************************************************************************
 119  */
 120
 121 .globl _TEXT_BASE
 122 _TEXT_BASE:
 123 #ifdef CONFIG_NAND_SPL /* deprecated, use instead CONFIG_SPL_BUILD */
 124         .word   CONFIG_SYS_TEXT_BASE
 125 #else
 126 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_TEXT_BASE)
 127         .word   CONFIG_SPL_TEXT_BASE
 128 #else
 129         .word   CONFIG_SYS_TEXT_BASE
 130 #endif
 131 #endif
 132
 133 /*
 134  * These are defined in the board-specific linker script.
 135  * Subtracting _start from them lets the linker put their
 136  * relative position in the executable instead of leaving
 137  * them null.
 138  */
 139 .globl _bss_start_ofs
 140 _bss_start_ofs:
 141         .word __bss_start - _start
 142
 143 .globl _bss_end_ofs
 144 _bss_end_ofs:
 145         .word __bss_end - _start
 146
 147 .globl _end_ofs
 148 _end_ofs:
 149         .word _end - _start
 150
 151 #ifdef CONFIG_NAND_U_BOOT
 152 .globl _end
 153 _end:
 154         .word __bss_end
 155 #endif
 156
 157 #ifdef CONFIG_USE_IRQ
 158 /* IRQ stack memory (calculated at run-time) */
 159 .globl IRQ_STACK_START
 160 IRQ_STACK_START:
 161         .word   0x0badc0de
 162
 163 /* IRQ stack memory (calculated at run-time) */
 164 .globl FIQ_STACK_START
 165 FIQ_STACK_START:
 166         .word 0x0badc0de
 167 #endif
 168
 169 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 170 .globl IRQ_STACK_START_IN
 171 IRQ_STACK_START_IN:
 172         .word   0x0badc0de
 173
 174 /*
 175  * the actual reset code
 176  */
 177
 178 reset:
 179         /*
 180          * set the cpu to SVC32 mode
 181          */
 182         mrs     r0,cpsr
 183         bic     r0,r0,#0x1f
 184         orr     r0,r0,#0xd3
 185         msr     cpsr,r0
 186
 187         /*
 188          * we do sys-critical inits only at reboot,
 189          * not when booting from ram!
 190          */
 191 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 192         bl      cpu_init_crit
 193 #endif
 194
 195         bl      _main
 196
 197 /*------------------------------------------------------------------------------*/
 198
 199 #if !defined(CONFIG_SPL_BUILD) || defined(CONFIG_NAND_SPL)
 200 /*
 201  * void relocate_code (addr_sp, gd, addr_moni)
 202  *
 203  * This function relocates the monitor code.
 204  */
 205         .globl  relocate_code
 206 relocate_code:
 207         mov     r4, r0  /* save addr_sp */
 208         mov     r5, r1  /* save addr of gd */
 209         mov     r6, r2  /* save addr of destination */
 210
 211         adr     r0, _start
 212         sub     r9, r6, r0              /* r9 <- relocation offset */
 213         cmp     r0, r6
 214         moveq   r9, #0                  /* no relocation. offset(r9) = 0 */
 215         beq     relocate_done           /* skip relocation */
 216         mov     r1, r6                  /* r1 <- scratch for copy loop */
 217         ldr     r3, _bss_start_ofs
 218         add     r2, r0, r3              /* r2 <- source end address         */
 219
 220 copy_loop:
 221         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 222         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 223         cmp     r0, r2                  /* until source end address [r2]    */
 224         blo     copy_loop
 225
 226 #ifndef CONFIG_SPL_BUILD
 227         /*
 228          * fix .rel.dyn relocations
 229          */
 230         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 231         sub     r9, r6, r0              /* r9 <- relocation offset */
 232         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 233         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 234         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 235         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 236         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 237         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 238 fixloop:
 239         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 240         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 241         ldr     r1, [r2, #4]
 242         and     r7, r1, #0xff
 243         cmp     r7, #23                 /* relative fixup? */
 244         beq     fixrel
 245         cmp     r7, #2                  /* absolute fixup? */
 246         beq     fixabs
 247         /* ignore unknown type of fixup */
 248         b       fixnext
 249 fixabs:
 250         /* absolute fix: set location to (offset) symbol value */
 251         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 252         add     r1, r10, r1             /* r1 <- address of symbol in table */
 253         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 254         add     r1, r1, r9              /* r1 <- relocated sym addr */
 255         b       fixnext
 256 fixrel:
 257         /* relative fix: increase location by offset */
 258         ldr     r1, [r0]
 259         add     r1, r1, r9
 260 fixnext:
 261         str     r1, [r0]
 262         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 263         cmp     r2, r3
 264         blo     fixloop
 265 #endif
 266
 267 relocate_done:
 268
 269         bx      lr
 270
 271 _rel_dyn_start_ofs:
 272         .word __rel_dyn_start - _start
 273 _rel_dyn_end_ofs:
 274         .word __rel_dyn_end - _start
 275 _dynsym_start_ofs:
 276         .word __dynsym_start - _start
 277
 278 #endif
 279
 280         .globl  c_runtime_cpu_setup
 281 c_runtime_cpu_setup:
 282
 283         bx      lr
 284
 285 /*
 286  *************************************************************************
 287  *
 288  * CPU_init_critical registers
 289  *
 290  * setup important registers
 291  * setup memory timing
 292  *
 293  *************************************************************************
 294  */
 295 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 296 cpu_init_crit:
 297         /*
 298          * flush D cache before disabling it
 299          */
 300         mov     r0, #0
 301 flush_dcache:
 302         mrc     p15, 0, r15, c7, c10, 3
 303         bne     flush_dcache
 304
 305         mcr     p15, 0, r0, c8, c7, 0   /* invalidate TLB */
 306         mcr     p15, 0, r0, c7, c5, 0   /* invalidate I Cache */
 307
 308         /*
 309          * disable MMU and D cache
 310          * enable I cache if CONFIG_SYS_ICACHE_OFF is not defined
 311          */
 312         mrc     p15, 0, r0, c1, c0, 0
 313         bic     r0, r0, #0x00000300     /* clear bits 9:8 (---- --RS) */
 314         bic     r0, r0, #0x00000087     /* clear bits 7, 2:0 (B--- -CAM) */
 315 #ifdef CONFIG_SYS_EXCEPTION_VECTORS_HIGH
 316         orr     r0, r0, #0x00002000     /* set bit 13 (--V- ----) */
 317 #else
 318         bic     r0, r0, #0x00002000     /* clear bit 13 (--V- ----) */
 319 #endif
 320         orr     r0, r0, #0x00000002     /* set bit 2 (A) Align */
 321 #ifndef CONFIG_SYS_ICACHE_OFF
 322         orr     r0, r0, #0x00001000     /* set bit 12 (I) I-Cache */
 323 #endif
 324         mcr     p15, 0, r0, c1, c0, 0
 325
 326         /*
 327          * Go setup Memory and board specific bits prior to relocation.
 328          */
 329         mov     ip, lr          /* perserve link reg across call */
 330         bl      lowlevel_init   /* go setup pll,mux,memory */
 331         mov     lr, ip          /* restore link */
 332         mov     pc, lr          /* back to my caller */
 333 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 334
 335 #ifndef CONFIG_SPL_BUILD
 336 /*
 337  *************************************************************************
 338  *
 339  * Interrupt handling
 340  *
 341  *************************************************************************
 342  */
 343
 344 @
 345 @ IRQ stack frame.
 346 @
 347 #define S_FRAME_SIZE    72
 348
 349 #define S_OLD_R0        68
 350 #define S_PSR           64
 351 #define S_PC            60
 352 #define S_LR            56
 353 #define S_SP            52
 354
 355 #define S_IP            48
 356 #define S_FP            44
 357 #define S_R10           40
 358 #define S_R9            36
 359 #define S_R8            32
 360 #define S_R7            28
 361 #define S_R6            24
 362 #define S_R5            20
 363 #define S_R4            16
 364 #define S_R3            12
 365 #define S_R2            8
 366 #define S_R1            4
 367 #define S_R0            0
 368
 369 #define MODE_SVC 0x13
 370 #define I_BIT    0x80
 371
 372 /*
 373  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 374  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 375  */
 376
 377         .macro  bad_save_user_regs
 378         @ carve out a frame on current user stack
 379         sub     sp, sp, #S_FRAME_SIZE
 380         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 381         ldr     r2, IRQ_STACK_START_IN
 382         @ get values for "aborted" pc and cpsr (into parm regs)
 383         ldmia   r2, {r2 - r3}
 384         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 385         add     r5, sp, #S_SP
 386         mov     r1, lr
 387         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 388         mov     r0, sp          @ save current stack into r0 (param register)
 389         .endm
 390
 391         .macro  irq_save_user_regs
 392         sub     sp, sp, #S_FRAME_SIZE
 393         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 394         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 395         add     r8, sp, #S_PC
 396         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 397         str     lr, [r8, #0]            @ Save calling PC
 398         mrs     r6, spsr
 399         str     r6, [r8, #4]            @ Save CPSR
 400         str     r0, [r8, #8]            @ Save OLD_R0
 401         mov     r0, sp
 402         .endm
 403
 404         .macro  irq_restore_user_regs
 405         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 406         mov     r0, r0
 407         ldr     lr, [sp, #S_PC]                 @ Get PC
 408         add     sp, sp, #S_FRAME_SIZE
 409         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 410         .endm
 411
 412         .macro get_bad_stack
 413         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 414
 415         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 416         mrs     lr, spsr        @ get the spsr
 417         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 418         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 419         @ msr   spsr_c, r13
 420         msr     spsr, r13       @ switch modes, make sure moves will execute
 421         mov     lr, pc          @ capture return pc
 422         movs    pc, lr          @ jump to next instruction & switch modes.
 423         .endm
 424
 425         .macro get_irq_stack                    @ setup IRQ stack
 426         ldr     sp, IRQ_STACK_START
 427         .endm
 428
 429         .macro get_fiq_stack                    @ setup FIQ stack
 430         ldr     sp, FIQ_STACK_START
 431         .endm
 432 #endif  /* CONFIG_SPL_BUILD */
 433
 434 /*
 435  * exception handlers
 436  */
 437 #ifdef CONFIG_SPL_BUILD
 438         .align  5
 439 do_hang:
 440         ldr     sp, _TEXT_BASE                  /* switch to abort stack */
 441 1:
 442         bl      1b                              /* hang and never return */
 443 #else   /* !CONFIG_SPL_BUILD */
 444         .align  5
 445 undefined_instruction:
 446         get_bad_stack
 447         bad_save_user_regs
 448         bl      do_undefined_instruction
 449
 450         .align  5
 451 software_interrupt:
 452         get_bad_stack
 453         bad_save_user_regs
 454         bl      do_software_interrupt
 455
 456         .align  5
 457 prefetch_abort:
 458         get_bad_stack
 459         bad_save_user_regs
 460         bl      do_prefetch_abort
 461
 462         .align  5
 463 data_abort:
 464         get_bad_stack
 465         bad_save_user_regs
 466         bl      do_data_abort
 467
 468         .align  5
 469 not_used:
 470         get_bad_stack
 471         bad_save_user_regs
 472         bl      do_not_used
 473
 474 #ifdef CONFIG_USE_IRQ
 475
 476         .align  5
 477 irq:
 478         get_irq_stack
 479         irq_save_user_regs
 480         bl      do_irq
 481         irq_restore_user_regs
 482
 483         .align  5
 484 fiq:
 485         get_fiq_stack
 486         /* someone ought to write a more effiction fiq_save_user_regs */
 487         irq_save_user_regs
 488         bl      do_fiq
 489         irq_restore_user_regs
 490
 491 #else
 492
 493         .align  5
 494 irq:
 495         get_bad_stack
 496         bad_save_user_regs
 497         bl      do_irq
 498
 499         .align  5
 500 fiq:
 501         get_bad_stack
 502         bad_save_user_regs
 503         bl      do_fiq
 504
 505 #endif
 506 #endif  /* CONFIG_SPL_BUILD */