ARM: use r9 for gd
[karo-tx-uboot.git] / arch / arm / lib / crt0.S
1 /*
2  *  crt0 - C-runtime startup Code for ARM U-Boot
3  *
4  *  Copyright (c) 2012  Albert ARIBAUD <albert.u.boot@aribaud.net>
5  *
6  * SPDX-License-Identifier:     GPL-2.0+
7  */
8
9 #include <config.h>
10 #include <asm-offsets.h>
11 #include <linux/linkage.h>
12
13 /*
14  * This file handles the target-independent stages of the U-Boot
15  * start-up where a C runtime environment is needed. Its entry point
16  * is _main and is branched into from the target's start.S file.
17  *
18  * _main execution sequence is:
19  *
20  * 1. Set up initial environment for calling board_init_f().
21  *    This environment only provides a stack and a place to store
22  *    the GD ('global data') structure, both located in some readily
23  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
24  *    global data, initialized or not (BSS), are UNAVAILABLE; only
25  *    CONSTANT initialized data are available.
26  *
27  * 2. Call board_init_f(). This function prepares the hardware for
28  *    execution from system RAM (DRAM, DDR...) As system RAM may not
29  *    be available yet, , board_init_f() must use the current GD to
30  *    store any data which must be passed on to later stages. These
31  *    data include the relocation destination, the future stack, and
32  *    the future GD location.
33  *
34  * (the following applies only to non-SPL builds)
35  *
36  * 3. Set up intermediate environment where the stack and GD are the
37  *    ones allocated by board_init_f() in system RAM, but BSS and
38  *    initialized non-const data are still not available.
39  *
40  * 4. Call relocate_code(). This function relocates U-Boot from its
41  *    current location into the relocation destination computed by
42  *    board_init_f().
43  *
44  * 5. Set up final environment for calling board_init_r(). This
45  *    environment has BSS (initialized to 0), initialized non-const
46  *    data (initialized to their intended value), and stack in system
47  *    RAM. GD has retained values set by board_init_f(). Some CPUs
48  *    have some work left to do at this point regarding memory, so
49  *    call c_runtime_cpu_setup.
50  *
51  * 6. Branch to board_init_r().
52  */
53
54 /*
55  * entry point of crt0 sequence
56  */
57
58 ENTRY(_main)
59
60 /*
61  * Set up initial C runtime environment and call board_init_f(0).
62  */
63
64 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
65         ldr     sp, =(CONFIG_SPL_STACK)
66 #else
67         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
68 #endif
69         bic     sp, sp, #7      /* 8-byte alignment for ABI compliance */
70         sub     sp, #GD_SIZE    /* allocate one GD above SP */
71         bic     sp, sp, #7      /* 8-byte alignment for ABI compliance */
72         mov     r9, sp          /* GD is above SP */
73         mov     r0, #0
74         bl      board_init_f
75
76 #if ! defined(CONFIG_SPL_BUILD)
77
78 /*
79  * Set up intermediate environment (new sp and gd) and call
80  * relocate_code(addr_moni). Trick here is that we'll return
81  * 'here' but relocated.
82  */
83
84         ldr     sp, [r9, #GD_START_ADDR_SP]     /* sp = gd->start_addr_sp */
85         bic     sp, sp, #7      /* 8-byte alignment for ABI compliance */
86         ldr     r9, [r9, #GD_BD]                /* r9 = gd->bd */
87         sub     r9, r9, #GD_SIZE                /* new GD is below bd */
88
89         adr     lr, here
90         ldr     r0, [r9, #GD_RELOC_OFF]         /* r0 = gd->reloc_off */
91         add     lr, lr, r0
92         ldr     r0, [r9, #GD_RELOCADDR]         /* r0 = gd->relocaddr */
93         b       relocate_code
94 here:
95
96 /* Set up final (full) environment */
97
98         bl      c_runtime_cpu_setup     /* we still call old routine here */
99
100         ldr     r0, =__bss_start        /* this is auto-relocated! */
101         ldr     r1, =__bss_end          /* this is auto-relocated! */
102
103         mov     r2, #0x00000000         /* prepare zero to clear BSS */
104
105 clbss_l:cmp     r0, r1                  /* while not at end of BSS */
106         strlo   r2, [r0]                /* clear 32-bit BSS word */
107         addlo   r0, r0, #4              /* move to next */
108         blo     clbss_l
109
110         bl coloured_LED_init
111         bl red_led_on
112
113         /* call board_init_r(gd_t *id, ulong dest_addr) */
114         mov     r0, r9                  /* gd_t */
115         ldr     r1, [r9, #GD_RELOCADDR] /* dest_addr */
116         /* call board_init_r */
117         ldr     pc, =board_init_r       /* this is auto-relocated! */
118
119         /* we should not return here. */
120
121 #endif
122
123 ENDPROC(_main)