board/freescale/mpc8548cds/u-boot.lds

   1 /*
   2  * Copyright 2004, 2007-2008 Freescale Semiconductor, Inc.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 OUTPUT_ARCH(powerpc)
  24 /* Do we need any of these for elf?
  25    __DYNAMIC = 0;    */
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .interp : { *(.interp) }
  31   .hash          : { *(.hash)           }
  32   .dynsym        : { *(.dynsym)         }
  33   .dynstr        : { *(.dynstr)         }
  34   .rel.text      : { *(.rel.text)               }
  35   .rela.text     : { *(.rela.text)      }
  36   .rel.data      : { *(.rel.data)               }
  37   .rela.data     : { *(.rela.data)      }
  38   .rel.rodata    : { *(.rel.rodata)     }
  39   .rela.rodata   : { *(.rela.rodata)    }
  40   .rel.got       : { *(.rel.got)                }
  41   .rela.got      : { *(.rela.got)               }
  42   .rel.ctors     : { *(.rel.ctors)      }
  43   .rela.ctors    : { *(.rela.ctors)     }
  44   .rel.dtors     : { *(.rel.dtors)      }
  45   .rela.dtors    : { *(.rela.dtors)     }
  46   .rel.bss       : { *(.rel.bss)                }
  47   .rela.bss      : { *(.rela.bss)               }
  48   .rel.plt       : { *(.rel.plt)                }
  49   .rela.plt      : { *(.rela.plt)               }
  50   .init          : { *(.init)   }
  51   .plt : { *(.plt) }
  52   .text      :
  53   {
  54     *(.text)
  55     *(.fixup)
  56     *(.got1)
  57    }
  58     _etext = .;
  59     PROVIDE (etext = .);
  60     .rodata    :
  61    {
  62     *(.rodata)
  63     *(.rodata1)
  64     *(.rodata.str1.4)
  65     *(.eh_frame)
  66   }
  67   .fini      : { *(.fini)    } =0
  68   .ctors     : { *(.ctors)   }
  69   .dtors     : { *(.dtors)   }
  70
  71   /* Read-write section, merged into data segment: */
  72   . = (. + 0x00FF) & 0xFFFFFF00;
  73   _erotext = .;
  74   PROVIDE (erotext = .);
  75   .reloc   :
  76   {
  77     *(.got)
  78     _GOT2_TABLE_ = .;
  79     *(.got2)
  80     _FIXUP_TABLE_ = .;
  81     *(.fixup)
  82   }
  83   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  84   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  85
  86   .data    :
  87   {
  88     *(.data)
  89     *(.data1)
  90     *(.sdata)
  91     *(.sdata2)
  92     *(.dynamic)
  93     CONSTRUCTORS
  94   }
  95   _edata  =  .;
  96   PROVIDE (edata = .);
  97
  98   . = .;
  99   __u_boot_cmd_start = .;
 100   .u_boot_cmd : { *(.u_boot_cmd) }
 101   __u_boot_cmd_end = .;
 102
 103   . = .;
 104   __start___ex_table = .;
 105   __ex_table : { *(__ex_table) }
 106   __stop___ex_table = .;
 107
 108   . = ALIGN(256);
 109   __init_begin = .;
 110   .text.init : { *(.text.init) }
 111   .data.init : { *(.data.init) }
 112   . = ALIGN(256);
 113   __init_end = .;
 114
 115   .bootpg ADDR(.text) + 0x7f000 :
 116   {
 117     cpu/mpc85xx/start.o (.bootpg)
 118   } = 0xffff
 119
 120   .resetvec ADDR(.text) + 0x7fffc :
 121   {
 122     *(.resetvec)
 123   } = 0xffff
 124
 125   . = ADDR(.text) + 0x80000;
 126
 127   __bss_start = .;
 128   .bss (NOLOAD)       :
 129   {
 130    *(.sbss) *(.scommon)
 131    *(.dynbss)
 132    *(.bss)
 133    *(COMMON)
 134   }
 135
 136   . = ALIGN(4);
 137   _end = . ;
 138   PROVIDE (end = .);
 139 }