arch/mips/cpu/mips64/start.S

   1 /*
   2  *  Startup Code for MIPS64 CPU-core
   3  *
   4  *  Copyright (c) 2003  Wolfgang Denk <wd@denx.de>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any dlater version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICUdlaR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Pdlace, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <asm-offsets.h>
  26 #include <config.h>
  27 #include <asm/regdef.h>
  28 #include <asm/mipsregs.h>
  29
  30 #ifndef CONFIG_SYS_MIPS_CACHE_MODE
  31 #define CONFIG_SYS_MIPS_CACHE_MODE CONF_CM_CACHABLE_NONCOHERENT
  32 #endif
  33
  34         /*
  35          * For the moment disable interrupts, mark the kernel mode and
  36          * set ST0_KX so that the CPU does not spit fire when using
  37          * 64-bit addresses.
  38          */
  39         .macro  setup_c0_status set clr
  40         .set    push
  41         mfc0    t0, CP0_STATUS
  42         or      t0, ST0_CU0 | \set | 0x1f | \clr
  43         xor     t0, 0x1f | \clr
  44         mtc0    t0, CP0_STATUS
  45         .set    noreorder
  46         sll     zero, 3                         # ehb
  47         .set    pop
  48         .endm
  49
  50         .set noreorder
  51
  52         .globl _start
  53         .text
  54 _start:
  55         .org 0x000
  56         b       reset
  57          nop
  58         .org 0x080
  59         b       romReserved
  60          nop
  61         .org 0x100
  62         b       romReserved
  63          nop
  64         .org 0x180
  65         b       romReserved
  66          nop
  67         .org 0x200
  68         b       romReserved
  69          nop
  70         .org 0x280
  71         b       romReserved
  72          nop
  73         .org 0x300
  74         b       romReserved
  75          nop
  76         .org 0x380
  77         b       romReserved
  78          nop
  79         .org 0x480
  80         b       romReserved
  81          nop
  82
  83         /*
  84          * We hope there are no more reserved vectors!
  85          * 128 * 8 == 1024 == 0x400
  86          * so this is address R_VEC+0x400 == 0xbfc00400
  87          */
  88         .org 0x500
  89         .align 4
  90 reset:
  91
  92         /* Clear watch registers */
  93         dmtc0   zero, CP0_WATCHLO
  94         dmtc0   zero, CP0_WATCHHI
  95
  96         /* WP(Watch Pending), SW0/1 should be cleared */
  97         mtc0    zero, CP0_CAUSE
  98
  99         setup_c0_status ST0_KX 0
 100
 101         /* Init Timer */
 102         mtc0    zero, CP0_COUNT
 103         mtc0    zero, CP0_COMPARE
 104
 105 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 106         /* CONFIG0 register */
 107         dli     t0, CONF_CM_UNCACHED
 108         mtc0    t0, CP0_CONFIG
 109 #endif
 110
 111         /*
 112          * Initialize $gp, force 8 byte alignment of bal instruction to forbid
 113          * the compiler to put nop's between bal and _gp. This is required to
 114          * keep _gp and ra aligned to 8 byte.
 115          */
 116         .align  3
 117         bal     1f
 118          nop
 119         .dword  _gp
 120 1:
 121         ld      gp, 0(ra)
 122
 123 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 124         /* Initialize any external memory */
 125         dla     t9, lowlevel_init
 126         jalr    t9
 127          nop
 128
 129         /* Initialize caches... */
 130         dla     t9, mips_cache_reset
 131         jalr    t9
 132          nop
 133
 134         /* ... and enable them */
 135         dli     t0, CONFIG_SYS_MIPS_CACHE_MODE
 136         mtc0    t0, CP0_CONFIG
 137 #endif
 138
 139         /* Set up temporary stack */
 140         dli     t0, CONFIG_SYS_SDRAM_BASE + CONFIG_SYS_INIT_SP_OFFSET
 141         dla     sp, 0(t0)
 142
 143         dla     t9, board_init_f
 144         jr      t9
 145          nop
 146
 147 /*
 148  * void relocate_code (addr_sp, gd, addr_moni)
 149  *
 150  * This "function" does not return, instead it continues in RAM
 151  * after relocating the monitor code.
 152  *
 153  * a0 = addr_sp
 154  * a1 = gd
 155  * a2 = destination address
 156  */
 157         .globl  relocate_code
 158         .ent    relocate_code
 159 relocate_code:
 160         move    sp, a0                  # set new stack pointer
 161
 162         dli     t0, CONFIG_SYS_MONITOR_BASE
 163         dla     t3, in_ram
 164         ld      t2, -24(t3)             # t2 <-- uboot_end_data
 165         move    t1, a2
 166         move    s2, a2                  # s2 <-- destination address
 167
 168         /*
 169          * Fix $gp:
 170          *
 171          * New $gp = (Old $gp - CONFIG_SYS_MONITOR_BASE) + Destination Address
 172          */
 173         move    t8, gp
 174         dsub    gp, CONFIG_SYS_MONITOR_BASE
 175         dadd    gp, a2                  # gp now adjusted
 176         dsub    s1, gp, t8              # s1 <-- relocation offset
 177
 178         /*
 179          * t0 = source address
 180          * t1 = target address
 181          * t2 = source end address
 182          */
 183
 184         /*
 185          * Save destination address and size for dlater usage in flush_cache()
 186          */
 187         move    s0, a1                  # save gd in s0
 188         move    a0, t1                  # a0 <-- destination addr
 189         dsub    a1, t2, t0              # a1 <-- size
 190
 191 1:
 192         lw      t3, 0(t0)
 193         sw      t3, 0(t1)
 194         daddu   t0, 4
 195         ble     t0, t2, 1b
 196          daddu  t1, 4
 197
 198         /* If caches were enabled, we would have to flush them here. */
 199
 200         /* a0 & a1 are already set up for flush_cache(start, size) */
 201         dla     t9, flush_cache
 202         jalr    t9
 203          nop
 204
 205         /* Jump to where we've relocated ourselves */
 206         daddi   t0, s2, in_ram - _start
 207         jr      t0
 208          nop
 209
 210         .dword  _gp
 211         .dword  _GLOBAL_OFFSET_TABLE_
 212         .dword  uboot_end_data
 213         .dword  uboot_end
 214         .dword  num_got_entries
 215
 216 in_ram:
 217         /*
 218          * Now we want to update GOT.
 219          *
 220          * GOT[0] is reserved. GOT[1] is also reserved for the dynamic object
 221          * generated by GNU ld. Skip these reserved entries from relocation.
 222          */
 223         ld      t3, -8(t0)              # t3 <-- num_got_entries
 224         ld      t8, -32(t0)             # t8 <-- _GLOBAL_OFFSET_TABLE_
 225         ld      t9, -40(t0)             # t9 <-- _gp
 226         dsub    t8, t9                  # compute offset
 227         dadd    t8, t8, gp              # t8 now holds relocated _G_O_T_
 228         daddi   t8, t8, 16              # skipping first two entries
 229         dli     t2, 2
 230 1:
 231         ld      t1, 0(t8)
 232         beqz    t1, 2f
 233          dadd   t1, s1
 234         sd      t1, 0(t8)
 235 2:
 236         daddi   t2, 1
 237         blt     t2, t3, 1b
 238          daddi  t8, 8
 239
 240         /* Clear BSS */
 241         ld      t1, -24(t0)             # t1 <-- uboot_end_data
 242         ld      t2, -16(t0)             # t2 <-- uboot_end
 243         dadd    t1, s1                  # adjust pointers
 244         dadd    t2, s1
 245
 246         dsub    t1, 8
 247 1:
 248         daddi   t1, 8
 249         bltl    t1, t2, 1b
 250          sd     zero, 0(t1)
 251
 252         move    a0, s0                  # a0 <-- gd
 253         dla     t9, board_init_r
 254         jr      t9
 255          move   a1, s2
 256
 257         .end    relocate_code
 258
 259         /* Exception handlers */
 260 romReserved:
 261         b       romReserved