arch/arm/cpu/lh7a40x/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 #include <asm-offsets.h>
  28 #include <config.h>
  29 #include <version.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 .globl _TEXT_BASE
  75 _TEXT_BASE:
  76         .word   CONFIG_SYS_TEXT_BASE
  77
  78 /*
  79  * These are defined in the board-specific linker script.
  80  */
  81 .globl _bss_start
  82 _bss_start:
  83         .word __bss_start
  84
  85 .globl _bss_end
  86 _bss_end:
  87         .word _end
  88
  89 #ifdef CONFIG_USE_IRQ
  90 /* IRQ stack memory (calculated at run-time) */
  91 .globl IRQ_STACK_START
  92 IRQ_STACK_START:
  93         .word   0x0badc0de
  94
  95 /* IRQ stack memory (calculated at run-time) */
  96 .globl FIQ_STACK_START
  97 FIQ_STACK_START:
  98         .word 0x0badc0de
  99 #endif
 100
 101 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 102 .globl IRQ_STACK_START_IN
 103 IRQ_STACK_START_IN:
 104         .word   0x0badc0de
 105
 106 .globl _datarel_start
 107 _datarel_start:
 108         .word __datarel_start
 109
 110 .globl _datarelrolocal_start
 111 _datarelrolocal_start:
 112         .word __datarelrolocal_start
 113
 114 .globl _datarellocal_start
 115 _datarellocal_start:
 116         .word __datarellocal_start
 117
 118 .globl _datarelro_start
 119 _datarelro_start:
 120         .word __datarelro_start
 121
 122 .globl _got_start
 123 _got_start:
 124         .word __got_start
 125
 126 .globl _got_end
 127 _got_end:
 128         .word __got_end
 129
 130 /*
 131  * the actual reset code
 132  */
 133
 134 reset:
 135         /*
 136          * set the cpu to SVC32 mode
 137          */
 138         mrs     r0,cpsr
 139         bic     r0,r0,#0x1f
 140         orr     r0,r0,#0xd3
 141         msr     cpsr,r0
 142
 143 #define pWDTCTL         0x80001400  /* Watchdog Timer control register */
 144 #define pINTENC         0x8000050C  /* Interupt-Controller enable clear register */
 145 #define pCLKSET         0x80000420  /* clock divisor register */
 146
 147         /* disable watchdog, set watchdog control register to
 148          * all zeros (default reset)
 149          */
 150         ldr     r0, =pWDTCTL
 151         mov     r1, #0x0
 152         str     r1, [r0]
 153
 154         /*
 155          * mask all IRQs by setting all bits in the INTENC register (default)
 156          */
 157         mov     r1, #0xffffffff
 158         ldr     r0, =pINTENC
 159         str     r1, [r0]
 160
 161         /* FCLK:HCLK:PCLK = 1:2:2 */
 162         /* default FCLK is 200 MHz, using 14.7456 MHz fin */
 163         ldr     r0, =pCLKSET
 164         ldr r1, =0x0004ee39
 165 @       ldr r1, =0x0005ee39     @ 1: 2: 4
 166         str     r1, [r0]
 167
 168         /*
 169          * we do sys-critical inits only at reboot,
 170          * not when booting from ram!
 171          */
 172 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 173         bl      cpu_init_crit
 174 #endif
 175
 176 /* Set stackpointer in internal RAM to call board_init_f */
 177 call_board_init_f:
 178         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 179         ldr     r0,=0x00000000
 180         bl      board_init_f
 181
 182 /*------------------------------------------------------------------------------*/
 183
 184 /*
 185  * void relocate_code (addr_sp, gd, addr_moni)
 186  *
 187  * This "function" does not return, instead it continues in RAM
 188  * after relocating the monitor code.
 189  *
 190  */
 191         .globl  relocate_code
 192 relocate_code:
 193         mov     r4, r0  /* save addr_sp */
 194         mov     r5, r1  /* save addr of gd */
 195         mov     r6, r2  /* save addr of destination */
 196         mov     r7, r2  /* save addr of destination */
 197
 198         /* Set up the stack                                                 */
 199 stack_setup:
 200         mov     sp, r4
 201
 202         adr     r0, _start
 203         ldr     r2, _TEXT_BASE
 204         ldr     r3, _bss_start
 205         sub     r2, r3, r2              /* r2 <- size of armboot            */
 206         add     r2, r0, r2              /* r2 <- source end address         */
 207         cmp     r0, r6
 208         beq     clear_bss
 209
 210 copy_loop:
 211         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 212         stmia   r6!, {r9-r10}           /* copy to   target address [r1]    */
 213         cmp     r0, r2                  /* until source end address [r2]    */
 214         blo     copy_loop
 215
 216 #ifndef CONFIG_PRELOADER
 217         /* fix got entries */
 218         ldr     r1, _TEXT_BASE          /* Text base */
 219         mov     r0, r7                  /* reloc addr */
 220         ldr     r2, _got_start          /* addr in Flash */
 221         ldr     r3, _got_end            /* addr in Flash */
 222         sub     r3, r3, r1
 223         add     r3, r3, r0
 224         sub     r2, r2, r1
 225         add     r2, r2, r0
 226
 227 fixloop:
 228         ldr     r4, [r2]
 229         sub     r4, r4, r1
 230         add     r4, r4, r0
 231         str     r4, [r2]
 232         add     r2, r2, #4
 233         cmp     r2, r3
 234         blo     fixloop
 235 #endif
 236
 237 clear_bss:
 238 #ifndef CONFIG_PRELOADER
 239         ldr     r0, _bss_start
 240         ldr     r1, _bss_end
 241         ldr     r3, _TEXT_BASE          /* Text base */
 242         mov     r4, r7                  /* reloc addr */
 243         sub     r0, r0, r3
 244         add     r0, r0, r4
 245         sub     r1, r1, r3
 246         add     r1, r1, r4
 247         mov     r2, #0x00000000         /* clear                            */
 248
 249 clbss_l:str     r2, [r0]                /* clear loop...                    */
 250         add     r0, r0, #4
 251         cmp     r0, r1
 252         bne     clbss_l
 253 #endif
 254
 255 /*
 256  * We are done. Do not return, instead branch to second part of board
 257  * initialization, now running from RAM.
 258  */
 259         ldr     r0, _TEXT_BASE
 260         ldr     r2, _board_init_r
 261         sub     r2, r2, r0
 262         add     r2, r2, r7      /* position from board_init_r in RAM */
 263         /* setup parameters for board_init_r */
 264         mov     r0, r5          /* gd_t */
 265         mov     r1, r7          /* dest_addr */
 266         /* jump to it ... */
 267         mov     lr, r2
 268         mov     pc, lr
 269
 270 _board_init_r: .word board_init_r
 271
 272 /*
 273  *************************************************************************
 274  *
 275  * CPU_init_critical registers
 276  *
 277  * setup important registers
 278  * setup memory timing
 279  *
 280  *************************************************************************
 281  */
 282
 283
 284 cpu_init_crit:
 285         /*
 286          * flush v4 I/D caches
 287          */
 288         mov     r0, #0
 289         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 290         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 291
 292         /*
 293          * disable MMU stuff and caches
 294          */
 295         mrc     p15, 0, r0, c1, c0, 0
 296         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 297         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 298         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 299         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 300         orr     r0, r0, #0x40000000     @ set bit 30 (nF) notFastBus
 301         mcr     p15, 0, r0, c1, c0, 0
 302
 303
 304         /*
 305          * before relocating, we have to setup RAM timing
 306          * because memory timing is board-dependend, you will
 307          * find a lowlevel_init.S in your board directory.
 308          */
 309         mov     ip, lr
 310         bl      lowlevel_init
 311         mov     lr, ip
 312
 313         mov     pc, lr
 314
 315
 316 /*
 317  *************************************************************************
 318  *
 319  * Interrupt handling
 320  *
 321  *************************************************************************
 322  */
 323
 324 @
 325 @ IRQ stack frame.
 326 @
 327 #define S_FRAME_SIZE    72
 328
 329 #define S_OLD_R0        68
 330 #define S_PSR           64
 331 #define S_PC            60
 332 #define S_LR            56
 333 #define S_SP            52
 334
 335 #define S_IP            48
 336 #define S_FP            44
 337 #define S_R10           40
 338 #define S_R9            36
 339 #define S_R8            32
 340 #define S_R7            28
 341 #define S_R6            24
 342 #define S_R5            20
 343 #define S_R4            16
 344 #define S_R3            12
 345 #define S_R2            8
 346 #define S_R1            4
 347 #define S_R0            0
 348
 349 #define MODE_SVC 0x13
 350 #define I_BIT    0x80
 351
 352 /*
 353  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 354  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 355  */
 356
 357         .macro  bad_save_user_regs
 358         sub     sp, sp, #S_FRAME_SIZE
 359         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 360         ldr     r2, IRQ_STACK_START_IN
 361         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 362         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 363
 364         add     r5, sp, #S_SP
 365         mov     r1, lr
 366         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 367         mov     r0, sp
 368         .endm
 369
 370         .macro  irq_save_user_regs
 371         sub     sp, sp, #S_FRAME_SIZE
 372         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 373         add     r8, sp, #S_PC
 374         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 375         str     lr, [r8, #0]                    @ Save calling PC
 376         mrs     r6, spsr
 377         str     r6, [r8, #4]                    @ Save CPSR
 378         str     r0, [r8, #8]                    @ Save OLD_R0
 379         mov     r0, sp
 380         .endm
 381
 382         .macro  irq_restore_user_regs
 383         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 384         mov     r0, r0
 385         ldr     lr, [sp, #S_PC]                 @ Get PC
 386         add     sp, sp, #S_FRAME_SIZE
 387         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 388         .endm
 389
 390         .macro get_bad_stack
 391         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 392
 393         str     lr, [r13]                       @ save caller lr / spsr
 394         mrs     lr, spsr
 395         str     lr, [r13, #4]
 396
 397         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 398         @ msr   spsr_c, r13
 399         msr     spsr, r13
 400         mov     lr, pc
 401         movs    pc, lr
 402         .endm
 403
 404         .macro get_irq_stack                    @ setup IRQ stack
 405         ldr     sp, IRQ_STACK_START
 406         .endm
 407
 408         .macro get_fiq_stack                    @ setup FIQ stack
 409         ldr     sp, FIQ_STACK_START
 410         .endm
 411
 412 /*
 413  * exception handlers
 414  */
 415         .align  5
 416 undefined_instruction:
 417         get_bad_stack
 418         bad_save_user_regs
 419         bl      do_undefined_instruction
 420
 421         .align  5
 422 software_interrupt:
 423         get_bad_stack
 424         bad_save_user_regs
 425         bl      do_software_interrupt
 426
 427         .align  5
 428 prefetch_abort:
 429         get_bad_stack
 430         bad_save_user_regs
 431         bl      do_prefetch_abort
 432
 433         .align  5
 434 data_abort:
 435         get_bad_stack
 436         bad_save_user_regs
 437         bl      do_data_abort
 438
 439         .align  5
 440 not_used:
 441         get_bad_stack
 442         bad_save_user_regs
 443         bl      do_not_used
 444
 445 #ifdef CONFIG_USE_IRQ
 446
 447         .align  5
 448 irq:
 449         get_irq_stack
 450         irq_save_user_regs
 451         bl      do_irq
 452         irq_restore_user_regs
 453
 454         .align  5
 455 fiq:
 456         get_fiq_stack
 457         /* someone ought to write a more effiction fiq_save_user_regs */
 458         irq_save_user_regs
 459         bl      do_fiq
 460         irq_restore_user_regs
 461
 462 #else
 463
 464         .align  5
 465 irq:
 466         get_bad_stack
 467         bad_save_user_regs
 468         bl      do_irq
 469
 470         .align  5
 471 fiq:
 472         get_bad_stack
 473         bad_save_user_regs
 474         bl      do_fiq
 475
 476 #endif
 477
 478         .align  5
 479 .globl reset_cpu
 480 reset_cpu:
 481         bl      disable_interrupts
 482
 483         /* Disable watchdog */
 484         ldr     r1, =pWDTCTL
 485         mov     r3, #0
 486         str     r3, [r1]
 487
 488         /* reset counter */
 489         ldr     r3, =0x00001984
 490         str     r3, [r1, #4]
 491
 492         /* Enable the watchdog */
 493         mov     r3, #1
 494         str     r3, [r1]
 495
 496 _loop_forever:
 497         b       _loop_forever