arch/arm/cpu/lh7a40x/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 #include <asm-offsets.h>
  28 #include <config.h>
  29 #include <version.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 .globl _TEXT_BASE
  75 _TEXT_BASE:
  76         .word   CONFIG_SYS_TEXT_BASE
  77
  78 /*
  79  * These are defined in the board-specific linker script.
  80  * Subtracting _start from them lets the linker put their
  81  * relative position in the executable instead of leaving
  82  * them null.
  83  */
  84 .globl _bss_start_ofs
  85 _bss_start_ofs:
  86         .word __bss_start - _start
  87
  88 .globl _bss_end_ofs
  89 _bss_end_ofs:
  90         .word _end - _start
  91
  92 #ifdef CONFIG_USE_IRQ
  93 /* IRQ stack memory (calculated at run-time) */
  94 .globl IRQ_STACK_START
  95 IRQ_STACK_START:
  96         .word   0x0badc0de
  97
  98 /* IRQ stack memory (calculated at run-time) */
  99 .globl FIQ_STACK_START
 100 FIQ_STACK_START:
 101         .word 0x0badc0de
 102 #endif
 103
 104 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 105 .globl IRQ_STACK_START_IN
 106 IRQ_STACK_START_IN:
 107         .word   0x0badc0de
 108
 109 /*
 110  * the actual reset code
 111  */
 112
 113 reset:
 114         /*
 115          * set the cpu to SVC32 mode
 116          */
 117         mrs     r0,cpsr
 118         bic     r0,r0,#0x1f
 119         orr     r0,r0,#0xd3
 120         msr     cpsr,r0
 121
 122 #define pWDTCTL         0x80001400  /* Watchdog Timer control register */
 123 #define pINTENC         0x8000050C  /* Interupt-Controller enable clear register */
 124 #define pCLKSET         0x80000420  /* clock divisor register */
 125
 126         /* disable watchdog, set watchdog control register to
 127          * all zeros (default reset)
 128          */
 129         ldr     r0, =pWDTCTL
 130         mov     r1, #0x0
 131         str     r1, [r0]
 132
 133         /*
 134          * mask all IRQs by setting all bits in the INTENC register (default)
 135          */
 136         mov     r1, #0xffffffff
 137         ldr     r0, =pINTENC
 138         str     r1, [r0]
 139
 140         /* FCLK:HCLK:PCLK = 1:2:2 */
 141         /* default FCLK is 200 MHz, using 14.7456 MHz fin */
 142         ldr     r0, =pCLKSET
 143         ldr r1, =0x0004ee39
 144 @       ldr r1, =0x0005ee39     @ 1: 2: 4
 145         str     r1, [r0]
 146
 147         /*
 148          * we do sys-critical inits only at reboot,
 149          * not when booting from ram!
 150          */
 151 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 152         bl      cpu_init_crit
 153 #endif
 154
 155 /* Set stackpointer in internal RAM to call board_init_f */
 156 call_board_init_f:
 157         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 158         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 159         ldr     r0,=0x00000000
 160         bl      board_init_f
 161
 162 /*------------------------------------------------------------------------------*/
 163
 164 /*
 165  * void relocate_code (addr_sp, gd, addr_moni)
 166  *
 167  * This "function" does not return, instead it continues in RAM
 168  * after relocating the monitor code.
 169  *
 170  */
 171         .globl  relocate_code
 172 relocate_code:
 173         mov     r4, r0  /* save addr_sp */
 174         mov     r5, r1  /* save addr of gd */
 175         mov     r6, r2  /* save addr of destination */
 176
 177         /* Set up the stack                                                 */
 178 stack_setup:
 179         mov     sp, r4
 180
 181         adr     r0, _start
 182         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 183         ldr     r2, _TEXT_BASE
 184         ldr     r3, _bss_start_ofs
 185         add     r2, r0, r3              /* r2 <- source end address         */
 186         cmp     r0, r6
 187         beq     clear_bss
 188
 189 copy_loop:
 190         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 191         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 192         cmp     r0, r2                  /* until source end address [r2]    */
 193         blo     copy_loop
 194
 195 #ifndef CONFIG_PRELOADER
 196         /*
 197          * fix .rel.dyn relocations
 198          */
 199         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 200         sub     r9, r6, r0              /* r9 <- relocation offset */
 201         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 202         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 203         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 204         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 205         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 206         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 207 fixloop:
 208         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 209         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 210         ldr     r1, [r2, #4]
 211         and     r8, r1, #0xff
 212         cmp     r8, #23                 /* relative fixup? */
 213         beq     fixrel
 214         cmp     r8, #2                  /* absolute fixup? */
 215         beq     fixabs
 216         /* ignore unknown type of fixup */
 217         b       fixnext
 218 fixabs:
 219         /* absolute fix: set location to (offset) symbol value */
 220         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 221         add     r1, r10, r1             /* r1 <- address of symbol in table */
 222         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 223         add     r1, r9                  /* r1 <- relocated sym addr */
 224         b       fixnext
 225 fixrel:
 226         /* relative fix: increase location by offset */
 227         ldr     r1, [r0]
 228         add     r1, r1, r9
 229 fixnext:
 230         str     r1, [r0]
 231         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 232         cmp     r2, r3
 233         blo     fixloop
 234 #endif
 235
 236 clear_bss:
 237 #ifndef CONFIG_PRELOADER
 238         ldr     r0, _bss_start_ofs
 239         ldr     r1, _bss_end_ofs
 240         ldr     r3, _TEXT_BASE          /* Text base */
 241         mov     r4, r6                  /* reloc addr */
 242         add     r0, r0, r4
 243         add     r1, r1, r4
 244         mov     r2, #0x00000000         /* clear                            */
 245
 246 clbss_l:str     r2, [r0]                /* clear loop...                    */
 247         add     r0, r0, #4
 248         cmp     r0, r1
 249         bne     clbss_l
 250 #endif
 251
 252 /*
 253  * We are done. Do not return, instead branch to second part of board
 254  * initialization, now running from RAM.
 255  */
 256         ldr     r0, _board_init_r_ofs
 257         adr     r1, _start
 258         add     lr, r0, r1
 259         add     lr, lr, r9
 260         /* setup parameters for board_init_r */
 261         mov     r0, r5          /* gd_t */
 262         mov     r1, r6          /* dest_addr */
 263         /* jump to it ... */
 264         mov     pc, lr
 265
 266 _board_init_r_ofs:
 267         .word board_init_r - _start
 268
 269 _rel_dyn_start_ofs:
 270         .word __rel_dyn_start - _start
 271 _rel_dyn_end_ofs:
 272         .word __rel_dyn_end - _start
 273 _dynsym_start_ofs:
 274         .word __dynsym_start - _start
 275
 276 /*
 277  *************************************************************************
 278  *
 279  * CPU_init_critical registers
 280  *
 281  * setup important registers
 282  * setup memory timing
 283  *
 284  *************************************************************************
 285  */
 286
 287
 288 cpu_init_crit:
 289         /*
 290          * flush v4 I/D caches
 291          */
 292         mov     r0, #0
 293         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 294         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 295
 296         /*
 297          * disable MMU stuff and caches
 298          */
 299         mrc     p15, 0, r0, c1, c0, 0
 300         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 301         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 302         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 303         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 304         orr     r0, r0, #0x40000000     @ set bit 30 (nF) notFastBus
 305         mcr     p15, 0, r0, c1, c0, 0
 306
 307
 308         /*
 309          * before relocating, we have to setup RAM timing
 310          * because memory timing is board-dependend, you will
 311          * find a lowlevel_init.S in your board directory.
 312          */
 313         mov     ip, lr
 314         bl      lowlevel_init
 315         mov     lr, ip
 316
 317         mov     pc, lr
 318
 319
 320 /*
 321  *************************************************************************
 322  *
 323  * Interrupt handling
 324  *
 325  *************************************************************************
 326  */
 327
 328 @
 329 @ IRQ stack frame.
 330 @
 331 #define S_FRAME_SIZE    72
 332
 333 #define S_OLD_R0        68
 334 #define S_PSR           64
 335 #define S_PC            60
 336 #define S_LR            56
 337 #define S_SP            52
 338
 339 #define S_IP            48
 340 #define S_FP            44
 341 #define S_R10           40
 342 #define S_R9            36
 343 #define S_R8            32
 344 #define S_R7            28
 345 #define S_R6            24
 346 #define S_R5            20
 347 #define S_R4            16
 348 #define S_R3            12
 349 #define S_R2            8
 350 #define S_R1            4
 351 #define S_R0            0
 352
 353 #define MODE_SVC 0x13
 354 #define I_BIT    0x80
 355
 356 /*
 357  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 358  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 359  */
 360
 361         .macro  bad_save_user_regs
 362         sub     sp, sp, #S_FRAME_SIZE
 363         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 364         ldr     r2, IRQ_STACK_START_IN
 365         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 366         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 367
 368         add     r5, sp, #S_SP
 369         mov     r1, lr
 370         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 371         mov     r0, sp
 372         .endm
 373
 374         .macro  irq_save_user_regs
 375         sub     sp, sp, #S_FRAME_SIZE
 376         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 377         add     r8, sp, #S_PC
 378         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 379         str     lr, [r8, #0]                    @ Save calling PC
 380         mrs     r6, spsr
 381         str     r6, [r8, #4]                    @ Save CPSR
 382         str     r0, [r8, #8]                    @ Save OLD_R0
 383         mov     r0, sp
 384         .endm
 385
 386         .macro  irq_restore_user_regs
 387         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 388         mov     r0, r0
 389         ldr     lr, [sp, #S_PC]                 @ Get PC
 390         add     sp, sp, #S_FRAME_SIZE
 391         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 392         .endm
 393
 394         .macro get_bad_stack
 395         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 396
 397         str     lr, [r13]                       @ save caller lr / spsr
 398         mrs     lr, spsr
 399         str     lr, [r13, #4]
 400
 401         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 402         @ msr   spsr_c, r13
 403         msr     spsr, r13
 404         mov     lr, pc
 405         movs    pc, lr
 406         .endm
 407
 408         .macro get_irq_stack                    @ setup IRQ stack
 409         ldr     sp, IRQ_STACK_START
 410         .endm
 411
 412         .macro get_fiq_stack                    @ setup FIQ stack
 413         ldr     sp, FIQ_STACK_START
 414         .endm
 415
 416 /*
 417  * exception handlers
 418  */
 419         .align  5
 420 undefined_instruction:
 421         get_bad_stack
 422         bad_save_user_regs
 423         bl      do_undefined_instruction
 424
 425         .align  5
 426 software_interrupt:
 427         get_bad_stack
 428         bad_save_user_regs
 429         bl      do_software_interrupt
 430
 431         .align  5
 432 prefetch_abort:
 433         get_bad_stack
 434         bad_save_user_regs
 435         bl      do_prefetch_abort
 436
 437         .align  5
 438 data_abort:
 439         get_bad_stack
 440         bad_save_user_regs
 441         bl      do_data_abort
 442
 443         .align  5
 444 not_used:
 445         get_bad_stack
 446         bad_save_user_regs
 447         bl      do_not_used
 448
 449 #ifdef CONFIG_USE_IRQ
 450
 451         .align  5
 452 irq:
 453         get_irq_stack
 454         irq_save_user_regs
 455         bl      do_irq
 456         irq_restore_user_regs
 457
 458         .align  5
 459 fiq:
 460         get_fiq_stack
 461         /* someone ought to write a more effiction fiq_save_user_regs */
 462         irq_save_user_regs
 463         bl      do_fiq
 464         irq_restore_user_regs
 465
 466 #else
 467
 468         .align  5
 469 irq:
 470         get_bad_stack
 471         bad_save_user_regs
 472         bl      do_irq
 473
 474         .align  5
 475 fiq:
 476         get_bad_stack
 477         bad_save_user_regs
 478         bl      do_fiq
 479
 480 #endif
 481
 482         .align  5
 483 .globl reset_cpu
 484 reset_cpu:
 485         bl      disable_interrupts
 486
 487         /* Disable watchdog */
 488         ldr     r1, =pWDTCTL
 489         mov     r3, #0
 490         str     r3, [r1]
 491
 492         /* reset counter */
 493         ldr     r3, =0x00001984
 494         str     r3, [r1, #4]
 495
 496         /* Enable the watchdog */
 497         mov     r3, #1
 498         str     r3, [r1]
 499
 500 _loop_forever:
 501         b       _loop_forever