arch/mips/cpu/xburst/start.S

   1 /*
   2  *  Startup Code for MIPS32 XBURST CPU-core
   3  *
   4  *  Copyright (c) 2010 Xiangfu Liu <xiangfu@sharism.cc>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <config.h>
  26 #include <version.h>
  27 #include <asm/regdef.h>
  28 #include <asm/mipsregs.h>
  29 #include <asm/addrspace.h>
  30 #include <asm/cacheops.h>
  31
  32         .set noreorder
  33
  34         .globl _start
  35         .text
  36 _start:
  37         /* Initialize $gp */
  38         bal     1f
  39          nop
  40         .word   _gp
  41 1:
  42         lw      gp, 0(ra)
  43
  44         /* Set up temporary stack */
  45         li      sp, CONFIG_SYS_SDRAM_BASE + CONFIG_SYS_INIT_SP_OFFSET
  46
  47         la      t9, board_init_f
  48         jr      t9
  49          nop
  50
  51 /*
  52  * void relocate_code (addr_sp, gd, addr_moni)
  53  *
  54  * This "function" does not return, instead it continues in RAM
  55  * after relocating the monitor code.
  56  *
  57  * a0 = addr_sp
  58  * a1 = gd
  59  * a2 = destination address
  60  */
  61         .globl  relocate_code
  62         .ent    relocate_code
  63 relocate_code:
  64         move    sp, a0                  # set new stack pointer
  65
  66         li      t0, CONFIG_SYS_MONITOR_BASE
  67         la      t3, in_ram
  68         lw      t2, -12(t3)             # t2 <-- uboot_end_data
  69         move    t1, a2
  70
  71         /*
  72          * Fix $gp:
  73          *
  74          * New $gp = (Old $gp - CONFIG_SYS_MONITOR_BASE) + Destination Address
  75          */
  76         move    t6, gp
  77         sub     gp, CONFIG_SYS_MONITOR_BASE
  78         add     gp, a2                  # gp now adjusted
  79         sub     t6, gp, t6              # t6 <-- relocation offset
  80
  81         /*
  82          * t0 = source address
  83          * t1 = target address
  84          * t2 = source end address
  85          */
  86 1:
  87         lw      t3, 0(t0)
  88         sw      t3, 0(t1)
  89         addu    t0, 4
  90         ble     t0, t2, 1b
  91          addu   t1, 4
  92
  93         /* If caches were enabled, we would have to flush them here. */
  94
  95         /* flush d-cache */
  96         li      t0, KSEG0
  97         addi    t1, t0, CONFIG_SYS_DCACHE_SIZE
  98 2:
  99         cache   INDEX_WRITEBACK_INV_D, 0(t0)
 100         bne     t0, t1, 2b
 101          addi   t0, CONFIG_SYS_CACHELINE_SIZE
 102
 103         sync
 104
 105         /* flush i-cache */
 106         li      t0, KSEG0
 107         addi    t1, t0, CONFIG_SYS_ICACHE_SIZE
 108 3:
 109         cache   INDEX_INVALIDATE_I, 0(t0)
 110         bne     t0, t1, 3b
 111          addi   t0, CONFIG_SYS_CACHELINE_SIZE
 112
 113         /* Invalidate BTB */
 114         mfc0    t0, CP0_CONFIG, 7
 115         nop
 116         ori     t0, 2
 117         mtc0    t0, CP0_CONFIG, 7
 118         nop
 119
 120         /* Jump to where we've relocated ourselves */
 121         addi    t0, a2, in_ram - _start
 122         jr      t0
 123          nop
 124
 125         .word   _gp
 126         .word   _GLOBAL_OFFSET_TABLE_
 127         .word   uboot_end_data
 128         .word   uboot_end
 129         .word   num_got_entries
 130
 131 in_ram:
 132         /*
 133          * Now we want to update GOT.
 134          *
 135          * GOT[0] is reserved. GOT[1] is also reserved for the dynamic object
 136          * generated by GNU ld. Skip these reserved entries from relocation.
 137          */
 138         lw      t3, -4(t0)              # t3 <-- num_got_entries
 139         lw      t4, -16(t0)             # t4 <-- _GLOBAL_OFFSET_TABLE_
 140         lw      t5, -20(t0)             # t5 <-- _gp
 141         sub     t4, t5                  # compute offset
 142         add     t4, t4, gp              # t4 now holds relocated _G_O_T_
 143         addi    t4, t4, 8               # skipping first two entries
 144         li      t2, 2
 145 1:
 146         lw      t1, 0(t4)
 147         beqz    t1, 2f
 148          add    t1, t6
 149         sw      t1, 0(t4)
 150 2:
 151         addi    t2, 1
 152         blt     t2, t3, 1b
 153          addi   t4, 4
 154
 155         /* Clear BSS */
 156         lw      t1, -12(t0)             # t1 <-- uboot_end_data
 157         lw      t2, -8(t0)              # t2 <-- uboot_end
 158         add     t1, t6                  # adjust pointers
 159         add     t2, t6
 160
 161         sub     t1, 4
 162 1:      addi    t1, 4
 163         bltl    t1, t2, 1b
 164          sw     zero, 0(t1)
 165
 166         move    a0, a1                  # a0 <-- gd
 167         la      t9, board_init_r
 168         jr      t9
 169          move   a1, a2
 170
 171         .end    relocate_code