arm: fixloop(): do not use r8 for relocation
[karo-tx-uboot.git] / arch / arm / cpu / arm_intcm / start.S
1 /*
2  *  armboot - Startup Code for ARM926EJS CPU-core
3  *
4  *  Copyright (c) 2003  Texas Instruments
5  *
6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
7  *
8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
13  *
14  * See file CREDITS for list of people who contributed to this
15  * project.
16  *
17  * This program is free software; you can redistribute it and/or
18  * modify it under the terms of the GNU General Public License as
19  * published by the Free Software Foundation; either version 2 of
20  * the License, or (at your option) any later version.
21  *
22  * This program is distributed in the hope that it will be useful,
23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
25  * GNU General Public License for more details.
26  *
27  * You should have received a copy of the GNU General Public License
28  * along with this program; if not, write to the Free Software
29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
30  * MA 02111-1307 USA
31  */
32
33 #include <asm-offsets.h>
34 #include <config.h>
35 #include <version.h>
36
37 /*
38  *************************************************************************
39  *
40  * Jump vector table
41  *
42  *************************************************************************
43  */
44
45 .globl _start
46 _start:
47         b       reset
48         ldr     pc, _undefined_instruction
49         ldr     pc, _software_interrupt
50         ldr     pc, _prefetch_abort
51         ldr     pc, _data_abort
52         ldr     pc, _not_used
53         ldr     pc, _irq
54         ldr     pc, _fiq
55
56 _undefined_instruction:
57         .word undefined_instruction
58 _software_interrupt:
59         .word software_interrupt
60 _prefetch_abort:
61         .word prefetch_abort
62 _data_abort:
63         .word data_abort
64 _not_used:
65         .word not_used
66 _irq:
67         .word irq
68 _fiq:
69         .word fiq
70
71         .balignl 16,0xdeadbeef
72
73 /*
74  *************************************************************************
75  *
76  * Startup Code (reset vector)
77  *
78  * do important init only if we don't start from memory!
79  * setup memory and board specific bits prior to relocation.
80  * relocate armboot to ram
81  * setup stack
82  *
83  *************************************************************************
84  */
85
86 .globl _TEXT_BASE
87 _TEXT_BASE:
88         .word   CONFIG_SYS_TEXT_BASE /* address of _start in the linked image */
89
90 /*
91  * These are defined in the board-specific linker script.
92  * Subtracting _start from them lets the linker put their
93  * relative position in the executable instead of leaving
94  * them null.
95  */
96 .globl _bss_start_ofs
97 _bss_start_ofs:
98         .word __bss_start - _start
99
100 .globl _bss_end_ofs
101 _bss_end_ofs:
102         .word _end - _start
103
104 #ifdef CONFIG_USE_IRQ
105 /* IRQ stack memory (calculated at run-time) */
106 .globl IRQ_STACK_START
107 IRQ_STACK_START:
108         .word   0x0badc0de
109
110 /* IRQ stack memory (calculated at run-time) */
111 .globl FIQ_STACK_START
112 FIQ_STACK_START:
113         .word 0x0badc0de
114 #endif
115
116 /* IRQ stack memory (calculated at run-time) + 8 bytes */
117 .globl IRQ_STACK_START_IN
118 IRQ_STACK_START_IN:
119         .word   0x0badc0de
120
121 /*
122  * the actual reset code
123  */
124
125 reset:
126         /*
127          * set the cpu to SVC32 mode
128          */
129         mrs     r0,cpsr
130         bic     r0,r0,#0x1f
131         orr     r0,r0,#0xd3
132         msr     cpsr,r0
133
134         /*
135          * we do sys-critical inits only at reboot,
136          * not when booting from ram!
137          */
138 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
139         bl      cpu_init_crit
140 #endif
141
142 /* Set stackpointer in internal RAM to call board_init_f */
143 call_board_init_f:
144         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
145         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
146         ldr     r0,=0x00000000
147         bl      board_init_f
148
149 /*------------------------------------------------------------------------------*/
150
151 /*
152  * void relocate_code (addr_sp, gd, addr_moni)
153  *
154  * This "function" does not return, instead it continues in RAM
155  * after relocating the monitor code.
156  *
157  */
158         .globl  relocate_code
159 relocate_code:
160         mov     r4, r0  /* save addr_sp */
161         mov     r5, r1  /* save addr of gd */
162         mov     r6, r2  /* save addr of destination */
163
164         /* Set up the stack                                                 */
165 stack_setup:
166         mov     sp, r4
167
168         adr     r0, _start
169         cmp     r0, r6
170         beq     clear_bss               /* skip relocation */
171         mov     r1, r6                  /* r1 <- scratch for copy_loop */
172         ldr     r2, _TEXT_BASE
173         ldr     r3, _bss_start_ofs
174         add     r2, r0, r3              /* r2 <- source end address         */
175
176 copy_loop:
177         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
178         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
179         cmp     r0, r2                  /* until source end address [r2]    */
180         blo     copy_loop
181
182 #ifndef CONFIG_PRELOADER
183         /*
184          * fix .rel.dyn relocations
185          */
186         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
187         sub     r9, r6, r0              /* r9 <- relocation offset */
188         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
189         add     r10, r10, r0            /* r10 <- sym table in FLASH */
190         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
191         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
192         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
193         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
194 fixloop:
195         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
196         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
197         ldr     r1, [r2, #4]
198         and     r7, r1, #0xff
199         cmp     r7, #23                 /* relative fixup? */
200         beq     fixrel
201         cmp     r7, #2                  /* absolute fixup? */
202         beq     fixabs
203         /* ignore unknown type of fixup */
204         b       fixnext
205 fixabs:
206         /* absolute fix: set location to (offset) symbol value */
207         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
208         add     r1, r10, r1             /* r1 <- address of symbol in table */
209         ldr     r1, [r1, #4]            /* r1 <- symbol value */
210         add     r1, r9                  /* r1 <- relocated sym addr */
211         b       fixnext
212 fixrel:
213         /* relative fix: increase location by offset */
214         ldr     r1, [r0]
215         add     r1, r1, r9
216 fixnext:
217         str     r1, [r0]
218         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
219         cmp     r2, r3
220         blo     fixloop
221 #endif
222
223 clear_bss:
224 #ifndef CONFIG_PRELOADER
225         ldr     r0, _bss_start_ofs
226         ldr     r1, _bss_end_ofs
227         ldr     r3, _TEXT_BASE          /* Text base */
228         mov     r4, r6                  /* reloc addr */
229         add     r0, r0, r4
230         add     r1, r1, r4
231         mov     r2, #0x00000000         /* clear                            */
232
233 clbss_l:str     r2, [r0]                /* clear loop...                    */
234         add     r0, r0, #4
235         cmp     r0, r1
236         bne     clbss_l
237
238         bl coloured_LED_init
239         bl red_LED_on
240 #endif
241
242 /*
243  * We are done. Do not return, instead branch to second part of board
244  * initialization, now running from RAM.
245  */
246 #ifdef CONFIG_NAND_SPL
247         ldr     r0, _nand_boot_ofs
248         mov     pc, r0
249
250 _nand_boot_ofs:
251         .word nand_boot
252 #else
253         ldr     r0, _board_init_r_ofs
254         adr     r1, _start
255         add     lr, r0, r1
256         add     lr, lr, r9
257         /* setup parameters for board_init_r */
258         mov     r0, r5          /* gd_t */
259         mov     r1, r6          /* dest_addr */
260         /* jump to it ... */
261         mov     pc, lr
262
263 _board_init_r_ofs:
264         .word board_init_r - _start
265 #endif
266
267 _rel_dyn_start_ofs:
268         .word __rel_dyn_start - _start
269 _rel_dyn_end_ofs:
270         .word __rel_dyn_end - _start
271 _dynsym_start_ofs:
272         .word __dynsym_start - _start
273
274 /*
275  *************************************************************************
276  *
277  * CPU_init_critical registers
278  *
279  * setup important registers
280  * setup memory timing
281  *
282  *************************************************************************
283  */
284
285 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
286 cpu_init_crit:
287         /*  arm_int_generic assumes the ARM boot monitor, or user software,
288          * has initialized the platform
289          */
290         mov     pc, lr          /* back to my caller */
291 #endif
292 /*
293  *************************************************************************
294  *
295  * Interrupt handling
296  *
297  *************************************************************************
298  */
299
300 @
301 @ IRQ stack frame.
302 @
303 #define S_FRAME_SIZE    72
304
305 #define S_OLD_R0        68
306 #define S_PSR           64
307 #define S_PC            60
308 #define S_LR            56
309 #define S_SP            52
310
311 #define S_IP            48
312 #define S_FP            44
313 #define S_R10           40
314 #define S_R9            36
315 #define S_R8            32
316 #define S_R7            28
317 #define S_R6            24
318 #define S_R5            20
319 #define S_R4            16
320 #define S_R3            12
321 #define S_R2            8
322 #define S_R1            4
323 #define S_R0            0
324
325 #define MODE_SVC 0x13
326 #define I_BIT    0x80
327
328 /*
329  * use bad_save_user_regs for abort/prefetch/undef/swi ...
330  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
331  */
332
333         .macro  bad_save_user_regs
334         @ carve out a frame on current user stack
335         sub     sp, sp, #S_FRAME_SIZE
336         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
337
338         ldr     r2, IRQ_STACK_START_IN
339         @ get values for "aborted" pc and cpsr (into parm regs)
340         ldmia   r2, {r2 - r3}
341         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
342         add     r5, sp, #S_SP
343         mov     r1, lr
344         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
345         mov     r0, sp          @ save current stack into r0 (param register)
346         .endm
347
348         .macro  irq_save_user_regs
349         sub     sp, sp, #S_FRAME_SIZE
350         stmia   sp, {r0 - r12}                  @ Calling r0-r12
351         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
352         add     r8, sp, #S_PC
353         stmdb   r8, {sp, lr}^           @ Calling SP, LR
354         str     lr, [r8, #0]            @ Save calling PC
355         mrs     r6, spsr
356         str     r6, [r8, #4]            @ Save CPSR
357         str     r0, [r8, #8]            @ Save OLD_R0
358         mov     r0, sp
359         .endm
360
361         .macro  irq_restore_user_regs
362         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
363         mov     r0, r0
364         ldr     lr, [sp, #S_PC]                 @ Get PC
365         add     sp, sp, #S_FRAME_SIZE
366         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
367         .endm
368
369         .macro get_bad_stack
370         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
371
372         str     lr, [r13]       @ save caller lr in position 0 of saved stack
373         mrs     lr, spsr        @ get the spsr
374         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
375         mov     r13, #MODE_SVC  @ prepare SVC-Mode
376         @ msr   spsr_c, r13
377         msr     spsr, r13       @ switch modes, make sure moves will execute
378         mov     lr, pc          @ capture return pc
379         movs    pc, lr          @ jump to next instruction & switch modes.
380         .endm
381
382         .macro get_irq_stack                    @ setup IRQ stack
383         ldr     sp, IRQ_STACK_START
384         .endm
385
386         .macro get_fiq_stack                    @ setup FIQ stack
387         ldr     sp, FIQ_STACK_START
388         .endm
389
390 /*
391  * exception handlers
392  */
393         .align  5
394 .globl undefined_instruction
395 undefined_instruction:
396         get_bad_stack
397         bad_save_user_regs
398         bl      do_undefined_instruction
399
400         .align  5
401 .globl software_interrupt
402 software_interrupt:
403         get_bad_stack
404         bad_save_user_regs
405         bl      do_software_interrupt
406
407         .align  5
408 .globl prefetch_abort
409 prefetch_abort:
410         get_bad_stack
411         bad_save_user_regs
412         bl      do_prefetch_abort
413
414         .align  5
415 .globl data_abort
416 data_abort:
417         get_bad_stack
418         bad_save_user_regs
419         bl      do_data_abort
420
421         .align  5
422 .globl not_used
423 not_used:
424         get_bad_stack
425         bad_save_user_regs
426         bl      do_not_used
427
428 #ifdef CONFIG_USE_IRQ
429         .align  5
430 .globl irq
431 irq:
432         get_irq_stack
433         irq_save_user_regs
434         bl      do_irq
435         irq_restore_user_regs
436
437         .align  5
438 .globl fiq
439 fiq:
440         get_fiq_stack
441         /* someone ought to write a more effiction fiq_save_user_regs */
442         irq_save_user_regs
443         bl      do_fiq
444         irq_restore_user_regs
445
446 #else
447
448         .align  5
449 .globl irq
450 irq:
451         get_bad_stack
452         bad_save_user_regs
453         bl      do_irq
454
455         .align  5
456 .globl fiq
457 fiq:
458         get_bad_stack
459         bad_save_user_regs
460         bl      do_fiq
461
462 #endif