arch/arm/cpu/arm920t/u-boot.lds

   1 /*
   2  * (c) Copyright 2004
   3  * Techware Information Technology, Inc.
   4  * Ming-Len Wu <minglen_wu@techware.com.tw>
   5  *
   6  * (C) Copyright 2000-2004
   7  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   8  *
   9  * (C) Copyright 2002
  10  * Gary Jennejohn, DENX Software Engineering, <gj@denx.de>
  11  *
  12  * See file CREDITS for list of people who contributed to this
  13  * project.
  14  *
  15  * This program is free software; you can redistribute it and/or
  16  * modify it under the terms of the GNU General Public License as
  17  * published by the Free Software Foundation; either version 2 of
  18  * the License, or (at your option) any later version.
  19  *
  20  * This program is distributed in the hope that it will be useful,
  21  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  22  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23  * GNU General Public License for more details.
  24  *
  25  * You should have received a copy of the GNU General Public License
  26  * along with this program; if not, write to the Free Software
  27  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  28  * MA 02111-1307 USA
  29  *
  30  */
  31
  32 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  33 OUTPUT_ARCH(arm)
  34 ENTRY(_start)
  35 SECTIONS
  36 {
  37         . = 0x00000000;
  38
  39         . = ALIGN(4);
  40         .text :
  41         {
  42                 arch/arm/cpu/arm920t/start.o    (.text)
  43                 *(.text)
  44         }
  45
  46         . = ALIGN(4);
  47         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  48
  49         . = ALIGN(4);
  50         .data : {
  51                 *(.data)
  52         }
  53
  54         . = ALIGN(4);
  55
  56         . = .;
  57         __u_boot_cmd_start = .;
  58         .u_boot_cmd : { *(.u_boot_cmd) }
  59         __u_boot_cmd_end = .;
  60
  61         . = ALIGN(4);
  62
  63         .rel.dyn : {
  64                 __rel_dyn_start = .;
  65                 *(.rel*)
  66                 __rel_dyn_end = .;
  67         }
  68
  69         .dynsym : {
  70                 __dynsym_start = .;
  71                 *(.dynsym)
  72         }
  73
  74         .bss __rel_dyn_start (OVERLAY) : {
  75                 __bss_start = .;
  76                 *(.bss)
  77                  . = ALIGN(4);
  78                 __bss_end__ = .;
  79         }
  80
  81         /DISCARD/ : { *(.dynstr*) }
  82         /DISCARD/ : { *(.dynamic*) }
  83         /DISCARD/ : { *(.plt*) }
  84         /DISCARD/ : { *(.interp*) }
  85         /DISCARD/ : { *(.gnu*) }
  86 }