arch/arm/cpu/arm920t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 #include <asm-offsets.h>
  28 #include <common.h>
  29 #include <config.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       start_code
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (called from the ARM reset exception vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 .globl _TEXT_BASE
  75 _TEXT_BASE:
  76         .word   CONFIG_SYS_TEXT_BASE
  77
  78 /*
  79  * These are defined in the board-specific linker script.
  80  * Subtracting _start from them lets the linker put their
  81  * relative position in the executable instead of leaving
  82  * them null.
  83  */
  84 .globl _bss_start_ofs
  85 _bss_start_ofs:
  86         .word __bss_start - _start
  87
  88 .globl _bss_end_ofs
  89 _bss_end_ofs:
  90         .word _end - _start
  91
  92 #ifdef CONFIG_USE_IRQ
  93 /* IRQ stack memory (calculated at run-time) */
  94 .globl IRQ_STACK_START
  95 IRQ_STACK_START:
  96         .word   0x0badc0de
  97
  98 /* IRQ stack memory (calculated at run-time) */
  99 .globl FIQ_STACK_START
 100 FIQ_STACK_START:
 101         .word 0x0badc0de
 102 #endif
 103
 104 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 105 .globl IRQ_STACK_START_IN
 106 IRQ_STACK_START_IN:
 107         .word   0x0badc0de
 108
 109 /*
 110  * the actual start code
 111  */
 112
 113 start_code:
 114         /*
 115          * set the cpu to SVC32 mode
 116          */
 117         mrs     r0, cpsr
 118         bic     r0, r0, #0x1f
 119         orr     r0, r0, #0xd3
 120         msr     cpsr, r0
 121
 122         bl      coloured_LED_init
 123         bl      red_LED_on
 124
 125 #if     defined(CONFIG_AT91RM9200DK) || defined(CONFIG_AT91RM9200EK)
 126         /*
 127          * relocate exception table
 128          */
 129         ldr     r0, =_start
 130         ldr     r1, =0x0
 131         mov     r2, #16
 132 copyex:
 133         subs    r2, r2, #1
 134         ldr     r3, [r0], #4
 135         str     r3, [r1], #4
 136         bne     copyex
 137 #endif
 138
 139 #ifdef CONFIG_S3C24X0
 140         /* turn off the watchdog */
 141
 142 # if defined(CONFIG_S3C2400)
 143 #  define pWTCON        0x15300000
 144 #  define INTMSK        0x14400008      /* Interupt-Controller base addresses */
 145 #  define CLKDIVN       0x14800014      /* clock divisor register */
 146 #else
 147 #  define pWTCON        0x53000000
 148 #  define INTMSK        0x4A000008      /* Interupt-Controller base addresses */
 149 #  define INTSUBMSK     0x4A00001C
 150 #  define CLKDIVN       0x4C000014      /* clock divisor register */
 151 # endif
 152
 153         ldr     r0, =pWTCON
 154         mov     r1, #0x0
 155         str     r1, [r0]
 156
 157         /*
 158          * mask all IRQs by setting all bits in the INTMR - default
 159          */
 160         mov     r1, #0xffffffff
 161         ldr     r0, =INTMSK
 162         str     r1, [r0]
 163 # if defined(CONFIG_S3C2410)
 164         ldr     r1, =0x3ff
 165         ldr     r0, =INTSUBMSK
 166         str     r1, [r0]
 167 # endif
 168
 169         /* FCLK:HCLK:PCLK = 1:2:4 */
 170         /* default FCLK is 120 MHz ! */
 171         ldr     r0, =CLKDIVN
 172         mov     r1, #3
 173         str     r1, [r0]
 174 #endif  /* CONFIG_S3C24X0 */
 175
 176         /*
 177          * we do sys-critical inits only at reboot,
 178          * not when booting from ram!
 179          */
 180 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 181         bl      cpu_init_crit
 182 #endif
 183
 184 /* Set stackpointer in internal RAM to call board_init_f */
 185 call_board_init_f:
 186         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 187         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 188         ldr     r0,=0x00000000
 189         bl      board_init_f
 190
 191 /*------------------------------------------------------------------------------*/
 192
 193 /*
 194  * void relocate_code (addr_sp, gd, addr_moni)
 195  *
 196  * This "function" does not return, instead it continues in RAM
 197  * after relocating the monitor code.
 198  *
 199  */
 200         .globl  relocate_code
 201 relocate_code:
 202         mov     r4, r0  /* save addr_sp */
 203         mov     r5, r1  /* save addr of gd */
 204         mov     r6, r2  /* save addr of destination */
 205
 206         /* Set up the stack                                                 */
 207 stack_setup:
 208         mov     sp, r4
 209
 210         adr     r0, _start
 211         cmp     r0, r6
 212         beq     clear_bss               /* skip relocation */
 213         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 214         ldr     r3, _bss_start_ofs
 215         add     r2, r0, r3              /* r2 <- source end address         */
 216
 217 copy_loop:
 218         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 219         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 220         cmp     r0, r2                  /* until source end address [r2]    */
 221         blo     copy_loop
 222
 223 #ifndef CONFIG_PRELOADER
 224         /*
 225          * fix .rel.dyn relocations
 226          */
 227         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 228         sub     r9, r6, r0              /* r9 <- relocation offset */
 229         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 230         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 231         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 232         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 233         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 234         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 235 fixloop:
 236         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 237         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 238         ldr     r1, [r2, #4]
 239         and     r7, r1, #0xff
 240         cmp     r7, #23                 /* relative fixup? */
 241         beq     fixrel
 242         cmp     r7, #2                  /* absolute fixup? */
 243         beq     fixabs
 244         /* ignore unknown type of fixup */
 245         b       fixnext
 246 fixabs:
 247         /* absolute fix: set location to (offset) symbol value */
 248         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 249         add     r1, r10, r1             /* r1 <- address of symbol in table */
 250         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 251         add     r1, r1, r9              /* r1 <- relocated sym addr */
 252         b       fixnext
 253 fixrel:
 254         /* relative fix: increase location by offset */
 255         ldr     r1, [r0]
 256         add     r1, r1, r9
 257 fixnext:
 258         str     r1, [r0]
 259         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 260         cmp     r2, r3
 261         blo     fixloop
 262 #endif
 263
 264 clear_bss:
 265 #ifndef CONFIG_PRELOADER
 266         ldr     r0, _bss_start_ofs
 267         ldr     r1, _bss_end_ofs
 268         mov     r4, r6                  /* reloc addr */
 269         add     r0, r0, r4
 270         add     r1, r1, r4
 271         mov     r2, #0x00000000         /* clear                            */
 272
 273 clbss_l:str     r2, [r0]                /* clear loop...                    */
 274         add     r0, r0, #4
 275         cmp     r0, r1
 276         bne     clbss_l
 277
 278         bl coloured_LED_init
 279         bl red_LED_on
 280 #endif
 281
 282 /*
 283  * We are done. Do not return, instead branch to second part of board
 284  * initialization, now running from RAM.
 285  */
 286 #ifdef CONFIG_NAND_SPL
 287         ldr     r0, _nand_boot_ofs
 288         mov     pc, r0
 289
 290 _nand_boot_ofs:
 291         .word nand_boot
 292 #else
 293         ldr     r0, _board_init_r_ofs
 294         adr     r1, _start
 295         add     lr, r0, r1
 296         add     lr, lr, r9
 297         /* setup parameters for board_init_r */
 298         mov     r0, r5          /* gd_t */
 299         mov     r1, r6          /* dest_addr */
 300         /* jump to it ... */
 301         mov     pc, lr
 302
 303 _board_init_r_ofs:
 304         .word board_init_r - _start
 305 #endif
 306
 307 _rel_dyn_start_ofs:
 308         .word __rel_dyn_start - _start
 309 _rel_dyn_end_ofs:
 310         .word __rel_dyn_end - _start
 311 _dynsym_start_ofs:
 312         .word __dynsym_start - _start
 313
 314 /*
 315  *************************************************************************
 316  *
 317  * CPU_init_critical registers
 318  *
 319  * setup important registers
 320  * setup memory timing
 321  *
 322  *************************************************************************
 323  */
 324
 325
 326 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 327 cpu_init_crit:
 328         /*
 329          * flush v4 I/D caches
 330          */
 331         mov     r0, #0
 332         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 333         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 334
 335         /*
 336          * disable MMU stuff and caches
 337          */
 338         mrc     p15, 0, r0, c1, c0, 0
 339         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 340         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 341         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 342         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 343         mcr     p15, 0, r0, c1, c0, 0
 344
 345         /*
 346          * before relocating, we have to setup RAM timing
 347          * because memory timing is board-dependend, you will
 348          * find a lowlevel_init.S in your board directory.
 349          */
 350         mov     ip, lr
 351
 352         bl      lowlevel_init
 353
 354         mov     lr, ip
 355         mov     pc, lr
 356 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 357
 358 /*
 359  *************************************************************************
 360  *
 361  * Interrupt handling
 362  *
 363  *************************************************************************
 364  */
 365
 366 @
 367 @ IRQ stack frame.
 368 @
 369 #define S_FRAME_SIZE    72
 370
 371 #define S_OLD_R0        68
 372 #define S_PSR           64
 373 #define S_PC            60
 374 #define S_LR            56
 375 #define S_SP            52
 376
 377 #define S_IP            48
 378 #define S_FP            44
 379 #define S_R10           40
 380 #define S_R9            36
 381 #define S_R8            32
 382 #define S_R7            28
 383 #define S_R6            24
 384 #define S_R5            20
 385 #define S_R4            16
 386 #define S_R3            12
 387 #define S_R2            8
 388 #define S_R1            4
 389 #define S_R0            0
 390
 391 #define MODE_SVC        0x13
 392 #define I_BIT           0x80
 393
 394 /*
 395  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 396  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 397  */
 398
 399         .macro  bad_save_user_regs
 400         sub     sp, sp, #S_FRAME_SIZE
 401         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 402         ldr     r2, IRQ_STACK_START_IN
 403         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 404         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 405
 406         add     r5, sp, #S_SP
 407         mov     r1, lr
 408         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 409         mov     r0, sp
 410         .endm
 411
 412         .macro  irq_save_user_regs
 413         sub     sp, sp, #S_FRAME_SIZE
 414         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 415         add     r7, sp, #S_PC
 416         stmdb   r7, {sp, lr}^                   @ Calling SP, LR
 417         str     lr, [r7, #0]                    @ Save calling PC
 418         mrs     r6, spsr
 419         str     r6, [r7, #4]                    @ Save CPSR
 420         str     r0, [r7, #8]                    @ Save OLD_R0
 421         mov     r0, sp
 422         .endm
 423
 424         .macro  irq_restore_user_regs
 425         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 426         mov     r0, r0
 427         ldr     lr, [sp, #S_PC]                 @ Get PC
 428         add     sp, sp, #S_FRAME_SIZE
 429         /* return & move spsr_svc into cpsr */
 430         subs    pc, lr, #4
 431         .endm
 432
 433         .macro get_bad_stack
 434         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 435
 436         str     lr, [r13]                       @ save caller lr / spsr
 437         mrs     lr, spsr
 438         str     lr, [r13, #4]
 439
 440         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 441         @ msr   spsr_c, r13
 442         msr     spsr, r13
 443         mov     lr, pc
 444         movs    pc, lr
 445         .endm
 446
 447         .macro get_irq_stack                    @ setup IRQ stack
 448         ldr     sp, IRQ_STACK_START
 449         .endm
 450
 451         .macro get_fiq_stack                    @ setup FIQ stack
 452         ldr     sp, FIQ_STACK_START
 453         .endm
 454
 455 /*
 456  * exception handlers
 457  */
 458         .align  5
 459 undefined_instruction:
 460         get_bad_stack
 461         bad_save_user_regs
 462         bl      do_undefined_instruction
 463
 464         .align  5
 465 software_interrupt:
 466         get_bad_stack
 467         bad_save_user_regs
 468         bl      do_software_interrupt
 469
 470         .align  5
 471 prefetch_abort:
 472         get_bad_stack
 473         bad_save_user_regs
 474         bl      do_prefetch_abort
 475
 476         .align  5
 477 data_abort:
 478         get_bad_stack
 479         bad_save_user_regs
 480         bl      do_data_abort
 481
 482         .align  5
 483 not_used:
 484         get_bad_stack
 485         bad_save_user_regs
 486         bl      do_not_used
 487
 488 #ifdef CONFIG_USE_IRQ
 489
 490         .align  5
 491 irq:
 492         get_irq_stack
 493         irq_save_user_regs
 494         bl      do_irq
 495         irq_restore_user_regs
 496
 497         .align  5
 498 fiq:
 499         get_fiq_stack
 500         /* someone ought to write a more effiction fiq_save_user_regs */
 501         irq_save_user_regs
 502         bl      do_fiq
 503         irq_restore_user_regs
 504
 505 #else
 506
 507         .align  5
 508 irq:
 509         get_bad_stack
 510         bad_save_user_regs
 511         bl      do_irq
 512
 513         .align  5
 514 fiq:
 515         get_bad_stack
 516         bad_save_user_regs
 517         bl      do_fiq
 518
 519 #endif