arch/arm/cpu/u-boot.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  11 OUTPUT_ARCH(arm)
  12 ENTRY(_start)
  13 SECTIONS
  14 {
  15         . = 0x00000000;
  16
  17         . = ALIGN(4);
  18         .text :
  19         {
  20                 *(.__image_copy_start)
  21                 CPUDIR/start.o (.text*)
  22                 *(.text*)
  23         }
  24
  25         . = ALIGN(4);
  26         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  27
  28         . = ALIGN(4);
  29         .data : {
  30                 *(.data*)
  31         }
  32
  33         . = ALIGN(4);
  34
  35         . = .;
  36
  37         . = ALIGN(4);
  38         .u_boot_list : {
  39                 KEEP(*(SORT(.u_boot_list*)));
  40         }
  41
  42         . = ALIGN(4);
  43
  44         .image_copy_end :
  45         {
  46                 *(.__image_copy_end)
  47         }
  48
  49         .rel_dyn_start :
  50         {
  51                 *(.__rel_dyn_start)
  52         }
  53
  54         .rel.dyn : {
  55                 *(.rel*)
  56         }
  57
  58         .rel_dyn_end :
  59         {
  60                 *(.__rel_dyn_end)
  61         }
  62
  63         _end = .;
  64
  65         /*
  66          * Deprecated: this MMU section is used by pxa at present but
  67          * should not be used by new boards/CPUs.
  68          */
  69         . = ALIGN(4096);
  70         .mmutable : {
  71                 *(.mmutable)
  72         }
  73
  74 /*
  75  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  76  * __bss_base and __bss_limit are for linker only (overlay ordering)
  77  */
  78
  79         .bss_start __rel_dyn_start (OVERLAY) : {
  80                 KEEP(*(.__bss_start));
  81                 __bss_base = .;
  82         }
  83
  84         .bss __bss_base (OVERLAY) : {
  85                 *(.bss*)
  86                  . = ALIGN(4);
  87                  __bss_limit = .;
  88         }
  89
  90         .bss_end __bss_limit (OVERLAY) : {
  91                 KEEP(*(.__bss_end));
  92         }
  93
  94         .dynsym _end : { *(.dynsym) }
  95         .hash : { *(.hash) }
  96         .got.plt : { *(.got.plt) }
  97         .dynbss : { *(.dynbss) }
  98         .dynstr : { *(.dynstr*) }
  99         .dynamic : { *(.dynamic*) }
 100         .plt : { *(.plt*) }
 101         .interp : { *(.interp*) }
 102         .gnu : { *(.gnu*) }
 103         .ARM.exidx : { *(.ARM.exidx*) }
 104 }