arch/arm/cpu/arm_intcm/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33 #include <asm-offsets.h>
  34 #include <config.h>
  35 #include <version.h>
  36
  37 /*
  38  *************************************************************************
  39  *
  40  * Jump vector table
  41  *
  42  *************************************************************************
  43  */
  44
  45 .globl _start
  46 _start:
  47         b       reset
  48         ldr     pc, _undefined_instruction
  49         ldr     pc, _software_interrupt
  50         ldr     pc, _prefetch_abort
  51         ldr     pc, _data_abort
  52         ldr     pc, _not_used
  53         ldr     pc, _irq
  54         ldr     pc, _fiq
  55
  56 _undefined_instruction:
  57         .word undefined_instruction
  58 _software_interrupt:
  59         .word software_interrupt
  60 _prefetch_abort:
  61         .word prefetch_abort
  62 _data_abort:
  63         .word data_abort
  64 _not_used:
  65         .word not_used
  66 _irq:
  67         .word irq
  68 _fiq:
  69         .word fiq
  70
  71         .balignl 16,0xdeadbeef
  72
  73 /*
  74  *************************************************************************
  75  *
  76  * Startup Code (reset vector)
  77  *
  78  * do important init only if we don't start from memory!
  79  * setup memory and board specific bits prior to relocation.
  80  * relocate armboot to ram
  81  * setup stack
  82  *
  83  *************************************************************************
  84  */
  85
  86 .globl _TEXT_BASE
  87 _TEXT_BASE:
  88         .word   CONFIG_SYS_TEXT_BASE /* address of _start in the linked image */
  89
  90 /*
  91  * These are defined in the board-specific linker script.
  92  * Subtracting _start from them lets the linker put their
  93  * relative position in the executable instead of leaving
  94  * them null.
  95  */
  96 .globl _bss_start_ofs
  97 _bss_start_ofs:
  98         .word __bss_start - _start
  99
 100 .globl _bss_end_ofs
 101 _bss_end_ofs:
 102         .word __bss_end__ - _start
 103
 104 .globl _end_ofs
 105 _end_ofs:
 106         .word _end - _start
 107
 108 #ifdef CONFIG_USE_IRQ
 109 /* IRQ stack memory (calculated at run-time) */
 110 .globl IRQ_STACK_START
 111 IRQ_STACK_START:
 112         .word   0x0badc0de
 113
 114 /* IRQ stack memory (calculated at run-time) */
 115 .globl FIQ_STACK_START
 116 FIQ_STACK_START:
 117         .word 0x0badc0de
 118 #endif
 119
 120 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 121 .globl IRQ_STACK_START_IN
 122 IRQ_STACK_START_IN:
 123         .word   0x0badc0de
 124
 125 /*
 126  * the actual reset code
 127  */
 128
 129 reset:
 130         /*
 131          * set the cpu to SVC32 mode
 132          */
 133         mrs     r0,cpsr
 134         bic     r0,r0,#0x1f
 135         orr     r0,r0,#0xd3
 136         msr     cpsr,r0
 137
 138         /*
 139          * we do sys-critical inits only at reboot,
 140          * not when booting from ram!
 141          */
 142 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 143         bl      cpu_init_crit
 144 #endif
 145
 146 /* Set stackpointer in internal RAM to call board_init_f */
 147 call_board_init_f:
 148         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 149         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 150         ldr     r0,=0x00000000
 151         bl      board_init_f
 152
 153 /*------------------------------------------------------------------------------*/
 154
 155 /*
 156  * void relocate_code (addr_sp, gd, addr_moni)
 157  *
 158  * This "function" does not return, instead it continues in RAM
 159  * after relocating the monitor code.
 160  *
 161  */
 162         .globl  relocate_code
 163 relocate_code:
 164         mov     r4, r0  /* save addr_sp */
 165         mov     r5, r1  /* save addr of gd */
 166         mov     r6, r2  /* save addr of destination */
 167
 168         /* Set up the stack                                                 */
 169 stack_setup:
 170         mov     sp, r4
 171
 172         adr     r0, _start
 173         cmp     r0, r6
 174         beq     clear_bss               /* skip relocation */
 175         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 176         ldr     r3, _bss_start_ofs
 177         add     r2, r0, r3              /* r2 <- source end address         */
 178
 179 copy_loop:
 180         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 181         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 182         cmp     r0, r2                  /* until source end address [r2]    */
 183         blo     copy_loop
 184
 185 #ifndef CONFIG_SPL_BUILD
 186         /*
 187          * fix .rel.dyn relocations
 188          */
 189         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 190         sub     r9, r6, r0              /* r9 <- relocation offset */
 191         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 192         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 193         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 194         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 195         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 196         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 197 fixloop:
 198         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 199         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 200         ldr     r1, [r2, #4]
 201         and     r7, r1, #0xff
 202         cmp     r7, #23                 /* relative fixup? */
 203         beq     fixrel
 204         cmp     r7, #2                  /* absolute fixup? */
 205         beq     fixabs
 206         /* ignore unknown type of fixup */
 207         b       fixnext
 208 fixabs:
 209         /* absolute fix: set location to (offset) symbol value */
 210         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 211         add     r1, r10, r1             /* r1 <- address of symbol in table */
 212         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 213         add     r1, r1, r9              /* r1 <- relocated sym addr */
 214         b       fixnext
 215 fixrel:
 216         /* relative fix: increase location by offset */
 217         ldr     r1, [r0]
 218         add     r1, r1, r9
 219 fixnext:
 220         str     r1, [r0]
 221         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 222         cmp     r2, r3
 223         blo     fixloop
 224 #endif
 225
 226 clear_bss:
 227 #ifndef CONFIG_SPL_BUILD
 228         ldr     r0, _bss_start_ofs
 229         ldr     r1, _bss_end_ofs
 230         mov     r4, r6                  /* reloc addr */
 231         add     r0, r0, r4
 232         add     r1, r1, r4
 233         mov     r2, #0x00000000         /* clear                            */
 234
 235 clbss_l:cmp     r0, r1                  /* clear loop... */
 236         bhs     clbss_e                 /* if reached end of bss, exit */
 237         str     r2, [r0]
 238         add     r0, r0, #4
 239         b       clbss_l
 240 clbss_e:
 241
 242         bl coloured_LED_init
 243         bl red_led_on
 244 #endif
 245
 246 /*
 247  * We are done. Do not return, instead branch to second part of board
 248  * initialization, now running from RAM.
 249  */
 250 #ifdef CONFIG_NAND_SPL
 251         ldr     r0, _nand_boot_ofs
 252         mov     pc, r0
 253
 254 _nand_boot_ofs:
 255         .word nand_boot
 256 #else
 257         ldr     r0, _board_init_r_ofs
 258         adr     r1, _start
 259         add     lr, r0, r1
 260         add     lr, lr, r9
 261         /* setup parameters for board_init_r */
 262         mov     r0, r5          /* gd_t */
 263         mov     r1, r6          /* dest_addr */
 264         /* jump to it ... */
 265         mov     pc, lr
 266
 267 _board_init_r_ofs:
 268         .word board_init_r - _start
 269 #endif
 270
 271 _rel_dyn_start_ofs:
 272         .word __rel_dyn_start - _start
 273 _rel_dyn_end_ofs:
 274         .word __rel_dyn_end - _start
 275 _dynsym_start_ofs:
 276         .word __dynsym_start - _start
 277
 278 /*
 279  *************************************************************************
 280  *
 281  * CPU_init_critical registers
 282  *
 283  * setup important registers
 284  * setup memory timing
 285  *
 286  *************************************************************************
 287  */
 288
 289 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 290 cpu_init_crit:
 291         /*  arm_int_generic assumes the ARM boot monitor, or user software,
 292          * has initialized the platform
 293          */
 294         mov     pc, lr          /* back to my caller */
 295 #endif
 296 /*
 297  *************************************************************************
 298  *
 299  * Interrupt handling
 300  *
 301  *************************************************************************
 302  */
 303
 304 @
 305 @ IRQ stack frame.
 306 @
 307 #define S_FRAME_SIZE    72
 308
 309 #define S_OLD_R0        68
 310 #define S_PSR           64
 311 #define S_PC            60
 312 #define S_LR            56
 313 #define S_SP            52
 314
 315 #define S_IP            48
 316 #define S_FP            44
 317 #define S_R10           40
 318 #define S_R9            36
 319 #define S_R8            32
 320 #define S_R7            28
 321 #define S_R6            24
 322 #define S_R5            20
 323 #define S_R4            16
 324 #define S_R3            12
 325 #define S_R2            8
 326 #define S_R1            4
 327 #define S_R0            0
 328
 329 #define MODE_SVC 0x13
 330 #define I_BIT    0x80
 331
 332 /*
 333  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 334  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 335  */
 336
 337         .macro  bad_save_user_regs
 338         @ carve out a frame on current user stack
 339         sub     sp, sp, #S_FRAME_SIZE
 340         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 341
 342         ldr     r2, IRQ_STACK_START_IN
 343         @ get values for "aborted" pc and cpsr (into parm regs)
 344         ldmia   r2, {r2 - r3}
 345         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 346         add     r5, sp, #S_SP
 347         mov     r1, lr
 348         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 349         mov     r0, sp          @ save current stack into r0 (param register)
 350         .endm
 351
 352         .macro  irq_save_user_regs
 353         sub     sp, sp, #S_FRAME_SIZE
 354         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 355         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 356         add     r8, sp, #S_PC
 357         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 358         str     lr, [r8, #0]            @ Save calling PC
 359         mrs     r6, spsr
 360         str     r6, [r8, #4]            @ Save CPSR
 361         str     r0, [r8, #8]            @ Save OLD_R0
 362         mov     r0, sp
 363         .endm
 364
 365         .macro  irq_restore_user_regs
 366         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 367         mov     r0, r0
 368         ldr     lr, [sp, #S_PC]                 @ Get PC
 369         add     sp, sp, #S_FRAME_SIZE
 370         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 371         .endm
 372
 373         .macro get_bad_stack
 374         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 375
 376         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 377         mrs     lr, spsr        @ get the spsr
 378         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 379         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 380         @ msr   spsr_c, r13
 381         msr     spsr, r13       @ switch modes, make sure moves will execute
 382         mov     lr, pc          @ capture return pc
 383         movs    pc, lr          @ jump to next instruction & switch modes.
 384         .endm
 385
 386         .macro get_irq_stack                    @ setup IRQ stack
 387         ldr     sp, IRQ_STACK_START
 388         .endm
 389
 390         .macro get_fiq_stack                    @ setup FIQ stack
 391         ldr     sp, FIQ_STACK_START
 392         .endm
 393
 394 /*
 395  * exception handlers
 396  */
 397         .align  5
 398 .globl undefined_instruction
 399 undefined_instruction:
 400         get_bad_stack
 401         bad_save_user_regs
 402         bl      do_undefined_instruction
 403
 404         .align  5
 405 .globl software_interrupt
 406 software_interrupt:
 407         get_bad_stack
 408         bad_save_user_regs
 409         bl      do_software_interrupt
 410
 411         .align  5
 412 .globl prefetch_abort
 413 prefetch_abort:
 414         get_bad_stack
 415         bad_save_user_regs
 416         bl      do_prefetch_abort
 417
 418         .align  5
 419 .globl data_abort
 420 data_abort:
 421         get_bad_stack
 422         bad_save_user_regs
 423         bl      do_data_abort
 424
 425         .align  5
 426 .globl not_used
 427 not_used:
 428         get_bad_stack
 429         bad_save_user_regs
 430         bl      do_not_used
 431
 432 #ifdef CONFIG_USE_IRQ
 433         .align  5
 434 .globl irq
 435 irq:
 436         get_irq_stack
 437         irq_save_user_regs
 438         bl      do_irq
 439         irq_restore_user_regs
 440
 441         .align  5
 442 .globl fiq
 443 fiq:
 444         get_fiq_stack
 445         /* someone ought to write a more effiction fiq_save_user_regs */
 446         irq_save_user_regs
 447         bl      do_fiq
 448         irq_restore_user_regs
 449
 450 #else
 451
 452         .align  5
 453 .globl irq
 454 irq:
 455         get_bad_stack
 456         bad_save_user_regs
 457         bl      do_irq
 458
 459         .align  5
 460 .globl fiq
 461 fiq:
 462         get_bad_stack
 463         bad_save_user_regs
 464         bl      do_fiq
 465
 466 #endif