arch/microblaze/cpu/u-boot-spl.lds

   1 /*
   2  * (C) Copyright 2013 - 2014 Xilinx, Inc
   3  *
   4  * Michal Simek <michal.simek@xilinx.com>
   5  *
   6  * SPDX-License-Identifier:     GPL-2.0+
   7  */
   8
   9 #include <asm-offsets.h>
  10
  11 OUTPUT_ARCH(microblaze)
  12 ENTRY(_start)
  13
  14 SECTIONS
  15 {
  16         .text ALIGN(0x4):
  17         {
  18                 __text_start = .;
  19                 arch/microblaze/cpu/start.o (.text)
  20                 *(.text)
  21                 *(.text.*)
  22                 __text_end = .;
  23         }
  24
  25         .rodata ALIGN(0x4):
  26         {
  27                 __rodata_start = .;
  28                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  29                 __rodata_end = .;
  30         }
  31
  32         .data ALIGN(0x4):
  33         {
  34                 __data_start = .;
  35                 *(.data)
  36                 *(.data.*)
  37                 __data_end = .;
  38         }
  39
  40         .bss ALIGN(0x4):
  41         {
  42                 __bss_start = .;
  43                 *(.sbss)
  44                 *(.scommon)
  45                 *(.bss)
  46                 *(.bss.*)
  47                 *(COMMON)
  48                 . = ALIGN(4);
  49                 __bss_end = .;
  50         }
  51         __end = . ;
  52 }
  53
  54 #if defined(CONFIG_SPL_MAX_FOOTPRINT)
  55 ASSERT(__end - _start < (CONFIG_SPL_MAX_FOOTPRINT), \
  56         "SPL image plus BSS too big");
  57 #endif