board/dave/PPChameleonEVB/u-boot.lds

   1 /*
   2  * Copyright 2007-2009 Freescale Semiconductor, Inc.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 #include "config.h"     /* CONFIG_BOARDDIR */
  24
  25 #ifndef RESET_VECTOR_ADDRESS
  26 #define RESET_VECTOR_ADDRESS    0xfffffffc
  27 #endif
  28
  29 OUTPUT_ARCH(powerpc)
  30
  31 PHDRS
  32 {
  33   text PT_LOAD;
  34   bss PT_LOAD;
  35 }
  36
  37 SECTIONS
  38 {
  39   /* Read-only sections, merged into text segment: */
  40   . = + SIZEOF_HEADERS;
  41   .text      :
  42   {
  43     *(.text*)
  44    } :text
  45     _etext = .;
  46     PROVIDE (etext = .);
  47     .rodata    :
  48    {
  49     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  50   } :text
  51
  52   /* Read-write section, merged into data segment: */
  53   . = (. + 0x00FF) & 0xFFFFFF00;
  54   _erotext = .;
  55   PROVIDE (erotext = .);
  56   .reloc   :
  57   {
  58     _GOT2_TABLE_ = .;
  59     KEEP(*(.got2))
  60     KEEP(*(.got))
  61     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  62     _FIXUP_TABLE_ = .;
  63     KEEP(*(.fixup))
  64   }
  65   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  66   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  67
  68   .data    :
  69   {
  70     *(.data*)
  71     *(.sdata*)
  72   }
  73   _edata  =  .;
  74   PROVIDE (edata = .);
  75
  76   . = .;
  77   __u_boot_cmd_start = .;
  78   .u_boot_cmd : { *(.u_boot_cmd) }
  79   __u_boot_cmd_end = .;
  80
  81   . = ALIGN(4);
  82   .u_boot_list : {
  83         #include <u-boot.lst>
  84   }
  85
  86   . = .;
  87   __start___ex_table = .;
  88   __ex_table : { *(__ex_table) }
  89   __stop___ex_table = .;
  90
  91   . = ALIGN(256);
  92   __init_begin = .;
  93   .text.init : { *(.text.init) }
  94   .data.init : { *(.data.init) }
  95   . = ALIGN(256);
  96   __init_end = .;
  97
  98   ppcenv_assert = ASSERT(. < 0xFFFF8000, ".bss section too big, overlaps .ppcenv section. Please update your confguration: CONFIG_SYS_MONITOR_BASE, CONFIG_SYS_MONITOR_LEN and CONFIG_SYS_TEXT_BASE may need to be modified.");
  99   . = 0xFFFF8000;
 100   .ppcenv :
 101   {
 102     common/env_embedded.o(.ppcenv);
 103   }
 104
 105   .resetvec RESET_VECTOR_ADDRESS :
 106   {
 107     KEEP(*(.resetvec))
 108   } :text = 0xffff
 109
 110   . = RESET_VECTOR_ADDRESS + 0x4;
 111
 112   /*
 113    * Make sure that the bss segment isn't linked at 0x0, otherwise its
 114    * address won't be updated during relocation fixups.  Note that
 115    * this is a temporary fix.  Code to dynamically the fixup the bss
 116    * location will be added in the future.  When the bss relocation
 117    * fixup code is present this workaround should be removed.
 118    */
 119 #if (RESET_VECTOR_ADDRESS == 0xfffffffc)
 120   . |= 0x10;
 121 #endif
 122
 123   __bss_start = .;
 124   .bss (NOLOAD)       :
 125   {
 126    *(.bss*)
 127    *(.sbss*)
 128    *(COMMON)
 129   } :bss
 130
 131   . = ALIGN(4);
 132   __bss_end__ = . ;
 133   PROVIDE (end = .);
 134 }