arch/powerpc/cpu/mpc5xx/start.S

   1 /*
   2  *  Copyright (C) 1998  Dan Malek <dmalek@jlc.net>
   3  *  Copyright (C) 1999  Magnus Damm <kieraypc01.p.y.kie.era.ericsson.se>
   4  *  Copyright (C) 2000, 2001, 2002 Wolfgang Denk <wd@denx.de>
   5  *  Copyright (C) 2003  Martin Winistoerfer, martinwinistoerfer@gmx.ch.
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 /*
  11  * File:                start.S
  12  *
  13  * Discription:         startup code
  14  *
  15  */
  16
  17 #include <asm-offsets.h>
  18 #include <config.h>
  19 #include <mpc5xx.h>
  20 #include <version.h>
  21
  22 #define CONFIG_5xx 1            /* needed for Linux kernel header files */
  23
  24 #include <ppc_asm.tmpl>
  25 #include <ppc_defs.h>
  26
  27 #include <asm/processor.h>
  28 #include <asm/u-boot.h>
  29
  30 /* We don't have a MMU.
  31 */
  32 #undef  MSR_KERNEL
  33 #define MSR_KERNEL ( MSR_ME | MSR_RI )          /* Machine Check and Recoverable Interr. */
  34
  35 /*
  36  * Set up GOT: Global Offset Table
  37  *
  38  * Use r12 to access the GOT
  39  */
  40         START_GOT
  41         GOT_ENTRY(_GOT2_TABLE_)
  42         GOT_ENTRY(_FIXUP_TABLE_)
  43
  44         GOT_ENTRY(_start)
  45         GOT_ENTRY(_start_of_vectors)
  46         GOT_ENTRY(_end_of_vectors)
  47         GOT_ENTRY(transfer_to_handler)
  48
  49         GOT_ENTRY(__init_end)
  50         GOT_ENTRY(__bss_end)
  51         GOT_ENTRY(__bss_start)
  52         END_GOT
  53
  54 /*
  55  * r3 - 1st arg to board_init(): IMMP pointer
  56  * r4 - 2nd arg to board_init(): boot flag
  57  */
  58         .text
  59         .long   0x27051956                      /* U-Boot Magic Number */
  60         .globl  version_string
  61 version_string:
  62         .ascii U_BOOT_VERSION_STRING, "\0"
  63
  64         . = EXC_OFF_SYS_RESET
  65         .globl  _start
  66 _start:
  67         mfspr   r3, 638
  68         li      r4, CONFIG_SYS_ISB                      /* Set ISB bit */
  69         or      r3, r3, r4
  70         mtspr   638, r3
  71
  72         /* Initialize machine status; enable machine check interrupt            */
  73         /*----------------------------------------------------------------------*/
  74         li      r3, MSR_KERNEL                  /* Set ME, RI flags */
  75         mtmsr   r3
  76         mtspr   SRR1, r3                        /* Make SRR1 match MSR */
  77
  78         /* Initialize debug port registers                                      */
  79         /*----------------------------------------------------------------------*/
  80         xor     r0, r0, r0                      /* Clear R0 */
  81         mtspr   LCTRL1, r0                      /* Initialize debug port regs */
  82         mtspr   LCTRL2, r0
  83         mtspr   COUNTA, r0
  84         mtspr   COUNTB, r0
  85
  86 #if defined(CONFIG_PATI)
  87         /* the external flash access on PATI fails if programming the PLL to 40MHz.
  88          * Copy the PLL programming code to the internal RAM and execute it
  89          *----------------------------------------------------------------------*/
  90         lis     r3, CONFIG_SYS_MONITOR_BASE@h
  91         ori     r3, r3, CONFIG_SYS_MONITOR_BASE@l
  92         addi    r3, r3, pll_prog_code_start - _start + EXC_OFF_SYS_RESET
  93
  94         lis     r4, CONFIG_SYS_INIT_RAM_ADDR@h
  95         ori     r4, r4, CONFIG_SYS_INIT_RAM_ADDR@l
  96         mtlr    r4
  97         addis   r5,0,0x0
  98         ori     r5,r5,((pll_prog_code_end - pll_prog_code_start) >>2)
  99         mtctr   r5
 100         addi    r3, r3, -4
 101         addi    r4, r4, -4
 102 0:
 103         lwzu    r0,4(r3)
 104         stwu    r0,4(r4)
 105         bdnz    0b                /* copy loop */
 106         blrl
 107 #endif
 108
 109         /*
 110          * Calculate absolute address in FLASH and jump there
 111          *----------------------------------------------------------------------*/
 112
 113         lis     r3, CONFIG_SYS_MONITOR_BASE@h
 114         ori     r3, r3, CONFIG_SYS_MONITOR_BASE@l
 115         addi    r3, r3, in_flash - _start + EXC_OFF_SYS_RESET
 116         mtlr    r3
 117         blr
 118
 119 in_flash:
 120
 121         /* Initialize some SPRs that are hard to access from C                  */
 122         /*----------------------------------------------------------------------*/
 123
 124         lis     r3, CONFIG_SYS_IMMR@h                   /* Pass IMMR as arg1 to C routine */
 125         lis     r2, CONFIG_SYS_INIT_SP_ADDR@h
 126         ori     r1, r2, CONFIG_SYS_INIT_SP_ADDR@l       /* Set up the stack in internal SRAM */
 127         /* Note: R0 is still 0 here */
 128         stwu    r0, -4(r1)                      /* Clear final stack frame so that      */
 129         stwu    r0, -4(r1)                      /* stack backtraces terminate cleanly   */
 130
 131         /*
 132          * Disable serialized ifetch and show cycles
 133          * (i.e. set processor to normal mode) for maximum
 134          * performance.
 135          */
 136
 137         li      r2, 0x0007
 138         mtspr   ICTRL, r2
 139
 140         /* Set up debug mode entry */
 141
 142         lis     r2, CONFIG_SYS_DER@h
 143         ori     r2, r2, CONFIG_SYS_DER@l
 144         mtspr   DER, r2
 145
 146         /* Let the C-code set up the rest                                       */
 147         /*                                                                      */
 148         /* Be careful to keep code relocatable !                                */
 149         /*----------------------------------------------------------------------*/
 150
 151         GET_GOT                 /* initialize GOT access                        */
 152
 153         /* r3: IMMR */
 154         bl      cpu_init_f      /* run low-level CPU init code     (from Flash) */
 155
 156         bl      board_init_f    /* run 1st part of board init code (from Flash) */
 157
 158         /* NOTREACHED - board_init_f() does not return */
 159
 160
 161         .globl  _start_of_vectors
 162 _start_of_vectors:
 163
 164 /* Machine check */
 165         STD_EXCEPTION(0x200, MachineCheck, MachineCheckException)
 166
 167 /* Data Storage exception.  "Never" generated on the 860. */
 168         STD_EXCEPTION(0x300, DataStorage, UnknownException)
 169
 170 /* Instruction Storage exception.  "Never" generated on the 860. */
 171         STD_EXCEPTION(0x400, InstStorage, UnknownException)
 172
 173 /* External Interrupt exception. */
 174         STD_EXCEPTION(0x500, ExtInterrupt, external_interrupt)
 175
 176 /* Alignment exception. */
 177         . = 0x600
 178 Alignment:
 179         EXCEPTION_PROLOG(SRR0, SRR1)
 180         mfspr   r4,DAR
 181         stw     r4,_DAR(r21)
 182         mfspr   r5,DSISR
 183         stw     r5,_DSISR(r21)
 184         addi    r3,r1,STACK_FRAME_OVERHEAD
 185         EXC_XFER_TEMPLATE(Alignment, AlignmentException, MSR_KERNEL, COPY_EE)
 186
 187 /* Program check exception */
 188         . = 0x700
 189 ProgramCheck:
 190         EXCEPTION_PROLOG(SRR0, SRR1)
 191         addi    r3,r1,STACK_FRAME_OVERHEAD
 192         EXC_XFER_TEMPLATE(ProgramCheck, ProgramCheckException,
 193                 MSR_KERNEL, COPY_EE)
 194
 195         /* FPU on MPC5xx available. We will use it later.
 196         */
 197         STD_EXCEPTION(0x800, FPUnavailable, UnknownException)
 198
 199         /* I guess we could implement decrementer, and may have
 200          * to someday for timekeeping.
 201          */
 202         STD_EXCEPTION(0x900, Decrementer, timer_interrupt)
 203         STD_EXCEPTION(0xa00, Trap_0a, UnknownException)
 204         STD_EXCEPTION(0xb00, Trap_0b, UnknownException)
 205         STD_EXCEPTION(0xc00, SystemCall, UnknownException)
 206         STD_EXCEPTION(0xd00, SingleStep, UnknownException)
 207
 208         STD_EXCEPTION(0xe00, Trap_0e, UnknownException)
 209         STD_EXCEPTION(0xf00, Trap_0f, UnknownException)
 210
 211         /* On the MPC8xx, this is a software emulation interrupt.  It occurs
 212          * for all unimplemented and illegal instructions.
 213          */
 214         STD_EXCEPTION(0x1000, SoftEmu, SoftEmuException)
 215         STD_EXCEPTION(0x1100, InstructionTLBMiss, UnknownException)
 216         STD_EXCEPTION(0x1200, DataTLBMiss, UnknownException)
 217         STD_EXCEPTION(0x1300, InstructionTLBError, UnknownException)
 218         STD_EXCEPTION(0x1400, DataTLBError, UnknownException)
 219
 220         STD_EXCEPTION(0x1500, Reserved5, UnknownException)
 221         STD_EXCEPTION(0x1600, Reserved6, UnknownException)
 222         STD_EXCEPTION(0x1700, Reserved7, UnknownException)
 223         STD_EXCEPTION(0x1800, Reserved8, UnknownException)
 224         STD_EXCEPTION(0x1900, Reserved9, UnknownException)
 225         STD_EXCEPTION(0x1a00, ReservedA, UnknownException)
 226         STD_EXCEPTION(0x1b00, ReservedB, UnknownException)
 227
 228         STD_EXCEPTION(0x1c00, DataBreakpoint, UnknownException)
 229         STD_EXCEPTION(0x1d00, InstructionBreakpoint, DebugException)
 230         STD_EXCEPTION(0x1e00, PeripheralBreakpoint, UnknownException)
 231         STD_EXCEPTION(0x1f00, DevPortBreakpoint, UnknownException)
 232
 233
 234         .globl  _end_of_vectors
 235 _end_of_vectors:
 236
 237
 238         . = 0x2000
 239
 240 /*
 241  * This code finishes saving the registers to the exception frame
 242  * and jumps to the appropriate handler for the exception.
 243  * Register r21 is pointer into trap frame, r1 has new stack pointer.
 244  */
 245         .globl  transfer_to_handler
 246 transfer_to_handler:
 247         stw     r22,_NIP(r21)
 248         lis     r22,MSR_POW@h
 249         andc    r23,r23,r22
 250         stw     r23,_MSR(r21)
 251         SAVE_GPR(7, r21)
 252         SAVE_4GPRS(8, r21)
 253         SAVE_8GPRS(12, r21)
 254         SAVE_8GPRS(24, r21)
 255         mflr    r23
 256         andi.   r24,r23,0x3f00          /* get vector offset */
 257         stw     r24,TRAP(r21)
 258         li      r22,0
 259         stw     r22,RESULT(r21)
 260         mtspr   SPRG2,r22               /* r1 is now kernel sp */
 261         lwz     r24,0(r23)              /* virtual address of handler */
 262         lwz     r23,4(r23)              /* where to go when done */
 263         mtspr   SRR0,r24
 264         mtspr   SRR1,r20
 265         mtlr    r23
 266         SYNC
 267         rfi                             /* jump to handler, enable MMU */
 268
 269 int_return:
 270         mfmsr   r28                     /* Disable interrupts */
 271         li      r4,0
 272         ori     r4,r4,MSR_EE
 273         andc    r28,r28,r4
 274         SYNC                            /* Some chip revs need this... */
 275         mtmsr   r28
 276         SYNC
 277         lwz     r2,_CTR(r1)
 278         lwz     r0,_LINK(r1)
 279         mtctr   r2
 280         mtlr    r0
 281         lwz     r2,_XER(r1)
 282         lwz     r0,_CCR(r1)
 283         mtspr   XER,r2
 284         mtcrf   0xFF,r0
 285         REST_10GPRS(3, r1)
 286         REST_10GPRS(13, r1)
 287         REST_8GPRS(23, r1)
 288         REST_GPR(31, r1)
 289         lwz     r2,_NIP(r1)             /* Restore environment */
 290         lwz     r0,_MSR(r1)
 291         mtspr   SRR0,r2
 292         mtspr   SRR1,r0
 293         lwz     r0,GPR0(r1)
 294         lwz     r2,GPR2(r1)
 295         lwz     r1,GPR1(r1)
 296         SYNC
 297         rfi
 298
 299
 300 /*
 301  * unsigned int get_immr (unsigned int mask)
 302  *
 303  * return (mask ? (IMMR & mask) : IMMR);
 304  */
 305         .globl  get_immr
 306 get_immr:
 307         mr      r4,r3           /* save mask */
 308         mfspr   r3, IMMR        /* IMMR */
 309         cmpwi   0,r4,0          /* mask != 0 ? */
 310         beq     4f
 311         and     r3,r3,r4        /* IMMR & mask */
 312 4:
 313         blr
 314
 315         .globl get_pvr
 316 get_pvr:
 317         mfspr   r3, PVR
 318         blr
 319
 320
 321 /*------------------------------------------------------------------------------*/
 322
 323 /*
 324  * void relocate_code (addr_sp, gd, addr_moni)
 325  *
 326  * This "function" does not return, instead it continues in RAM
 327  * after relocating the monitor code.
 328  *
 329  * r3 = dest
 330  * r4 = src
 331  * r5 = length in bytes
 332  * r6 = cachelinesize
 333  */
 334         .globl  relocate_code
 335 relocate_code:
 336         mr      r1,  r3         /* Set new stack pointer in SRAM        */
 337         mr      r9,  r4         /* Save copy of global data pointer in SRAM */
 338         mr      r10, r5         /* Save copy of monitor destination Address in SRAM */
 339
 340         GET_GOT
 341         mr      r3,  r5                         /* Destination Address  */
 342         lis     r4, CONFIG_SYS_MONITOR_BASE@h           /* Source      Address  */
 343         ori     r4, r4, CONFIG_SYS_MONITOR_BASE@l
 344         lwz     r5, GOT(__init_end)
 345         sub     r5, r5, r4
 346
 347         /*
 348          * Fix GOT pointer:
 349          *
 350          * New GOT-PTR = (old GOT-PTR - CONFIG_SYS_MONITOR_BASE) + Destination Address
 351          *
 352          * Offset:
 353          */
 354         sub     r15, r10, r4
 355
 356         /* First our own GOT */
 357         add     r12, r12, r15
 358         /* the the one used by the C code */
 359         add     r30, r30, r15
 360
 361         /*
 362          * Now relocate code
 363          */
 364
 365         cmplw   cr1,r3,r4
 366         addi    r0,r5,3
 367         srwi.   r0,r0,2
 368         beq     cr1,4f          /* In place copy is not necessary       */
 369         beq     4f              /* Protect against 0 count              */
 370         mtctr   r0
 371         bge     cr1,2f
 372
 373         la      r8,-4(r4)
 374         la      r7,-4(r3)
 375 1:      lwzu    r0,4(r8)
 376         stwu    r0,4(r7)
 377         bdnz    1b
 378         b       4f
 379
 380 2:      slwi    r0,r0,2
 381         add     r8,r4,r0
 382         add     r7,r3,r0
 383 3:      lwzu    r0,-4(r8)
 384         stwu    r0,-4(r7)
 385         bdnz    3b
 386
 387 4:      sync
 388         isync
 389
 390 /*
 391  * We are done. Do not return, instead branch to second part of board
 392  * initialization, now running from RAM.
 393  */
 394
 395         addi    r0, r10, in_ram - _start + EXC_OFF_SYS_RESET
 396         mtlr    r0
 397         blr
 398
 399 in_ram:
 400
 401         /*
 402          * Relocation Function, r12 point to got2+0x8000
 403          *
 404          * Adjust got2 pointers, no need to check for 0, this code
 405          * already puts a few entries in the table.
 406          */
 407         li      r0,__got2_entries@sectoff@l
 408         la      r3,GOT(_GOT2_TABLE_)
 409         lwz     r11,GOT(_GOT2_TABLE_)
 410         mtctr   r0
 411         sub     r11,r3,r11
 412         addi    r3,r3,-4
 413 1:      lwzu    r0,4(r3)
 414         cmpwi   r0,0
 415         beq-    2f
 416         add     r0,r0,r11
 417         stw     r0,0(r3)
 418 2:      bdnz    1b
 419
 420         /*
 421          * Now adjust the fixups and the pointers to the fixups
 422          * in case we need to move ourselves again.
 423          */
 424         li      r0,__fixup_entries@sectoff@l
 425         lwz     r3,GOT(_FIXUP_TABLE_)
 426         cmpwi   r0,0
 427         mtctr   r0
 428         addi    r3,r3,-4
 429         beq     4f
 430 3:      lwzu    r4,4(r3)
 431         lwzux   r0,r4,r11
 432         cmpwi   r0,0
 433         add     r0,r0,r11
 434         stw     r4,0(r3)
 435         beq-    5f
 436         stw     r0,0(r4)
 437 5:      bdnz    3b
 438 4:
 439 clear_bss:
 440         /*
 441          * Now clear BSS segment
 442          */
 443         lwz     r3,GOT(__bss_start)
 444         lwz     r4,GOT(__bss_end)
 445         cmplw   0, r3, r4
 446         beq     6f
 447
 448         li      r0, 0
 449 5:
 450         stw     r0, 0(r3)
 451         addi    r3, r3, 4
 452         cmplw   0, r3, r4
 453         bne     5b
 454 6:
 455
 456         mr      r3, r9          /* Global Data pointer          */
 457         mr      r4, r10         /* Destination Address          */
 458         bl      board_init_r
 459
 460         /*
 461          * Copy exception vector code to low memory
 462          *
 463          * r3: dest_addr
 464          * r7: source address, r8: end address, r9: target address
 465          */
 466         .globl  trap_init
 467 trap_init:
 468         mflr    r4                      /* save link register           */
 469         GET_GOT
 470         lwz     r7, GOT(_start)
 471         lwz     r8, GOT(_end_of_vectors)
 472
 473         li      r9, 0x100               /* reset vector always at 0x100 */
 474
 475         cmplw   0, r7, r8
 476         bgelr                           /* return if r7>=r8 - just in case */
 477 1:
 478         lwz     r0, 0(r7)
 479         stw     r0, 0(r9)
 480         addi    r7, r7, 4
 481         addi    r9, r9, 4
 482         cmplw   0, r7, r8
 483         bne     1b
 484
 485         /*
 486          * relocate `hdlr' and `int_return' entries
 487          */
 488         li      r7, .L_MachineCheck - _start + EXC_OFF_SYS_RESET
 489         li      r8, Alignment - _start + EXC_OFF_SYS_RESET
 490 2:
 491         bl      trap_reloc
 492         addi    r7, r7, 0x100           /* next exception vector        */
 493         cmplw   0, r7, r8
 494         blt     2b
 495
 496         li      r7, .L_Alignment - _start + EXC_OFF_SYS_RESET
 497         bl      trap_reloc
 498
 499         li      r7, .L_ProgramCheck - _start + EXC_OFF_SYS_RESET
 500         bl      trap_reloc
 501
 502         li      r7, .L_FPUnavailable - _start + EXC_OFF_SYS_RESET
 503         li      r8, SystemCall - _start + EXC_OFF_SYS_RESET
 504 3:
 505         bl      trap_reloc
 506         addi    r7, r7, 0x100           /* next exception vector        */
 507         cmplw   0, r7, r8
 508         blt     3b
 509
 510         li      r7, .L_SingleStep - _start + EXC_OFF_SYS_RESET
 511         li      r8, _end_of_vectors - _start + EXC_OFF_SYS_RESET
 512 4:
 513         bl      trap_reloc
 514         addi    r7, r7, 0x100           /* next exception vector        */
 515         cmplw   0, r7, r8
 516         blt     4b
 517
 518         mtlr    r4                      /* restore link register        */
 519         blr
 520
 521 #if defined(CONFIG_PATI)
 522 /* Program the PLL */
 523 pll_prog_code_start:
 524         lis     r4, (CONFIG_SYS_IMMR + 0x002fc384)@h
 525         ori     r4, r4, (CONFIG_SYS_IMMR + 0x002fc384)@l
 526         lis     r3, (0x55ccaa33)@h
 527         ori     r3, r3, (0x55ccaa33)@l
 528         stw     r3, 0(r4)
 529         lis     r4, (CONFIG_SYS_IMMR + 0x002fc284)@h
 530         ori     r4, r4, (CONFIG_SYS_IMMR + 0x002fc284)@l
 531         lis     r3, CONFIG_SYS_PLPRCR@h
 532         ori     r3, r3, CONFIG_SYS_PLPRCR@l
 533         stw     r3, 0(r4)
 534         addis   r3,0,0x0
 535         ori     r3,r3,0xA000
 536         mtctr   r3
 537 ..spinlp:
 538   bdnz    ..spinlp                /* spin loop */
 539         blr
 540 pll_prog_code_end:
 541         nop
 542         blr
 543 #endif