arch/mips/cpu/mips32/start.S

   1 /*
   2  *  Startup Code for MIPS32 CPU-core
   3  *
   4  *  Copyright (c) 2003  Wolfgang Denk <wd@denx.de>
   5  *
   6  * SPDX-License-Identifier:     GPL-2.0+
   7  */
   8
   9 #include <asm-offsets.h>
  10 #include <config.h>
  11 #include <asm/regdef.h>
  12 #include <asm/mipsregs.h>
  13
  14 #ifndef CONFIG_SYS_MIPS_CACHE_MODE
  15 #define CONFIG_SYS_MIPS_CACHE_MODE CONF_CM_CACHABLE_NONCOHERENT
  16 #endif
  17
  18         /*
  19          * For the moment disable interrupts, mark the kernel mode and
  20          * set ST0_KX so that the CPU does not spit fire when using
  21          * 64-bit addresses.
  22          */
  23         .macro  setup_c0_status set clr
  24         .set    push
  25         mfc0    t0, CP0_STATUS
  26         or      t0, ST0_CU0 | \set | 0x1f | \clr
  27         xor     t0, 0x1f | \clr
  28         mtc0    t0, CP0_STATUS
  29         .set    noreorder
  30         sll     zero, 3                         # ehb
  31         .set    pop
  32         .endm
  33
  34         .set noreorder
  35
  36         .globl _start
  37         .text
  38 _start:
  39         /* U-boot entry point */
  40         b       reset
  41          nop
  42
  43         .org 0x10
  44 #if defined(CONFIG_SYS_XWAY_EBU_BOOTCFG)
  45         /*
  46          * Almost all Lantiq XWAY SoC devices have an external bus unit (EBU) to
  47          * access external NOR flashes. If the board boots from NOR flash the
  48          * internal BootROM does a blind read at address 0xB0000010 to read the
  49          * initial configuration for that EBU in order to access the flash
  50          * device with correct parameters. This config option is board-specific.
  51          */
  52         .word CONFIG_SYS_XWAY_EBU_BOOTCFG
  53         .word 0x0
  54 #elif defined(CONFIG_MALTA)
  55         /*
  56          * Linux expects the Board ID here.
  57          */
  58         .word 0x00000420        # 0x420 (Malta Board with CoreLV)
  59         .word 0x00000000
  60 #endif
  61
  62         .org 0x200
  63         /* TLB refill, 32 bit task */
  64 1:      b       1b
  65          nop
  66
  67         .org 0x280
  68         /* XTLB refill, 64 bit task */
  69 1:      b       1b
  70          nop
  71
  72         .org 0x300
  73         /* Cache error exception */
  74 1:      b       1b
  75          nop
  76
  77         .org 0x380
  78         /* General exception */
  79 1:      b       1b
  80          nop
  81
  82         .org 0x400
  83         /* Catch interrupt exceptions */
  84 1:      b       1b
  85          nop
  86
  87         .org 0x480
  88         /* EJTAG debug exception */
  89 1:      b       1b
  90          nop
  91
  92         .align 4
  93 reset:
  94
  95         /* Clear watch registers */
  96         mtc0    zero, CP0_WATCHLO
  97         mtc0    zero, CP0_WATCHHI
  98
  99         /* WP(Watch Pending), SW0/1 should be cleared */
 100         mtc0    zero, CP0_CAUSE
 101
 102         setup_c0_status 0 0
 103
 104         /* Init Timer */
 105         mtc0    zero, CP0_COUNT
 106         mtc0    zero, CP0_COMPARE
 107
 108 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 109         /* CONFIG0 register */
 110         li      t0, CONF_CM_UNCACHED
 111         mtc0    t0, CP0_CONFIG
 112 #endif
 113
 114         /* Initialize $gp */
 115         bal     1f
 116          nop
 117         .word   _gp
 118 1:
 119         lw      gp, 0(ra)
 120
 121 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 122         /* Initialize any external memory */
 123         la      t9, lowlevel_init
 124         jalr    t9
 125          nop
 126
 127         /* Initialize caches... */
 128         la      t9, mips_cache_reset
 129         jalr    t9
 130          nop
 131
 132         /* ... and enable them */
 133         li      t0, CONFIG_SYS_MIPS_CACHE_MODE
 134         mtc0    t0, CP0_CONFIG
 135 #endif
 136
 137         /* Set up temporary stack */
 138         li      sp, CONFIG_SYS_SDRAM_BASE + CONFIG_SYS_INIT_SP_OFFSET
 139         move    fp, sp
 140
 141         la      t9, board_init_f
 142         jr      t9
 143          move   ra, zero
 144
 145 /*
 146  * void relocate_code (addr_sp, gd, addr_moni)
 147  *
 148  * This "function" does not return, instead it continues in RAM
 149  * after relocating the monitor code.
 150  *
 151  * a0 = addr_sp
 152  * a1 = gd
 153  * a2 = destination address
 154  */
 155         .globl  relocate_code
 156         .ent    relocate_code
 157 relocate_code:
 158         move    sp, a0                  # set new stack pointer
 159         move    fp, sp
 160
 161         move    s0, a1                  # save gd in s0
 162         move    s2, a2                  # save destination address in s2
 163
 164         li      t0, CONFIG_SYS_MONITOR_BASE
 165         sub     s1, s2, t0              # s1 <-- relocation offset
 166
 167         la      t3, in_ram
 168         lw      t2, -12(t3)             # t2 <-- __image_copy_end
 169         move    t1, a2
 170
 171         add     gp, s1                  # adjust gp
 172
 173         /*
 174          * t0 = source address
 175          * t1 = target address
 176          * t2 = source end address
 177          */
 178 1:
 179         lw      t3, 0(t0)
 180         sw      t3, 0(t1)
 181         addu    t0, 4
 182         blt     t0, t2, 1b
 183          addu   t1, 4
 184
 185         /* If caches were enabled, we would have to flush them here. */
 186         sub     a1, t1, s2              # a1 <-- size
 187         la      t9, flush_cache
 188         jalr    t9
 189          move   a0, s2                  # a0 <-- destination address
 190
 191         /* Jump to where we've relocated ourselves */
 192         addi    t0, s2, in_ram - _start
 193         jr      t0
 194          nop
 195
 196         .word   __rel_dyn_end
 197         .word   __rel_dyn_start
 198         .word   __image_copy_end
 199         .word   _GLOBAL_OFFSET_TABLE_
 200         .word   num_got_entries
 201
 202 in_ram:
 203         /*
 204          * Now we want to update GOT.
 205          *
 206          * GOT[0] is reserved. GOT[1] is also reserved for the dynamic object
 207          * generated by GNU ld. Skip these reserved entries from relocation.
 208          */
 209         lw      t3, -4(t0)              # t3 <-- num_got_entries
 210         lw      t8, -8(t0)              # t8 <-- _GLOBAL_OFFSET_TABLE_
 211         add     t8, s1                  # t8 now holds relocated _G_O_T_
 212         addi    t8, t8, 8               # skipping first two entries
 213         li      t2, 2
 214 1:
 215         lw      t1, 0(t8)
 216         beqz    t1, 2f
 217          add    t1, s1
 218         sw      t1, 0(t8)
 219 2:
 220         addi    t2, 1
 221         blt     t2, t3, 1b
 222          addi   t8, 4
 223
 224         /* Update dynamic relocations */
 225         lw      t1, -16(t0)             # t1 <-- __rel_dyn_start
 226         lw      t2, -20(t0)             # t2 <-- __rel_dyn_end
 227
 228         b       2f                      # skip first reserved entry
 229          addi   t1, 8
 230
 231 1:
 232         lw      t8, -4(t1)              # t8 <-- relocation info
 233
 234         li      t3, 3
 235         bne     t8, t3, 2f              # skip non R_MIPS_REL32 entries
 236          nop
 237
 238         lw      t3, -8(t1)              # t3 <-- location to fix up in FLASH
 239
 240         lw      t8, 0(t3)               # t8 <-- original pointer
 241         add     t8, s1                  # t8 <-- adjusted pointer
 242
 243         add     t3, s1                  # t3 <-- location to fix up in RAM
 244         sw      t8, 0(t3)
 245
 246 2:
 247         blt     t1, t2, 1b
 248          addi   t1, 8                   # each rel.dyn entry is 8 bytes
 249
 250         /*
 251          * Clear BSS
 252          *
 253          * GOT is now relocated. Thus __bss_start and __bss_end can be
 254          * accessed directly via $gp.
 255          */
 256         la      t1, __bss_start         # t1 <-- __bss_start
 257         la      t2, __bss_end           # t2 <-- __bss_end
 258
 259 1:
 260         sw      zero, 0(t1)
 261         blt     t1, t2, 1b
 262          addi   t1, 4
 263
 264         move    a0, s0                  # a0 <-- gd
 265         move    a1, s2
 266         la      t9, board_init_r
 267         jr      t9
 268          move   ra, zero
 269
 270         .end    relocate_code