arch/arm/lib/relocate.S

   1 /*
   2  *  relocate - common relocation function for ARM U-Boot
   3  *
   4  *  Copyright (c) 2013  Albert ARIBAUD <albert.u.boot@aribaud.net>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <linux/linkage.h>
  26
  27 /*
  28  * void relocate_code(addr_moni)
  29  *
  30  * This function relocates the monitor code.
  31  *
  32  * NOTE:
  33  * To prevent the code below from containing references with an R_ARM_ABS32
  34  * relocation record type, we never refer to linker-defined symbols directly.
  35  * Instead, we declare literals which contain their relative location with
  36  * respect to relocate_code, and at run time, add relocate_code back to them.
  37  */
  38
  39 ENTRY(relocate_code)
  40         mov     r6, r0  /* save addr of destination */
  41
  42         ldr     r0, =__image_copy_start /* r0 <- SRC &__image_copy_start */
  43         subs    r9, r6, r0              /* r9 <- relocation offset */
  44         beq     relocate_done           /* skip relocation */
  45         mov     r1, r6                  /* r1 <- scratch for copy loop */
  46         adr     r7, relocate_code       /* r7 <- SRC &relocate_code */
  47         ldr     r2, =__image_copy_end   /* r2 <- SRC &__image_copy_end */
  48
  49 copy_loop:
  50         ldmia   r0!, {r10-r11}          /* copy from source address [r0]    */
  51         stmia   r1!, {r10-r11}          /* copy to   target address [r1]    */
  52         cmp     r0, r2                  /* until source end address [r2]    */
  53         blo     copy_loop
  54
  55         /*
  56          * fix .rel.dyn relocations
  57          */
  58         ldr     r2, =__rel_dyn_start    /* r2 <- SRC &__rel_dyn_start */
  59         ldr     r3, =__rel_dyn_end      /* r3 <- SRC &__rel_dyn_end */
  60 fixloop:
  61         ldr     r0, [r2]                /* r0 <- SRC location to fix up */
  62         add     r0, r0, r9              /* r0 <- DST location to fix up */
  63         ldr     r1, [r2, #4]
  64         and     r7, r1, #0xff
  65         cmp     r7, #23                 /* relative fixup? */
  66         beq     fixrel
  67         /* ignore unknown type of fixup */
  68         b       fixnext
  69 fixrel:
  70         /* relative fix: increase location by offset */
  71         ldr     r1, [r0]
  72         add     r1, r1, r9
  73 fixnext:
  74         str     r1, [r0]
  75         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
  76         cmp     r2, r3
  77         blo     fixloop
  78
  79 relocate_done:
  80
  81         /* ARMv4- don't know bx lr but the assembler fails to see that */
  82
  83 #ifdef __ARM_ARCH_4__
  84         mov        pc, lr
  85 #else
  86         bx        lr
  87 #endif
  88
  89 ENDPROC(relocate_code)