arch/arm/cpu/arm925t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM925 CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1510 from ARM920 code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij  <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33 #include <asm-offsets.h>
  34 #include <config.h>
  35 #include <version.h>
  36
  37 #if defined(CONFIG_OMAP1510)
  38 #include <./configs/omap1510.h>
  39 #endif
  40
  41 /*
  42  *************************************************************************
  43  *
  44  * Jump vector table as in table 3.1 in [1]
  45  *
  46  *************************************************************************
  47  */
  48
  49
  50 .globl _start
  51 _start: b       reset
  52         ldr     pc, _undefined_instruction
  53         ldr     pc, _software_interrupt
  54         ldr     pc, _prefetch_abort
  55         ldr     pc, _data_abort
  56         ldr     pc, _not_used
  57         ldr     pc, _irq
  58         ldr     pc, _fiq
  59
  60 _undefined_instruction: .word undefined_instruction
  61 _software_interrupt:    .word software_interrupt
  62 _prefetch_abort:        .word prefetch_abort
  63 _data_abort:            .word data_abort
  64 _not_used:              .word not_used
  65 _irq:                   .word irq
  66 _fiq:                   .word fiq
  67
  68         .balignl 16,0xdeadbeef
  69
  70
  71 /*
  72  *************************************************************************
  73  *
  74  * Startup Code (reset vector)
  75  *
  76  * do important init only if we don't start from memory!
  77  * setup Memory and board specific bits prior to relocation.
  78  * relocate armboot to ram
  79  * setup stack
  80  *
  81  *************************************************************************
  82  */
  83
  84 .globl _TEXT_BASE
  85 _TEXT_BASE:
  86         .word   CONFIG_SYS_TEXT_BASE
  87
  88 /*
  89  * These are defined in the board-specific linker script.
  90  * Subtracting _start from them lets the linker put their
  91  * relative position in the executable instead of leaving
  92  * them null.
  93  */
  94 .globl _bss_start_ofs
  95 _bss_start_ofs:
  96         .word __bss_start - _start
  97
  98 .globl _bss_end_ofs
  99 _bss_end_ofs:
 100         .word __bss_end__ - _start
 101
 102 .globl _end_ofs
 103 _end_ofs:
 104         .word _end - _start
 105
 106 #ifdef CONFIG_USE_IRQ
 107 /* IRQ stack memory (calculated at run-time) */
 108 .globl IRQ_STACK_START
 109 IRQ_STACK_START:
 110         .word   0x0badc0de
 111
 112 /* IRQ stack memory (calculated at run-time) */
 113 .globl FIQ_STACK_START
 114 FIQ_STACK_START:
 115         .word 0x0badc0de
 116 #endif
 117
 118 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 119 .globl IRQ_STACK_START_IN
 120 IRQ_STACK_START_IN:
 121         .word   0x0badc0de
 122
 123 /*
 124  * the actual reset code
 125  */
 126
 127 reset:
 128         /*
 129          * set the cpu to SVC32 mode
 130          */
 131         mrs     r0,cpsr
 132         bic     r0,r0,#0x1f
 133         orr     r0,r0,#0xd3
 134         msr     cpsr,r0
 135
 136         /*
 137          * Set up 925T mode
 138          */
 139         mov r1, #0x81               /* Set ARM925T configuration. */
 140         mcr p15, 0, r1, c15, c1, 0  /* Write ARM925T configuration register. */
 141
 142         /*
 143          * turn off the watchdog, unlock/diable sequence
 144          */
 145         mov  r1, #0xF5
 146         ldr  r0, =WDTIM_MODE
 147         strh r1, [r0]
 148         mov  r1, #0xA0
 149         strh r1, [r0]
 150
 151         /*
 152          * mask all IRQs by setting all bits in the INTMR - default
 153          */
 154         mov r1, #0xffffffff
 155         ldr r0, =REG_IHL1_MIR
 156         str r1, [r0]
 157         ldr r0, =REG_IHL2_MIR
 158         str r1, [r0]
 159
 160         /*
 161          * wait for dpll to lock
 162          */
 163         ldr  r0, =CK_DPLL1
 164         mov  r1, #0x10
 165         strh r1, [r0]
 166 poll1:
 167         ldrh r1, [r0]
 168         ands r1, r1, #0x01
 169         beq poll1
 170
 171         /*
 172          * we do sys-critical inits only at reboot,
 173          * not when booting from ram!
 174          */
 175 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 176         bl  cpu_init_crit
 177 #endif
 178
 179 /* Set stackpointer in internal RAM to call board_init_f */
 180 call_board_init_f:
 181         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 182         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 183         ldr     r0,=0x00000000
 184         bl      board_init_f
 185
 186 /*------------------------------------------------------------------------------*/
 187
 188 /*
 189  * void relocate_code (addr_sp, gd, addr_moni)
 190  *
 191  * This "function" does not return, instead it continues in RAM
 192  * after relocating the monitor code.
 193  *
 194  */
 195         .globl  relocate_code
 196 relocate_code:
 197         mov     r4, r0  /* save addr_sp */
 198         mov     r5, r1  /* save addr of gd */
 199         mov     r6, r2  /* save addr of destination */
 200
 201         /* Set up the stack                                                 */
 202 stack_setup:
 203         mov     sp, r4
 204
 205         adr     r0, _start
 206         cmp     r0, r6
 207         moveq   r9, #0          /* no relocation. relocation offset(r9) = 0 */
 208         beq     clear_bss               /* skip relocation */
 209         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 210         ldr     r3, _bss_start_ofs
 211         add     r2, r0, r3              /* r2 <- source end address         */
 212
 213 copy_loop:
 214         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 215         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 216         cmp     r0, r2                  /* until source end address [r2]    */
 217         blo     copy_loop
 218
 219 #ifndef CONFIG_SPL_BUILD
 220         /*
 221          * fix .rel.dyn relocations
 222          */
 223         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 224         sub     r9, r6, r0              /* r9 <- relocation offset */
 225         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 226         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 227         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 228         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 229         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 230         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 231 fixloop:
 232         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 233         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 234         ldr     r1, [r2, #4]
 235         and     r7, r1, #0xff
 236         cmp     r7, #23                 /* relative fixup? */
 237         beq     fixrel
 238         cmp     r7, #2                  /* absolute fixup? */
 239         beq     fixabs
 240         /* ignore unknown type of fixup */
 241         b       fixnext
 242 fixabs:
 243         /* absolute fix: set location to (offset) symbol value */
 244         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 245         add     r1, r10, r1             /* r1 <- address of symbol in table */
 246         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 247         add     r1, r1, r9              /* r1 <- relocated sym addr */
 248         b       fixnext
 249 fixrel:
 250         /* relative fix: increase location by offset */
 251         ldr     r1, [r0]
 252         add     r1, r1, r9
 253 fixnext:
 254         str     r1, [r0]
 255         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 256         cmp     r2, r3
 257         blo     fixloop
 258 #endif
 259
 260 clear_bss:
 261 #ifndef CONFIG_SPL_BUILD
 262         ldr     r0, _bss_start_ofs
 263         ldr     r1, _bss_end_ofs
 264         mov     r4, r6                  /* reloc addr */
 265         add     r0, r0, r4
 266         add     r1, r1, r4
 267         mov     r2, #0x00000000         /* clear                            */
 268
 269 clbss_l:cmp     r0, r1                  /* clear loop... */
 270         bhs     clbss_e                 /* if reached end of bss, exit */
 271         str     r2, [r0]
 272         add     r0, r0, #4
 273         b       clbss_l
 274 clbss_e:
 275
 276         bl coloured_LED_init
 277         bl red_led_on
 278 #endif
 279
 280 /*
 281  * We are done. Do not return, instead branch to second part of board
 282  * initialization, now running from RAM.
 283  */
 284 #ifdef CONFIG_NAND_SPL
 285         ldr     r0, _nand_boot_ofs
 286         mov     pc, r0
 287
 288 _nand_boot_ofs:
 289         .word nand_boot
 290 #else
 291         ldr     r0, _board_init_r_ofs
 292         adr     r1, _start
 293         add     lr, r0, r1
 294         add     lr, lr, r9
 295         /* setup parameters for board_init_r */
 296         mov     r0, r5          /* gd_t */
 297         mov     r1, r6          /* dest_addr */
 298         /* jump to it ... */
 299         mov     pc, lr
 300
 301 _board_init_r_ofs:
 302         .word board_init_r - _start
 303 #endif
 304
 305 _rel_dyn_start_ofs:
 306         .word __rel_dyn_start - _start
 307 _rel_dyn_end_ofs:
 308         .word __rel_dyn_end - _start
 309 _dynsym_start_ofs:
 310         .word __dynsym_start - _start
 311
 312 /*
 313  *************************************************************************
 314  *
 315  * CPU_init_critical registers
 316  *
 317  * setup important registers
 318  * setup memory timing
 319  *
 320  *************************************************************************
 321  */
 322
 323
 324 cpu_init_crit:
 325         /*
 326          * flush v4 I/D caches
 327          */
 328         mov     r0, #0
 329         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 330         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 331
 332         /*
 333          * disable MMU stuff and caches
 334          */
 335         mrc     p15, 0, r0, c1, c0, 0
 336         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 337         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 338         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 339         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 340         mcr     p15, 0, r0, c1, c0, 0
 341
 342         /*
 343          * Go setup Memory and board specific bits prior to relocation.
 344          */
 345         mov     ip, lr          /* perserve link reg across call */
 346         bl      lowlevel_init   /* go setup pll,mux,memory */
 347         mov     lr, ip          /* restore link */
 348         mov     pc, lr          /* back to my caller */
 349 /*
 350  *************************************************************************
 351  *
 352  * Interrupt handling
 353  *
 354  *************************************************************************
 355  */
 356
 357 @
 358 @ IRQ stack frame.
 359 @
 360 #define S_FRAME_SIZE    72
 361
 362 #define S_OLD_R0        68
 363 #define S_PSR           64
 364 #define S_PC            60
 365 #define S_LR            56
 366 #define S_SP            52
 367
 368 #define S_IP            48
 369 #define S_FP            44
 370 #define S_R10           40
 371 #define S_R9            36
 372 #define S_R8            32
 373 #define S_R7            28
 374 #define S_R6            24
 375 #define S_R5            20
 376 #define S_R4            16
 377 #define S_R3            12
 378 #define S_R2            8
 379 #define S_R1            4
 380 #define S_R0            0
 381
 382 #define MODE_SVC 0x13
 383 #define I_BIT    0x80
 384
 385 /*
 386  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 387  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 388  */
 389
 390         .macro  bad_save_user_regs
 391         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current user stack
 392         stmia   sp, {r0 - r12}                  @ Save user registers (now in svc mode) r0-r12
 393
 394         ldr     r2, IRQ_STACK_START_IN
 395         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc and cpsr (into parm regs)
 396         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 397
 398         add     r5, sp, #S_SP
 399         mov     r1, lr
 400         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 401         mov     r0, sp                          @ save current stack into r0 (param register)
 402         .endm
 403
 404         .macro  irq_save_user_regs
 405         sub     sp, sp, #S_FRAME_SIZE
 406         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 407         add     r8, sp, #S_PC                   @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 408         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 409         str     lr, [r8, #0]                    @ Save calling PC
 410         mrs     r6, spsr
 411         str     r6, [r8, #4]                    @ Save CPSR
 412         str     r0, [r8, #8]                    @ Save OLD_R0
 413         mov     r0, sp
 414         .endm
 415
 416         .macro  irq_restore_user_regs
 417         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 418         mov     r0, r0
 419         ldr     lr, [sp, #S_PC]                 @ Get PC
 420         add     sp, sp, #S_FRAME_SIZE
 421         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 422         .endm
 423
 424         .macro get_bad_stack
 425         ldr     r13, IRQ_STACK_START_IN
 426
 427         str     lr, [r13]                       @ save caller lr in position 0 of saved stack
 428         mrs     lr, spsr                        @ get the spsr
 429         str     lr, [r13, #4]                   @ save spsr in position 1 of saved stack
 430
 431         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 432         @ msr   spsr_c, r13
 433         msr     spsr, r13                       @ switch modes, make sure moves will execute
 434         mov     lr, pc                          @ capture return pc
 435         movs    pc, lr                          @ jump to next instruction & switch modes.
 436         .endm
 437
 438         .macro get_irq_stack                    @ setup IRQ stack
 439         ldr     sp, IRQ_STACK_START
 440         .endm
 441
 442         .macro get_fiq_stack                    @ setup FIQ stack
 443         ldr     sp, FIQ_STACK_START
 444         .endm
 445
 446 /*
 447  * exception handlers
 448  */
 449         .align  5
 450 undefined_instruction:
 451         get_bad_stack
 452         bad_save_user_regs
 453         bl      do_undefined_instruction
 454
 455         .align  5
 456 software_interrupt:
 457         get_bad_stack
 458         bad_save_user_regs
 459         bl      do_software_interrupt
 460
 461         .align  5
 462 prefetch_abort:
 463         get_bad_stack
 464         bad_save_user_regs
 465         bl      do_prefetch_abort
 466
 467         .align  5
 468 data_abort:
 469         get_bad_stack
 470         bad_save_user_regs
 471         bl      do_data_abort
 472
 473         .align  5
 474 not_used:
 475         get_bad_stack
 476         bad_save_user_regs
 477         bl      do_not_used
 478
 479 #ifdef CONFIG_USE_IRQ
 480
 481         .align  5
 482 irq:
 483         get_irq_stack
 484         irq_save_user_regs
 485         bl      do_irq
 486         irq_restore_user_regs
 487
 488         .align  5
 489 fiq:
 490         get_fiq_stack
 491         /* someone ought to write a more effiction fiq_save_user_regs */
 492         irq_save_user_regs
 493         bl      do_fiq
 494         irq_restore_user_regs
 495
 496 #else
 497
 498         .align  5
 499 irq:
 500         get_bad_stack
 501         bad_save_user_regs
 502         bl      do_irq
 503
 504         .align  5
 505 fiq:
 506         get_bad_stack
 507         bad_save_user_regs
 508         bl      do_fiq
 509
 510 #endif
 511
 512         .align  5
 513 .globl reset_cpu
 514 reset_cpu:
 515         ldr     r1, rstctl1     /* get clkm1 reset ctl */
 516         mov     r3, #0x3        /* dsp_en + arm_rst = global reset */
 517         strh    r3, [r1]        /* force reset */
 518         mov     r0, r0
 519 _loop_forever:
 520         b       _loop_forever
 521 rstctl1:
 522         .word   0xfffece10