arch/powerpc/cpu/mpc5xxx/u-boot-customlayout.lds

   1 /*
   2  * (C) Copyright 2003-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9
  10 SECTIONS
  11 {
  12   /* Read-only sections, merged into text segment: */
  13   .text      :
  14   {
  15     /* WARNING - the following is hand-optimized to fit within  */
  16     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  17
  18     arch/powerpc/cpu/mpc5xxx/start.o    (.text*)
  19     arch/powerpc/cpu/mpc5xxx/traps.o    (.text*)
  20
  21     . = DEFINED(env_offset) ? env_offset : .;
  22     common/env_embedded.o               (.ppcenv*)
  23
  24     *(.text*)
  25     . = ALIGN(16);
  26     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  27   }
  28
  29   /* Read-write section, merged into data segment: */
  30   . = (. + 0x0FFF) & 0xFFFFF000;
  31   _erotext = .;
  32   PROVIDE (erotext = .);
  33   .reloc   :
  34   {
  35     KEEP(*(.got))
  36     _GOT2_TABLE_ = .;
  37     KEEP(*(.got2))
  38     _FIXUP_TABLE_ = .;
  39     KEEP(*(.fixup))
  40   }
  41   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  42   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  43
  44   .data    :
  45   {
  46     *(.data*)
  47     *(.sdata*)
  48   }
  49   _edata  =  .;
  50   PROVIDE (edata = .);
  51
  52   . = .;
  53
  54   .u_boot_list : {
  55         KEEP(*(SORT(.u_boot_list*)));
  56   }
  57
  58   . = .;
  59   __start___ex_table = .;
  60   __ex_table : { *(__ex_table) }
  61   __stop___ex_table = .;
  62
  63   . = ALIGN(4096);
  64   __init_begin = .;
  65   .text.init : { *(.text.init) }
  66   .data.init : { *(.data.init) }
  67   . = ALIGN(4096);
  68   __init_end = .;
  69
  70   __bss_start = .;
  71   .bss (NOLOAD)       :
  72   {
  73    *(.bss*)
  74    *(.sbss*)
  75    *(COMMON)
  76    . = ALIGN(4);
  77   }
  78   __bss_end = . ;
  79   PROVIDE (end = .);
  80 }