arch/powerpc/kernel/vdso64/vdso64.lds.S

   1 /*
   2  * This is the infamous ld script for the 64 bits vdso
   3  * library
   4  */
   5 #include <asm/vdso.h>
   6
   7 OUTPUT_FORMAT("elf64-powerpc", "elf64-powerpc", "elf64-powerpc")
   8 OUTPUT_ARCH(powerpc:common64)
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13   . = VDSO64_LBASE + SIZEOF_HEADERS;
  14   .hash           : { *(.hash) }                :text
  15   .dynsym         : { *(.dynsym) }
  16   .dynstr         : { *(.dynstr) }
  17   .gnu.version    : { *(.gnu.version) }
  18   .gnu.version_d  : { *(.gnu.version_d) }
  19   .gnu.version_r  : { *(.gnu.version_r) }
  20
  21   .note           : { *(.note.*) }              :text   :note
  22
  23   . = ALIGN (16);
  24   .text           :
  25   {
  26     *(.text .stub .text.* .gnu.linkonce.t.*)
  27     *(.sfpr .glink)
  28   }                                             :text
  29   PROVIDE (__etext = .);
  30   PROVIDE (_etext = .);
  31   PROVIDE (etext = .);
  32
  33   /* Other stuff is appended to the text segment: */
  34   .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  35   .rodata1        : { *(.rodata1) }
  36   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text   :eh_frame_hdr
  37   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
  38   .gcc_except_table   : { *(.gcc_except_table) }
  39
  40   .opd           ALIGN(8) : { KEEP (*(.opd)) }
  41   .got           ALIGN(8) : { *(.got .toc) }
  42   .rela.dyn      ALIGN(8) : { *(.rela.dyn) }
  43
  44   .dynamic        : { *(.dynamic) }             :text   :dynamic
  45
  46   _end = .;
  47   PROVIDE (end = .);
  48
  49   /* Stabs debugging sections are here too
  50    */
  51   .stab          0 : { *(.stab) }
  52   .stabstr       0 : { *(.stabstr) }
  53   .stab.excl     0 : { *(.stab.excl) }
  54   .stab.exclstr  0 : { *(.stab.exclstr) }
  55   .stab.index    0 : { *(.stab.index) }
  56   .stab.indexstr 0 : { *(.stab.indexstr) }
  57   .comment       0 : { *(.comment) }
  58   /* DWARF debug sectio/ns.
  59      Symbols in the DWARF debugging sections are relative to the beginning
  60      of the section so we begin them at 0.  */
  61   /* DWARF 1 */
  62   .debug          0 : { *(.debug) }
  63   .line           0 : { *(.line) }
  64   /* GNU DWARF 1 extensions */
  65   .debug_srcinfo  0 : { *(.debug_srcinfo) }
  66   .debug_sfnames  0 : { *(.debug_sfnames) }
  67   /* DWARF 1.1 and DWARF 2 */
  68   .debug_aranges  0 : { *(.debug_aranges) }
  69   .debug_pubnames 0 : { *(.debug_pubnames) }
  70   /* DWARF 2 */
  71   .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  72   .debug_abbrev   0 : { *(.debug_abbrev) }
  73   .debug_line     0 : { *(.debug_line) }
  74   .debug_frame    0 : { *(.debug_frame) }
  75   .debug_str      0 : { *(.debug_str) }
  76   .debug_loc      0 : { *(.debug_loc) }
  77   .debug_macinfo  0 : { *(.debug_macinfo) }
  78   /* SGI/MIPS DWARF 2 extensions */
  79   .debug_weaknames 0 : { *(.debug_weaknames) }
  80   .debug_funcnames 0 : { *(.debug_funcnames) }
  81   .debug_typenames 0 : { *(.debug_typenames) }
  82   .debug_varnames  0 : { *(.debug_varnames) }
  83
  84   /DISCARD/ : { *(.note.GNU-stack) }
  85   /DISCARD/ : { *(.branch_lt) }
  86   /DISCARD/ : { *(.data .data.* .gnu.linkonce.d.*) }
  87   /DISCARD/ : { *(.bss .sbss .dynbss .dynsbss) }
  88 }
  89
  90 PHDRS
  91 {
  92   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  93   note PT_NOTE FLAGS(4); /* PF_R */
  94   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  95   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  96 }
  97
  98 /*
  99  * This controls what symbols we export from the DSO.
 100  */
 101 VERSION
 102 {
 103   VDSO_VERSION_STRING {
 104     global:
 105         __kernel_datapage_offset; /* Has to be there for the kernel to find */
 106         __kernel_get_syscall_map;
 107         __kernel_gettimeofday;
 108         __kernel_clock_gettime;
 109         __kernel_clock_getres;
 110         __kernel_get_tbfreq;
 111         __kernel_sync_dicache;
 112         __kernel_sync_dicache_p5;
 113         __kernel_sigtramp_rt64;
 114     local: *;
 115   };
 116 }