board/mousse/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   .text      :
  31   {
  32     arch/powerpc/cpu/mpc824x/start.o    (.text*)
  33     *(.text*)
  34     . = ALIGN(16);
  35     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  36   }
  37
  38   /* Read-write section, merged into data segment: */
  39   . = (. + 0x0FF) & 0xFFFFFF00;
  40   _erotext = .;
  41   PROVIDE (erotext = .);
  42   .reloc   :
  43   {
  44     _GOT2_TABLE_ = .;
  45     KEEP(*(.got2))
  46     KEEP(*(.got))
  47     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  48     _FIXUP_TABLE_ = .;
  49     KEEP(*(.fixup))
  50   }
  51   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  52   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  53
  54   .data    :
  55   {
  56     *(.data*)
  57     *(.sdata*)
  58   }
  59   _edata  =  .;
  60   PROVIDE (edata = .);
  61
  62   . = .;
  63
  64   . = ALIGN(4);
  65   .u_boot_list : {
  66         KEEP(*(SORT(.u_boot_list*)));
  67   }
  68
  69
  70   . = .;
  71   __start___ex_table = .;
  72   __ex_table : { *(__ex_table) }
  73   __stop___ex_table = .;
  74
  75   . = ALIGN(4096);
  76   __init_begin = .;
  77   .text.init : { *(.text.init) }
  78   .data.init : { *(.data.init) }
  79   . = ALIGN(4096);
  80   __init_end = .;
  81
  82   __bss_start = .;
  83   .bss (NOLOAD)       :
  84   {
  85    *(.bss*)
  86    *(.sbss*)
  87    *(COMMON)
  88    . = ALIGN(4);
  89   }
  90
  91   __bss_end = . ;
  92   PROVIDE (end = .);
  93 }