b4c7a0ed6e225f343b7fc53d2d20986cfcd53301
[karo-tx-uboot.git] / board / cogent / u-boot.lds
1 /*
2  * (C) Copyright 2000-2010
3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
4  *
5  * See file CREDITS for list of people who contributed to this
6  * project.
7  *
8  * This program is free software; you can redistribute it and/or
9  * modify it under the terms of the GNU General Public License as
10  * published by the Free Software Foundation; either version 2 of
11  * the License, or (at your option) any later version.
12  *
13  * This program is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, write to the Free Software
20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
21  * MA 02111-1307 USA
22  */
23
24 OUTPUT_ARCH(powerpc)
25
26 SECTIONS
27 {
28   /* Read-only sections, merged into text segment: */
29   . = + SIZEOF_HEADERS;
30   .text      :
31   {
32     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
33     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
34
35     *(.text*)
36   }
37   _etext = .;
38   PROVIDE (etext = .);
39   .rodata    :
40   {
41     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
42   }
43
44   /* Read-write section, merged into data segment: */
45   . = (. + 0x0FFF) & 0xFFFFF000;
46   _erotext = .;
47   PROVIDE (erotext = .);
48   .reloc   :
49   {
50     KEEP(*(.got))
51     _GOT2_TABLE_ = .;
52     KEEP(*(.got2))
53     _FIXUP_TABLE_ = .;
54     KEEP(*(.fixup))
55   }
56   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
57   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
58
59   .data    :
60   {
61     *(.data*)
62     *(.sdata*)
63   }
64   _edata  =  .;
65   PROVIDE (edata = .);
66
67   . = .;
68   __u_boot_cmd_start = .;
69   .u_boot_cmd : { *(.u_boot_cmd) }
70   __u_boot_cmd_end = .;
71
72
73   . = .;
74   __start___ex_table = .;
75   __ex_table : { *(__ex_table) }
76   __stop___ex_table = .;
77
78   . = ALIGN(4096);
79   __init_begin = .;
80   .text.init : { *(.text.init) }
81   .data.init : { *(.data.init) }
82   . = ALIGN(4096);
83   __init_end = .;
84
85   __bss_start = .;
86   .bss (NOLOAD)       :
87   {
88    *(.bss*)
89    *(.sbss*)
90    *(COMMON)
91    . = ALIGN(4);
92   }
93   _end = . ;
94   PROVIDE (end = .);
95 }