arch/arm/cpu/ixp/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2006
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_FORMAT("elf32-bigarm", "elf32-bigarm", "elf32-bigarm")
   9 OUTPUT_ARCH(arm)
  10 ENTRY(_start)
  11 SECTIONS
  12 {
  13         . = 0x00000000;
  14
  15         . = ALIGN(4);
  16         .text :
  17         {
  18                 *(.__image_copy_start)
  19                 arch/arm/cpu/ixp/start.o(.text*)
  20                 *(.text*)
  21         }
  22
  23         . = ALIGN(4);
  24         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  25
  26         . = ALIGN(4);
  27         .data : {
  28                 *(.data*)
  29         }
  30
  31         . = ALIGN(4);
  32
  33         . = .;
  34
  35         . = ALIGN(4);
  36         .u_boot_list : {
  37                 KEEP(*(SORT(.u_boot_list*)));
  38         }
  39
  40         . = ALIGN(4);
  41
  42         .image_copy_end :
  43         {
  44                 *(.__image_copy_end)
  45         }
  46
  47         .rel_dyn_start :
  48         {
  49                 *(.__rel_dyn_start)
  50         }
  51
  52         .rel.dyn : {
  53                 *(.rel*)
  54         }
  55
  56         .rel_dyn_end :
  57         {
  58                 *(.__rel_dyn_end)
  59         }
  60
  61         _end = .;
  62
  63 /*
  64  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  65  * __bss_base and __bss_limit are for linker only (overlay ordering)
  66  */
  67
  68         .bss_start __rel_dyn_start (OVERLAY) : {
  69                 KEEP(*(.__bss_start));
  70                 __bss_base = .;
  71         }
  72
  73         .bss __bss_base (OVERLAY) : {
  74                 *(.bss*)
  75                  . = ALIGN(4);
  76                  __bss_limit = .;
  77         }
  78         .bss_end __bss_limit (OVERLAY) : {
  79                 KEEP(*(.__bss_end));
  80         }
  81
  82         .dynsym _end : { *(.dynsym) }
  83         .dynbss : { *(.dynbss) }
  84         .dynstr : { *(.dynstr*) }
  85         .dynamic : { *(.dynamic*) }
  86         .hash : { *(.hash*) }
  87         .plt : { *(.plt*) }
  88         .interp : { *(.interp*) }
  89         .gnu : { *(.gnu*) }
  90         .ARM.exidx : { *(.ARM.exidx*) }
  91 }