tools/perf/util/parse-events.l

   1
   2 %option reentrant
   3 %option bison-bridge
   4 %option prefix="parse_events_"
   5 %option stack
   6 %option bison-locations
   7 %option yylineno
   8
   9 %{
  10 #include <errno.h>
  11 #include "../perf.h"
  12 #include "parse-events-bison.h"
  13 #include "parse-events.h"
  14
  15 char *parse_events_get_text(yyscan_t yyscanner);
  16 YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
  17
  18 static int __value(YYSTYPE *yylval, char *str, int base, int token)
  19 {
  20         u64 num;
  21
  22         errno = 0;
  23         num = strtoull(str, NULL, base);
  24         if (errno)
  25                 return PE_ERROR;
  26
  27         yylval->num = num;
  28         return token;
  29 }
  30
  31 static int value(yyscan_t scanner, int base)
  32 {
  33         YYSTYPE *yylval = parse_events_get_lval(scanner);
  34         char *text = parse_events_get_text(scanner);
  35
  36         return __value(yylval, text, base, PE_VALUE);
  37 }
  38
  39 static int raw(yyscan_t scanner)
  40 {
  41         YYSTYPE *yylval = parse_events_get_lval(scanner);
  42         char *text = parse_events_get_text(scanner);
  43
  44         return __value(yylval, text + 1, 16, PE_RAW);
  45 }
  46
  47 static int str(yyscan_t scanner, int token)
  48 {
  49         YYSTYPE *yylval = parse_events_get_lval(scanner);
  50         char *text = parse_events_get_text(scanner);
  51
  52         yylval->str = strdup(text);
  53         return token;
  54 }
  55
  56 #define REWIND(__alloc)                         \
  57 do {                                                            \
  58         YYSTYPE *__yylval = parse_events_get_lval(yyscanner);   \
  59         char *text = parse_events_get_text(yyscanner);          \
  60                                                                 \
  61         if (__alloc)                                            \
  62                 __yylval->str = strdup(text);                   \
  63                                                                 \
  64         yycolumn -= strlen(text);                               \
  65         yyless(0);                                              \
  66 } while (0)
  67
  68 static int pmu_str_check(yyscan_t scanner)
  69 {
  70         YYSTYPE *yylval = parse_events_get_lval(scanner);
  71         char *text = parse_events_get_text(scanner);
  72
  73         yylval->str = strdup(text);
  74         switch (perf_pmu__parse_check(text)) {
  75                 case PMU_EVENT_SYMBOL_PREFIX:
  76                         return PE_PMU_EVENT_PRE;
  77                 case PMU_EVENT_SYMBOL_SUFFIX:
  78                         return PE_PMU_EVENT_SUF;
  79                 case PMU_EVENT_SYMBOL:
  80                         return PE_KERNEL_PMU_EVENT;
  81                 default:
  82                         return PE_NAME;
  83         }
  84 }
  85
  86 static int sym(yyscan_t scanner, int type, int config)
  87 {
  88         YYSTYPE *yylval = parse_events_get_lval(scanner);
  89
  90         yylval->num = (type << 16) + config;
  91         return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
  92 }
  93
  94 static int term(yyscan_t scanner, int type)
  95 {
  96         YYSTYPE *yylval = parse_events_get_lval(scanner);
  97
  98         yylval->num = type;
  99         return PE_TERM;
 100 }
 101
 102 #define YY_USER_ACTION                                  \
 103 do {                                                    \
 104         yylloc->last_column  = yylloc->first_column;    \
 105         yylloc->first_column = yycolumn;                \
 106         yycolumn += yyleng;                             \
 107 } while (0);
 108
 109 %}
 110
 111 %x mem
 112 %s config
 113 %x event
 114
 115 group           [^,{}/]*[{][^}]*[}][^,{}/]*
 116 event_pmu       [^,{}/]+[/][^/]*[/][^,{}/]*
 117 event           [^,{}/]+
 118
 119 num_dec         [0-9]+
 120 num_hex         0x[a-fA-F0-9]+
 121 num_raw_hex     [a-fA-F0-9]+
 122 name            [a-zA-Z_*?][a-zA-Z0-9_*?.]*
 123 name_minus      [a-zA-Z_*?][a-zA-Z0-9\-_*?.]*
 124 /* If you add a modifier you need to update check_modifier() */
 125 modifier_event  [ukhpGHSDI]+
 126 modifier_bp     [rwx]{1,3}
 127
 128 %%
 129
 130 %{
 131         {
 132                 int start_token;
 133
 134                 start_token = parse_events_get_extra(yyscanner);
 135
 136                 if (start_token == PE_START_TERMS)
 137                         BEGIN(config);
 138                 else if (start_token == PE_START_EVENTS)
 139                         BEGIN(event);
 140
 141                 if (start_token) {
 142                         parse_events_set_extra(NULL, yyscanner);
 143                         /*
 144                          * The flex parser does not init locations variable
 145                          * via the scan_string interface, so we need do the
 146                          * init in here.
 147                          */
 148                         yycolumn = 0;
 149                         return start_token;
 150                 }
 151          }
 152 %}
 153
 154 <event>{
 155
 156 {group}         {
 157                         BEGIN(INITIAL);
 158                         REWIND(0);
 159                 }
 160
 161 {event_pmu}     |
 162 {event}         {
 163                         BEGIN(INITIAL);
 164                         REWIND(1);
 165                         return PE_EVENT_NAME;
 166                 }
 167
 168 <<EOF>>         {
 169                         BEGIN(INITIAL);
 170                         REWIND(0);
 171                 }
 172
 173 }
 174
 175 <config>{
 176         /*
 177          * Please update parse_events_formats_error_string any time
 178          * new static term is added.
 179          */
 180 config                  { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
 181 config1                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
 182 config2                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
 183 name                    { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
 184 period                  { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
 185 freq                    { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
 186 branch_type             { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
 187 time                    { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
 188 call-graph              { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
 189 stack-size              { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
 190 ,                       { return ','; }
 191 "/"                     { BEGIN(INITIAL); return '/'; }
 192 {name_minus}            { return str(yyscanner, PE_NAME); }
 193 }
 194
 195 <mem>{
 196 {modifier_bp}           { return str(yyscanner, PE_MODIFIER_BP); }
 197 :                       { return ':'; }
 198 "/"                     { return '/'; }
 199 {num_dec}               { return value(yyscanner, 10); }
 200 {num_hex}               { return value(yyscanner, 16); }
 201         /*
 202          * We need to separate 'mem:' scanner part, in order to get specific
 203          * modifier bits parsed out. Otherwise we would need to handle PE_NAME
 204          * and we'd need to parse it manually. During the escape from <mem>
 205          * state we need to put the escaping char back, so we dont miss it.
 206          */
 207 .                       { unput(*yytext); BEGIN(INITIAL); }
 208         /*
 209          * We destroy the scanner after reaching EOF,
 210          * but anyway just to be sure get back to INIT state.
 211          */
 212 <<EOF>>                 { BEGIN(INITIAL); }
 213 }
 214
 215 cpu-cycles|cycles                               { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
 216 stalled-cycles-frontend|idle-cycles-frontend    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
 217 stalled-cycles-backend|idle-cycles-backend      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
 218 instructions                                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
 219 cache-references                                { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
 220 cache-misses                                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
 221 branch-instructions|branches                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
 222 branch-misses                                   { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
 223 bus-cycles                                      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
 224 ref-cycles                                      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
 225 cpu-clock                                       { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
 226 task-clock                                      { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
 227 page-faults|faults                              { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
 228 minor-faults                                    { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
 229 major-faults                                    { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
 230 context-switches|cs                             { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
 231 cpu-migrations|migrations                       { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
 232 alignment-faults                                { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
 233 emulation-faults                                { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
 234 dummy                                           { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
 235
 236         /*
 237          * We have to handle the kernel PMU event cycles-ct/cycles-t/mem-loads/mem-stores separately.
 238          * Because the prefix cycles is mixed up with cpu-cycles.
 239          * loads and stores are mixed up with cache event
 240          */
 241 cycles-ct                                       { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
 242 cycles-t                                        { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
 243 mem-loads                                       { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
 244 mem-stores                                      { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
 245
 246 L1-dcache|l1-d|l1d|L1-data              |
 247 L1-icache|l1-i|l1i|L1-instruction       |
 248 LLC|L2                                  |
 249 dTLB|d-tlb|Data-TLB                     |
 250 iTLB|i-tlb|Instruction-TLB              |
 251 branch|branches|bpu|btb|bpc             |
 252 node                                    { return str(yyscanner, PE_NAME_CACHE_TYPE); }
 253
 254 load|loads|read                         |
 255 store|stores|write                      |
 256 prefetch|prefetches                     |
 257 speculative-read|speculative-load       |
 258 refs|Reference|ops|access               |
 259 misses|miss                             { return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }
 260
 261 mem:                    { BEGIN(mem); return PE_PREFIX_MEM; }
 262 r{num_raw_hex}          { return raw(yyscanner); }
 263 {num_dec}               { return value(yyscanner, 10); }
 264 {num_hex}               { return value(yyscanner, 16); }
 265
 266 {modifier_event}        { return str(yyscanner, PE_MODIFIER_EVENT); }
 267 {name}                  { return pmu_str_check(yyscanner); }
 268 "/"                     { BEGIN(config); return '/'; }
 269 -                       { return '-'; }
 270 ,                       { BEGIN(event); return ','; }
 271 :                       { return ':'; }
 272 "{"                     { BEGIN(event); return '{'; }
 273 "}"                     { return '}'; }
 274 =                       { return '='; }
 275 \n                      { }
 276 .                       { }
 277
 278 %%
 279
 280 int parse_events_wrap(void *scanner __maybe_unused)
 281 {
 282         return 1;
 283 }