arch/powerpc/cpu/74xx_7xx/u-boot.lds

   1 /*
   2  * (C) Copyright 2010 Wolfgang Denk <wd@denx.de>
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 OUTPUT_ARCH(powerpc)
  24
  25 SECTIONS
  26 {
  27   .text      :
  28   {
  29     arch/powerpc/cpu/74xx_7xx/start.o   (.text*)
  30
  31     *(.text*)
  32   }
  33   _etext = .;
  34   PROVIDE (etext = .);
  35   .rodata    :
  36   {
  37     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  38   }
  39
  40   /* Read-write section, merged into data segment: */
  41   . = (. + 0x00FF) & 0xFFFFFF00;
  42   _erotext = .;
  43   PROVIDE (erotext = .);
  44   .reloc   :
  45   {
  46     _GOT2_TABLE_ = .;
  47     KEEP(*(.got2))
  48     KEEP(*(.got))
  49     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  50     _FIXUP_TABLE_ = .;
  51     KEEP(*(.fixup))
  52   }
  53   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  54   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  55
  56   .data    :
  57   {
  58     *(.data*)
  59     *(.sdata*)
  60   }
  61   _edata  =  .;
  62   PROVIDE (edata = .);
  63
  64   . = .;
  65
  66   . = ALIGN(4);
  67   .u_boot_list : {
  68         KEEP(*(SORT(.u_boot_list*)));
  69   }
  70
  71
  72   . = .;
  73   __start___ex_table = .;
  74   __ex_table : { *(__ex_table) }
  75   __stop___ex_table = .;
  76
  77   . = ALIGN(256);
  78   __init_begin = .;
  79   .text.init : { *(.text.init) }
  80   .data.init : { *(.data.init) }
  81   . = ALIGN(256);
  82   __init_end = .;
  83
  84   __bss_start = .;
  85   .bss (NOLOAD)       :
  86   {
  87    *(.bss*)
  88    *(.sbss*)
  89    *(COMMON)
  90    . = ALIGN(4);
  91   }
  92   __bss_end = . ;
  93   PROVIDE (end = .);
  94 }