board/amcc/kilauea/u-boot-nand.lds

   1 /*
   2  * (C) Copyright 2007
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9 SECTIONS
  10 {
  11   /* Read-only sections, merged into text segment: */
  12   . = + SIZEOF_HEADERS;
  13   .text      :
  14   {
  15     /* WARNING - the following is hand-optimized to fit within  */
  16     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  17
  18     arch/powerpc/cpu/ppc4xx/start.o     (.text*)
  19
  20     /* Align to next NAND block */
  21     . = ALIGN(0x4000);
  22     common/env_embedded.o  (.ppcenv)
  23     /* Keep some space here for redundant env and potential bad env blocks */
  24     . = ALIGN(0x10000);
  25
  26     *(.text*)
  27   }
  28   _etext = .;
  29   PROVIDE (etext = .);
  30   .rodata    :
  31   {
  32     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  33   }
  34
  35   /* Read-write section, merged into data segment: */
  36   . = (. + 0x00FF) & 0xFFFFFF00;
  37   _erotext = .;
  38   PROVIDE (erotext = .);
  39   .reloc   :
  40   {
  41     KEEP(*(.got))
  42     _GOT2_TABLE_ = .;
  43     KEEP(*(.got2))
  44     _FIXUP_TABLE_ = .;
  45     KEEP(*(.fixup))
  46   }
  47   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  48   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  49
  50   .data    :
  51   {
  52     *(.data*)
  53     *(.sdata*)
  54   }
  55   _edata  =  .;
  56   PROVIDE (edata = .);
  57
  58   . = .;
  59
  60   .u_boot_list : {
  61         KEEP(*(SORT(.u_boot_list*)));
  62   }
  63
  64   . = .;
  65   __start___ex_table = .;
  66   __ex_table : { *(__ex_table) }
  67   __stop___ex_table = .;
  68
  69   . = ALIGN(256);
  70   __init_begin = .;
  71   .text.init : { *(.text.init) }
  72   .data.init : { *(.data.init) }
  73   . = ALIGN(256);
  74   __init_end = .;
  75
  76   __bss_start = .;
  77   .bss (NOLOAD)       :
  78   {
  79    *(.bss*)
  80    *(.sbss*)
  81    *(COMMON)
  82    . = ALIGN(4);
  83   }
  84
  85   __bss_end = . ;
  86   PROVIDE (end = .);
  87 }