arch/arm/cpu/arm1136/start.S

   1 /*
   2  *  armboot - Startup Code for OMP2420/ARM1136 CPU-core
   3  *
   4  *  Copyright (c) 2004  Texas Instruments <r-woodruff2@ti.com>
   5  *
   6  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   7  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   8  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
   9  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  10  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  11  *
  12  * See file CREDITS for list of people who contributed to this
  13  * project.
  14  *
  15  * This program is free software; you can redistribute it and/or
  16  * modify it under the terms of the GNU General Public License as
  17  * published by the Free Software Foundation; either version 2 of
  18  * the License, or (at your option) any later version.
  19  *
  20  * This program is distributed in the hope that it will be useful,
  21  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  22  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23  * GNU General Public License for more details.
  24  *
  25  * You should have received a copy of the GNU General Public License
  26  * along with this program; if not, write to the Free Software
  27  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  28  * MA 02111-1307 USA
  29  */
  30
  31 #include <asm-offsets.h>
  32 #include <config.h>
  33 #include <version.h>
  34 .globl _start
  35 _start: b       reset
  36 #ifdef CONFIG_PRELOADER
  37         ldr     pc, _hang
  38         ldr     pc, _hang
  39         ldr     pc, _hang
  40         ldr     pc, _hang
  41         ldr     pc, _hang
  42         ldr     pc, _hang
  43         ldr     pc, _hang
  44
  45 _hang:
  46         .word   do_hang
  47         .word   0x12345678
  48         .word   0x12345678
  49         .word   0x12345678
  50         .word   0x12345678
  51         .word   0x12345678
  52         .word   0x12345678
  53         .word   0x12345678      /* now 16*4=64 */
  54 #else
  55         ldr     pc, _undefined_instruction
  56         ldr     pc, _software_interrupt
  57         ldr     pc, _prefetch_abort
  58         ldr     pc, _data_abort
  59         ldr     pc, _not_used
  60         ldr     pc, _irq
  61         ldr     pc, _fiq
  62
  63 _undefined_instruction: .word undefined_instruction
  64 _software_interrupt:    .word software_interrupt
  65 _prefetch_abort:        .word prefetch_abort
  66 _data_abort:            .word data_abort
  67 _not_used:              .word not_used
  68 _irq:                   .word irq
  69 _fiq:                   .word fiq
  70 _pad:                   .word 0x12345678 /* now 16*4=64 */
  71 #endif  /* CONFIG_PRELOADER */
  72 .global _end_vect
  73 _end_vect:
  74
  75         .balignl 16,0xdeadbeef
  76 /*
  77  *************************************************************************
  78  *
  79  * Startup Code (reset vector)
  80  *
  81  * do important init only if we don't start from memory!
  82  * setup Memory and board specific bits prior to relocation.
  83  * relocate armboot to ram
  84  * setup stack
  85  *
  86  *************************************************************************
  87  */
  88
  89 .globl _TEXT_BASE
  90 _TEXT_BASE:
  91         .word   CONFIG_SYS_TEXT_BASE
  92
  93 /*
  94  * These are defined in the board-specific linker script.
  95  * Subtracting _start from them lets the linker put their
  96  * relative position in the executable instead of leaving
  97  * them null.
  98  */
  99 .globl _bss_start_ofs
 100 _bss_start_ofs:
 101         .word __bss_start - _start
 102
 103 .globl _bss_end_ofs
 104 _bss_end_ofs:
 105         .word _end - _start
 106
 107 .globl _datarel_start_ofs
 108 _datarel_start_ofs:
 109         .word __datarel_start - _start
 110
 111 .globl _datarelrolocal_start_ofs
 112 _datarelrolocal_start_ofs:
 113         .word __datarelrolocal_start - _start
 114
 115 .globl _datarellocal_start_ofs
 116 _datarellocal_start_ofs:
 117         .word __datarellocal_start - _start
 118
 119 .globl _datarelro_start_ofs
 120 _datarelro_start_ofs:
 121         .word __datarelro_start - _start
 122
 123 #ifdef CONFIG_USE_IRQ
 124 /* IRQ stack memory (calculated at run-time) */
 125 .globl IRQ_STACK_START
 126 IRQ_STACK_START:
 127         .word   0x0badc0de
 128
 129 /* IRQ stack memory (calculated at run-time) */
 130 .globl FIQ_STACK_START
 131 FIQ_STACK_START:
 132         .word 0x0badc0de
 133 #endif
 134
 135 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 136 .globl IRQ_STACK_START_IN
 137 IRQ_STACK_START_IN:
 138         .word   0x0badc0de
 139
 140 /*
 141  * the actual reset code
 142  */
 143
 144 reset:
 145         /*
 146          * set the cpu to SVC32 mode
 147          */
 148         mrs     r0,cpsr
 149         bic     r0,r0,#0x1f
 150         orr     r0,r0,#0xd3
 151         msr     cpsr,r0
 152
 153 #ifdef CONFIG_OMAP2420H4
 154        /* Copy vectors to mask ROM indirect addr */
 155         adr     r0, _start              /* r0 <- current position of code   */
 156                 add     r0, r0, #4                              /* skip reset vector                    */
 157         mov     r2, #64                 /* r2 <- size to copy  */
 158         add     r2, r0, r2              /* r2 <- source end address         */
 159         mov     r1, #SRAM_OFFSET0         /* build vect addr */
 160         mov     r3, #SRAM_OFFSET1
 161         add     r1, r1, r3
 162         mov     r3, #SRAM_OFFSET2
 163         add     r1, r1, r3
 164 next:
 165         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 166         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 167         cmp     r0, r2                  /* until source end address [r2]    */
 168         bne     next                    /* loop until equal */
 169         bl      cpy_clk_code            /* put dpll adjust code behind vectors */
 170 #endif
 171         /* the mask ROM code should have PLL and others stable */
 172 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 173         bl  cpu_init_crit
 174 #endif
 175
 176 /* Set stackpointer in internal RAM to call board_init_f */
 177 call_board_init_f:
 178         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 179         ldr     r0,=0x00000000
 180
 181 #ifdef CONFIG_NAND_SPL
 182         bl      nand_boot
 183 #else
 184 #ifdef CONFIG_ONENAND_IPL
 185         bl      start_oneboot
 186 #else
 187         bl      board_init_f
 188 #endif /* CONFIG_ONENAND_IPL */
 189 #endif /* CONFIG_NAND_SPL */
 190
 191 /*------------------------------------------------------------------------------*/
 192
 193 /*
 194  * void relocate_code (addr_sp, gd, addr_moni)
 195  *
 196  * This "function" does not return, instead it continues in RAM
 197  * after relocating the monitor code.
 198  *
 199  */
 200         .globl  relocate_code
 201 relocate_code:
 202         mov     r4, r0  /* save addr_sp */
 203         mov     r5, r1  /* save addr of gd */
 204         mov     r6, r2  /* save addr of destination */
 205         mov     r7, r2  /* save addr of destination */
 206
 207         /* Set up the stack                                                 */
 208 stack_setup:
 209         mov     sp, r4
 210
 211         adr     r0, _start
 212         ldr     r2, _TEXT_BASE
 213         ldr     r3, _bss_start_ofs
 214         add     r2, r0, r3              /* r2 <- source end address         */
 215         cmp     r0, r6
 216         beq     clear_bss
 217
 218 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 219 copy_loop:
 220         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 221         stmia   r6!, {r9-r10}           /* copy to   target address [r1]    */
 222         cmp     r0, r2                  /* until source end address [r2]    */
 223         blo     copy_loop
 224
 225 #ifndef CONFIG_PRELOADER
 226         /*
 227          * fix .rel.dyn relocations
 228          */
 229         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 230         sub     r9, r7, r0              /* r9 <- relocation offset */
 231         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 232         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 233         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 234         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 235         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 236         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 237 fixloop:
 238         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 239         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 240         ldr     r1, [r2, #4]
 241         and     r8, r1, #0xff
 242         cmp     r8, #23                 /* relative fixup? */
 243         beq     fixrel
 244         cmp     r8, #2                  /* absolute fixup? */
 245         beq     fixabs
 246         /* ignore unknown type of fixup */
 247         b       fixnext
 248 fixabs:
 249         /* absolute fix: set location to (offset) symbol value */
 250         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 251         add     r1, r10, r1             /* r1 <- address of symbol in table */
 252         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 253         add     r1, r9                  /* r1 <- relocated sym addr */
 254         b       fixnext
 255 fixrel:
 256         /* relative fix: increase location by offset */
 257         ldr     r1, [r0]
 258         add     r1, r1, r9
 259 fixnext:
 260         str     r1, [r0]
 261         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 262         cmp     r2, r3
 263         blo     fixloop
 264 #endif
 265 #endif  /* #ifndef CONFIG_SKIP_RELOCATE_UBOOT */
 266
 267 clear_bss:
 268 #ifndef CONFIG_PRELOADER
 269         ldr     r0, _bss_start_ofs
 270         ldr     r1, _bss_end_ofs
 271         ldr     r3, _TEXT_BASE          /* Text base */
 272         mov     r4, r7                  /* reloc addr */
 273         add     r0, r0, r4
 274         add     r1, r1, r4
 275         mov     r2, #0x00000000         /* clear                            */
 276
 277 clbss_l:str     r2, [r0]                /* clear loop...                    */
 278         add     r0, r0, #4
 279         cmp     r0, r1
 280         bne     clbss_l
 281 #endif  /* #ifndef CONFIG_PRELOADER */
 282
 283 /*
 284  * We are done. Do not return, instead branch to second part of board
 285  * initialization, now running from RAM.
 286  */
 287 #ifdef CONFIG_NAND_SPL
 288         ldr     r0, _nand_boot_ofs
 289         adr     r1, _start
 290         add     pc, r0, r1
 291 _nand_boot_ofs
 292         : .word nand_boot - _start
 293 #else
 294 jump_2_ram:
 295         ldr     r0, _board_init_r_ofs
 296         adr     r1, _start
 297         add     lr, r0, r1
 298 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 299         add     lr, lr, r9
 300 #endif
 301         /* setup parameters for board_init_r */
 302         mov     r0, r5          /* gd_t */
 303         mov     r1, r7          /* dest_addr */
 304         /* jump to it ... */
 305         mov     pc, lr
 306
 307 _board_init_r_ofs:
 308         .word board_init_r - _start
 309 #endif
 310
 311 _rel_dyn_start_ofs:
 312         .word __rel_dyn_start - _start
 313 _rel_dyn_end_ofs:
 314         .word __rel_dyn_end - _start
 315 _dynsym_start_ofs:
 316         .word __dynsym_start - _start
 317
 318 /*
 319  *************************************************************************
 320  *
 321  * CPU_init_critical registers
 322  *
 323  * setup important registers
 324  * setup memory timing
 325  *
 326  *************************************************************************
 327  */
 328 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 329 cpu_init_crit:
 330         /*
 331          * flush v4 I/D caches
 332          */
 333         mov     r0, #0
 334         mcr     p15, 0, r0, c7, c7, 0   /* Invalidate I+D+BTB caches */
 335         mcr     p15, 0, r0, c8, c7, 0   /* Invalidate Unified TLB */
 336
 337         /*
 338          * disable MMU stuff and caches
 339          */
 340         mrc     p15, 0, r0, c1, c0, 0
 341         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 342         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 343         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 344         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 345         mcr     p15, 0, r0, c1, c0, 0
 346
 347         /*
 348          * Jump to board specific initialization... The Mask ROM will have already initialized
 349          * basic memory.  Go here to bump up clock rate and handle wake up conditions.
 350          */
 351         mov     ip, lr          /* persevere link reg across call */
 352         bl      lowlevel_init   /* go setup pll,mux,memory */
 353         mov     lr, ip          /* restore link */
 354         mov     pc, lr          /* back to my caller */
 355 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 356
 357 #ifndef CONFIG_PRELOADER
 358 /*
 359  *************************************************************************
 360  *
 361  * Interrupt handling
 362  *
 363  *************************************************************************
 364  */
 365 @
 366 @ IRQ stack frame.
 367 @
 368 #define S_FRAME_SIZE    72
 369
 370 #define S_OLD_R0        68
 371 #define S_PSR           64
 372 #define S_PC            60
 373 #define S_LR            56
 374 #define S_SP            52
 375
 376 #define S_IP            48
 377 #define S_FP            44
 378 #define S_R10           40
 379 #define S_R9            36
 380 #define S_R8            32
 381 #define S_R7            28
 382 #define S_R6            24
 383 #define S_R5            20
 384 #define S_R4            16
 385 #define S_R3            12
 386 #define S_R2            8
 387 #define S_R1            4
 388 #define S_R0            0
 389
 390 #define MODE_SVC 0x13
 391 #define I_BIT    0x80
 392
 393 /*
 394  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 395  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 396  */
 397
 398         .macro  bad_save_user_regs
 399         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current user stack
 400         stmia   sp, {r0 - r12}                  @ Save user registers (now in svc mode) r0-r12
 401
 402         ldr     r2, IRQ_STACK_START_IN          @ set base 2 words into abort stack
 403         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc and cpsr (into parm regs)
 404         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 405
 406         add     r5, sp, #S_SP
 407         mov     r1, lr
 408         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 409         mov     r0, sp                          @ save current stack into r0 (param register)
 410         .endm
 411
 412         .macro  irq_save_user_regs
 413         sub     sp, sp, #S_FRAME_SIZE
 414         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 415         add     r8, sp, #S_PC                   @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 416         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 417         str     lr, [r8, #0]                    @ Save calling PC
 418         mrs     r6, spsr
 419         str     r6, [r8, #4]                    @ Save CPSR
 420         str     r0, [r8, #8]                    @ Save OLD_R0
 421         mov     r0, sp
 422         .endm
 423
 424         .macro  irq_restore_user_regs
 425         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 426         mov     r0, r0
 427         ldr     lr, [sp, #S_PC]                 @ Get PC
 428         add     sp, sp, #S_FRAME_SIZE
 429         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 430         .endm
 431
 432         .macro get_bad_stack
 433         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack (enter in banked mode)
 434
 435         str     lr, [r13]                       @ save caller lr in position 0 of saved stack
 436         mrs     lr, spsr                        @ get the spsr
 437         str     lr, [r13, #4]                   @ save spsr in position 1 of saved stack
 438
 439         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 440         @ msr   spsr_c, r13
 441         msr     spsr, r13                       @ switch modes, make sure moves will execute
 442         mov     lr, pc                          @ capture return pc
 443         movs    pc, lr                          @ jump to next instruction & switch modes.
 444         .endm
 445
 446         .macro get_bad_stack_swi
 447         sub     r13, r13, #4                    @ space on current stack for scratch reg.
 448         str     r0, [r13]                       @ save R0's value.
 449         ldr     r0, IRQ_STACK_START_IN          @ get data regions start
 450         str     lr, [r0]                        @ save caller lr in position 0 of saved stack
 451         mrs     r0, spsr                        @ get the spsr
 452         str     lr, [r0, #4]                    @ save spsr in position 1 of saved stack
 453         ldr     r0, [r13]                       @ restore r0
 454         add     r13, r13, #4                    @ pop stack entry
 455         .endm
 456
 457         .macro get_irq_stack                    @ setup IRQ stack
 458         ldr     sp, IRQ_STACK_START
 459         .endm
 460
 461         .macro get_fiq_stack                    @ setup FIQ stack
 462         ldr     sp, FIQ_STACK_START
 463         .endm
 464 #endif  /* CONFIG_PRELOADER */
 465
 466 /*
 467  * exception handlers
 468  */
 469 #ifdef CONFIG_PRELOADER
 470         .align  5
 471 do_hang:
 472         ldr     sp, _TEXT_BASE                  /* use 32 words about stack */
 473         bl      hang                            /* hang and never return */
 474 #else   /* !CONFIG_PRELOADER */
 475         .align  5
 476 undefined_instruction:
 477         get_bad_stack
 478         bad_save_user_regs
 479         bl      do_undefined_instruction
 480
 481         .align  5
 482 software_interrupt:
 483         get_bad_stack_swi
 484         bad_save_user_regs
 485         bl      do_software_interrupt
 486
 487         .align  5
 488 prefetch_abort:
 489         get_bad_stack
 490         bad_save_user_regs
 491         bl      do_prefetch_abort
 492
 493         .align  5
 494 data_abort:
 495         get_bad_stack
 496         bad_save_user_regs
 497         bl      do_data_abort
 498
 499         .align  5
 500 not_used:
 501         get_bad_stack
 502         bad_save_user_regs
 503         bl      do_not_used
 504
 505 #ifdef CONFIG_USE_IRQ
 506
 507         .align  5
 508 irq:
 509         get_irq_stack
 510         irq_save_user_regs
 511         bl      do_irq
 512         irq_restore_user_regs
 513
 514         .align  5
 515 fiq:
 516         get_fiq_stack
 517         /* someone ought to write a more effiction fiq_save_user_regs */
 518         irq_save_user_regs
 519         bl      do_fiq
 520         irq_restore_user_regs
 521
 522 #else
 523
 524         .align  5
 525 irq:
 526         get_bad_stack
 527         bad_save_user_regs
 528         bl      do_irq
 529
 530         .align  5
 531 fiq:
 532         get_bad_stack
 533         bad_save_user_regs
 534         bl      do_fiq
 535
 536 #endif
 537         .align 5
 538 .global arm1136_cache_flush
 539 arm1136_cache_flush:
 540 #if !defined(CONFIG_SYS_NO_ICACHE)
 541                 mcr     p15, 0, r1, c7, c5, 0   @ invalidate I cache
 542 #endif
 543 #if !defined(CONFIG_SYS_NO_DCACHE)
 544                 mcr     p15, 0, r1, c7, c14, 0  @ invalidate D cache
 545 #endif
 546                 mov     pc, lr                  @ back to caller
 547 #endif  /* CONFIG_PRELOADER */