board/mousse/u-boot.lds.rom

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)               }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)               }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)                }
  42   .rela.got      : { *(.rela.got)               }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)                }
  48   .rela.bss      : { *(.rela.bss)               }
  49   .rel.plt       : { *(.rel.plt)                }
  50   .rela.plt      : { *(.rela.plt)               }
  51   .init          : { *(.init)   }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     cpu/mpc824x/start.o (.text)
  56          common/board.o (.text)
  57     lib_ppc/ppcstring.o (.text)
  58     lib_generic/vsprintf.o      (.text)
  59     lib_generic/crc32.o         (.text)
  60     lib_generic/zlib.o          (.text)
  61
  62                 . = env_offset;
  63     common/env_embedded.o (.text)
  64
  65                 *(.text)
  66
  67     *(.fixup)
  68     *(.got1)
  69     . = ALIGN(16);
  70     *(.rodata)
  71     *(.rodata1)
  72     *(.rodata.str1.4)
  73     *(.eh_frame)
  74   }
  75   .fini      : { *(.fini)    } =0
  76   .ctors     : { *(.ctors)   }
  77   .dtors     : { *(.dtors)   }
  78
  79   /* Read-write section, merged into data segment: */
  80   . = (. + 0x0FF) & 0xFFFFFF00;
  81   _erotext = .;
  82   PROVIDE (erotext = .);
  83   .reloc   :
  84   {
  85     *(.got)
  86     _GOT2_TABLE_ = .;
  87     *(.got2)
  88     _FIXUP_TABLE_ = .;
  89     *(.fixup)
  90   }
  91   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  92   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  93
  94   .data    :
  95   {
  96     *(.data)
  97     *(.data1)
  98     *(.sdata)
  99     *(.sdata2)
 100     *(.dynamic)
 101     CONSTRUCTORS
 102   }
 103   _edata  =  .;
 104   PROVIDE (edata = .);
 105
 106   __u_boot_cmd_start = .;
 107   .u_boot_cmd : { *(.u_boot_cmd) }
 108   __u_boot_cmd_end = .;
 109
 110   __start___ex_table = .;
 111   __ex_table : { *(__ex_table) }
 112   __stop___ex_table = .;
 113
 114   . = ALIGN(4096);
 115   __init_begin = .;
 116   .text.init : { *(.text.init) }
 117   .data.init : { *(.data.init) }
 118   . = ALIGN(4096);
 119   __init_end = .;
 120
 121   __bss_start = .;
 122   .bss       :
 123   {
 124    *(.sbss) *(.scommon)
 125    *(.dynbss)
 126    *(.bss)
 127    *(COMMON)
 128   }
 129
 130   _end = . ;
 131   PROVIDE (end = .);
 132 }