arch/i386/cpu/start.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002  Omicron Ceti AB, Daniel Engström <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25
  26 #include <config.h>
  27 #include <version.h>
  28
  29
  30 .section .text
  31 .code32
  32 .globl _start
  33 .type _start, @function
  34 .globl _i386boot_start
  35 _i386boot_start:
  36 _start:
  37         movl    $0x18,%eax      /* Load our segement registes, the
  38                                  * gdt have already been loaded by start16.S */
  39         movw    %ax,%fs
  40         movw    %ax,%ds
  41         movw    %ax,%gs
  42         movw    %ax,%es
  43         movw    %ax,%ss
  44
  45         /* We call a few functions in the board support package
  46          * since we have no stack yet we'll have to use %ebp
  47          * to store the return address */
  48
  49         /* Early platform init (setup gpio, etc ) */
  50         mov     $early_board_init_ret, %ebp
  51         jmp     early_board_init
  52 early_board_init_ret:
  53
  54         /* The __port80 entry-point should be usabe by now */
  55         /* so we try to indicate progress */
  56         movw    $0x01, %ax
  57         movl    $.progress0, %ebp
  58         jmp     show_boot_progress_asm
  59 .progress0:
  60
  61         /* size memory */
  62         mov     $mem_init_ret, %ebp
  63         jmp     mem_init
  64 mem_init_ret:
  65
  66         /* Check we have enough memory for stack */
  67         movl    $CONFIG_SYS_STACK_SIZE, %ecx
  68         cmpl    %ecx, %eax
  69         jae     mem_ok
  70
  71         /* indicate (lack of) progress */
  72         movw    $0x81, %ax
  73         movl    $.progress0a, %ebp
  74         jmp     show_boot_progress_asm
  75 .progress0a:
  76         jmp     die
  77 mem_ok:
  78         /* Set stack pointer to upper memory limit*/
  79         movl    %eax, %esp
  80
  81         /* indicate progress */
  82         movw    $0x02, %ax
  83         movl    $.progress1, %ebp
  84         jmp     show_boot_progress_asm
  85 .progress1:
  86
  87         /* Test the stack */
  88         pushl   $0
  89         popl    %eax
  90         cmpl    $0, %eax
  91         jne     no_stack
  92         push    $0x55aa55aa
  93         popl    %ebx
  94         cmpl    $0x55aa55aa, %ebx
  95         je      stack_ok
  96
  97 no_stack:
  98         /* indicate (lack of) progress */
  99         movw    $0x82, %ax
 100         movl    $.progress1a, %ebp
 101         jmp     show_boot_progress_asm
 102 .progress1a:
 103         jmp die
 104
 105
 106 stack_ok:
 107         /* indicate progress */
 108         movw    $0x03, %ax
 109         movl    $.progress2, %ebp
 110         jmp     show_boot_progress_asm
 111 .progress2:
 112
 113         wbinvd
 114
 115         /* Get upper memory limit */
 116         movl %esp, %ecx
 117         subl $CONFIG_SYS_STACK_SIZE, %ecx
 118
 119         /* Create a Stack Frame */
 120         pushl %ebp
 121         movl %esp, %ebp
 122
 123         /* stack_limit parameter */
 124         pushl   %ecx
 125         call    board_init_f    /* Enter, U-boot! */
 126
 127         /* indicate (lack of) progress */
 128         movw    $0x85, %ax
 129         movl    $.progress4a, %ebp
 130         jmp     show_boot_progress_asm
 131 .progress4a:
 132
 133 die:    hlt
 134         jmp     die
 135         hlt