board/mvs1/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)       }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)       }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)        }
  42   .rela.got      : { *(.rela.got)       }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)        }
  48   .rela.bss      : { *(.rela.bss)       }
  49   .rel.plt       : { *(.rel.plt)        }
  50   .rela.plt      : { *(.rela.plt)       }
  51   .init          : { *(.init)           }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     /* WARNING - the following is hand-optimized to fit within  */
  56     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  57
  58     cpu/mpc8xx/start.o          (.text)
  59     common/dlmalloc.o           (.text)
  60     lib_ppc/ppcstring.o         (.text)
  61     lib_generic/vsprintf.o      (.text)
  62     lib_generic/crc32.o         (.text)
  63     lib_generic/zlib.o          (.text)
  64     lib_generic/ctype.o         (.text)
  65     lib_generic/string.o        (.text)
  66     lib_ppc/extable.o           (.text)
  67     lib_ppc/kgdb.o              (.text)
  68
  69   . = env_offset;
  70     common/environment.o(.text)
  71
  72     *(.text)
  73     *(.fixup)
  74     *(.got1)
  75   }
  76   _etext = .;
  77   PROVIDE (etext = .);
  78   .rodata    :
  79   {
  80     *(.rodata)
  81     *(.rodata1)
  82     *(.rodata.str1.4)
  83     *(.eh_frame)
  84   }
  85   .fini      : { *(.fini)    } =0
  86   .ctors     : { *(.ctors)   }
  87   .dtors     : { *(.dtors)   }
  88
  89   /* Read-write section, merged into data segment: */
  90   . = (. + 0x00FF) & 0xFFFFFF00;
  91   _erotext = .;
  92   PROVIDE (erotext = .);
  93   .reloc   :
  94   {
  95     *(.got)
  96     _GOT2_TABLE_ = .;
  97     *(.got2)
  98     _FIXUP_TABLE_ = .;
  99     *(.fixup)
 100   }
 101   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 102   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 103
 104   .data    :
 105   {
 106     *(.data)
 107     *(.data1)
 108     *(.sdata)
 109     *(.sdata2)
 110     *(.dynamic)
 111     CONSTRUCTORS
 112   }
 113   _edata  =  .;
 114   PROVIDE (edata = .);
 115
 116   . = .;
 117   __u_boot_cmd_start = .;
 118   .u_boot_cmd : { *(.u_boot_cmd) }
 119   __u_boot_cmd_end = .;
 120
 121
 122   . = .;
 123   __start___ex_table = .;
 124   __ex_table : { *(__ex_table) }
 125   __stop___ex_table = .;
 126
 127   . = ALIGN(256);
 128   __init_begin = .;
 129   .text.init : { *(.text.init) }
 130   .data.init : { *(.data.init) }
 131   . = ALIGN(256);
 132   __init_end = .;
 133
 134   __bss_start = .;
 135   .bss (NOLOAD)       :
 136   {
 137    *(.sbss) *(.scommon)
 138    *(.dynbss)
 139    *(.bss)
 140    *(COMMON)
 141   }
 142   _end = . ;
 143   PROVIDE (end = .);
 144 }